t/t15color.t

   1 #!perl -w
   2 # Before `make install' is performed this script should be runnable with
   3 # `make test'. After `make install' it should work as `perl test.pl'
   4
   5 ######################### We start with some black magic to print on failure.
   6
   7 # Change 1..1 below to 1..last_test_to_print .
   8 # (It may become useful if the test is moved to ./t subdirectory.)
   9
  10 use Test::More tests => 70;
  11
  12 use Imager;
  13 use Imager::Test qw(is_fcolor4);
  14
  15 init_log("testout/t15color.log",1);
  16
  17 my $c1 = Imager::Color->new(100, 150, 200, 250);
  18 ok(test_col($c1, 100, 150, 200, 250), 'simple 4-arg');
  19 my $c2 = Imager::Color->new(100, 150, 200);
  20 ok(test_col($c2, 100, 150, 200, 255), 'simple 3-arg');
  21 my $c3 = Imager::Color->new("#6496C8");
  22 ok(test_col($c3, 100, 150, 200, 255), 'web color');
  23 # crashes in Imager-0.38pre8 and earlier
  24 my @foo;
  25 for (1..1000) {
  26   push(@foo, Imager::Color->new("#FFFFFF"));
  27 }
  28 my $fail;
  29 for (@foo) {
  30   Imager::Color::set_internal($_, 128, 128, 128, 128) == $_ or ++$fail;
  31   Imager::Color::set_internal($_, 128, 128, 128, 128) == $_ or ++$fail;
  32   test_col($_, 128, 128, 128, 128) or ++$fail;
  33 }
  34 ok(!$fail, 'consitency check');
  35
  36 # test the new OO methods
  37 color_ok('r g b',, 100, 150, 200, 255, Imager::Color->new(r=>100, g=>150, b=>200));
  38 color_ok('red green blue', 101, 151, 201, 255,
  39          Imager::Color->new(red=>101, green=>151, blue=>201));
  40 color_ok('grey', 102, 255, 255, 255, Imager::Color->new(grey=>102));
  41 color_ok('gray', 103, 255, 255, 255, Imager::Color->new(gray=>103));
  42 SKIP:
  43 {
  44   skip "no X rgb.txt found", 1
  45     unless grep -r, Imager::Color::_test_x_palettes();
  46   color_ok('xname', 0, 0, 255, 255, Imager::Color->new(xname=>'blue'));
  47 }
  48 color_ok('gimp', 255, 250, 250, 255,
  49          Imager::Color->new(gimp=>'snow', palette=>'testimg/test_gimp_pal'));
  50 color_ok('h s v', 255, 255, 255, 255, Imager::Color->new(h=>0, 's'=>0, 'v'=>1.0));
  51 color_ok('h s v again', 255, 0, 0, 255, Imager::Color->new(h=>0, 's'=>1, v=>1));
  52 color_ok('web 6 digit', 128, 129, 130, 255, Imager::Color->new(web=>'#808182'));
  53 color_ok('web 3 digit', 0x11, 0x22, 0x33, 255, Imager::Color->new(web=>'#123'));
  54 color_ok('rgb arrayref', 255, 150, 121, 255, Imager::Color->new(rgb=>[ 255, 150, 121 ]));
  55 color_ok('rgba arrayref', 255, 150, 121, 128,
  56          Imager::Color->new(rgba=>[ 255, 150, 121, 128 ]));
  57 color_ok('hsv arrayref', 255, 0, 0, 255, Imager::Color->new(hsv=>[ 0, 1, 1 ]));
  58 color_ok('channel0-3', 129, 130, 131, 134,
  59          Imager::Color->new(channel0=>129, channel1=>130, channel2=>131,
  60                             channel3=>134));
  61 color_ok('c0-3', 129, 130, 131, 134,
  62          Imager::Color->new(c0=>129, c1=>130, c2=>131, c3=>134));
  63 color_ok('channels arrayref', 200, 201, 203, 204,
  64          Imager::Color->new(channels=>[ 200, 201, 203, 204 ]));
  65 color_ok('name', 255, 250, 250, 255,
  66          Imager::Color->new(name=>'snow', palette=>'testimg/test_gimp_pal'));
  67
  68 # test the internal HSV <=> RGB conversions
  69 # these values were generated using the GIMP
  70 # all but hue is 0..360, saturation and value from 0 to 1
  71 # rgb from 0 to 255
  72 my @hsv_vs_rgb =
  73   (
  74    { hsv => [ 0, 0.2, 0.1 ], rgb=> [ 25, 20, 20 ] },
  75    { hsv => [ 0, 0.5, 1.0 ], rgb => [ 255, 127, 127 ] },
  76    { hsv => [ 100, 0.5, 1.0 ], rgb => [ 170, 255, 127 ] },
  77    { hsv => [ 100, 1.0, 1.0 ], rgb=> [ 85, 255, 0 ] },
  78    { hsv => [ 335, 0.5, 0.5 ], rgb=> [127, 63, 90 ] },
  79   );
  80
  81 use Imager::Color::Float;
  82 my $test_num = 23;
  83 my $index = 0;
  84 for my $entry (@hsv_vs_rgb) {
  85   print "# color index $index\n";
  86   my $hsv = $entry->{hsv};
  87   my $rgb = $entry->{rgb};
  88   my $fhsvo = Imager::Color::Float->new($hsv->[0]/360.0, $hsv->[1], $hsv->[2]);
  89   my $fc = Imager::Color::Float::i_hsv_to_rgb($fhsvo);
  90   fcolor_close_enough("i_hsv_to_rgbf $index", $rgb->[0]/255, $rgb->[1]/255,
  91                       $rgb->[2]/255, $fc);
  92   my $fc2 = Imager::Color::Float::i_rgb_to_hsv($fc);
  93   fcolor_close_enough("i_rgbf_to_hsv $index", $hsv->[0]/360.0, $hsv->[1], $hsv->[2],
  94                       $fc2);
  95
  96   my $hsvo = Imager::Color->new($hsv->[0]*255/360.0, $hsv->[1] * 255,
  97                                 $hsv->[2] * 255);
  98   my $c = Imager::Color::i_hsv_to_rgb($hsvo);
  99   color_close_enough("i_hsv_to_rgb $index", @$rgb, $c);
 100   my $c2 = Imager::Color::i_rgb_to_hsv($c);
 101   color_close_enough_hsv("i_rgb_to_hsv $index", $hsv->[0]*255/360.0, $hsv->[1] * 255,
 102                      $hsv->[2] * 255, $c2);
 103   ++$index;
 104 }
 105
 106 # check the built-ins table
 107 color_ok('builtin black', 0, 0, 0, 255,
 108         Imager::Color->new(builtin=>'black'));
 109
 110 {
 111   my $c1 = Imager::Color->new(255, 255, 255, 0);
 112   my $c2 = Imager::Color->new(255, 255, 255, 255);
 113   ok(!$c1->equals(other=>$c2), "not equal no ignore alpha");
 114   ok(scalar($c1->equals(other=>$c2, ignore_alpha=>1)),
 115       "equal with ignore alpha");
 116   ok($c1->equals(other=>$c1), "equal to itself");
 117 }
 118
 119 { # http://rt.cpan.org/NoAuth/Bug.html?id=13143
 120   # Imager::Color->new(color_name) warning if HOME environment variable not set
 121   local $ENV{HOME};
 122   my @warnings;
 123   local $SIG{__WARN__} = sub { push @warnings, "@_" };
 124
 125   # presumably no-one will name a color like this.
 126   my $c1 = Imager::Color->new(gimp=>"ABCDEFGHIJKLMNOP");
 127   is(@warnings, 0, "Should be no warnings")
 128     or do { print "# $_" for @warnings };
 129 }
 130
 131 {
 132   # float color from hex triple
 133   my $f3white = Imager::Color::Float->new("#FFFFFF");
 134   is_fcolor4($f3white, 1.0, 1.0, 1.0, 1.0, "check color #FFFFFF");
 135   my $f3black = Imager::Color::Float->new("#000000");
 136   is_fcolor4($f3black, 0, 0, 0, 1.0, "check color #000000");
 137   my $f3grey = Imager::Color::Float->new("#808080");
 138   is_fcolor4($f3grey, 0x80/0xff, 0x80/0xff, 0x80/0xff, 1.0, "check color #808080");
 139
 140   my $f4white = Imager::Color::Float->new("#FFFFFF80");
 141   is_fcolor4($f4white, 1.0, 1.0, 1.0, 0x80/0xff, "check color #FFFFFF80");
 142 }
 143
 144 {
 145   # fail to make a color
 146   ok(!Imager::Color::Float->new("-unknown-"), "try to make float color -unknown-");
 147 }
 148
 149 {
 150   # set after creation
 151   my $c = Imager::Color::Float->new(0, 0, 0);
 152   is_fcolor4($c, 0, 0, 0, 1.0, "check simple init of float color");
 153   ok($c->set(1.0, 0.5, 0.25, 1.0), "set() the color");
 154   is_fcolor4($c, 1.0, 0.5, 0.25, 1.0, "check after set");
 155
 156   ok(!$c->set("-unknown-"), "set to unknown");
 157 }
 158
 159 {
 160   # test ->hsv
 161   my $c = Imager::Color->new(255, 0, 0);
 162   my($h,$s,$v) = $c->hsv;
 163   is($h,0,'red hue');
 164   is($s,1,'red saturation');
 165   is($v,1,'red value');
 166
 167   $c = Imager::Color->new(0, 255, 0);
 168   ($h,$s,$v) = $c->hsv;
 169   is($h,120,'green hue');
 170   is($s,1,'green saturation');
 171   is($v,1,'green value');
 172
 173   $c = Imager::Color->new(0, 0, 255);
 174   ($h,$s,$v) = $c->hsv;
 175   is($h,240,'blue hue');
 176   is($s,1,'blue saturation');
 177   is($v,1,'blue value');
 178
 179   $c = Imager::Color->new(255, 255, 255);
 180   ($h,$s,$v) = $c->hsv;
 181   is($h,0,'white hue');
 182   is($s,0,'white saturation');
 183   is($v,1,'white value');
 184
 185   $c = Imager::Color->new(0, 0, 0);
 186   ($h,$s,$v) = $c->hsv;
 187   is($h,0,'black hue');
 188   is($s,0,'black saturation');
 189   is($v,0,'black value');
 190 }
 191
 192 sub test_col {
 193   my ($c, $r, $g, $b, $a) = @_;
 194   unless ($c) {
 195     print "# $Imager::ERRSTR\n";
 196     return 0;
 197   }
 198   my ($cr, $cg, $cb, $ca) = $c->rgba;
 199   return $r == $cr && $g == $cg && $b == $cb && $a == $ca;
 200 }
 201
 202 sub color_close_enough {
 203   my ($name, $r, $g, $b, $c) = @_;
 204
 205   my ($cr, $cg, $cb) = $c->rgba;
 206   ok(abs($cr-$r) <= 5 && abs($cg-$g) <= 5 && abs($cb-$b) <= 5,
 207     "$name - ($cr, $cg, $cb) <=> ($r, $g, $b)");
 208 }
 209
 210 sub color_close_enough_hsv {
 211   my ($name, $h, $s, $v, $c) = @_;
 212
 213   my ($ch, $cs, $cv) = $c->rgba;
 214   if ($ch < 5 && $h > 250) {
 215     $ch += 255;
 216   }
 217   elsif ($ch > 250 && $h < 5) {
 218     $h += 255;
 219   }
 220   ok(abs($ch-$h) <= 5 && abs($cs-$s) <= 5 && abs($cv-$v) <= 5,
 221     "$name - ($ch, $cs, $cv) <=> ($h, $s, $v)");
 222 }
 223
 224 sub fcolor_close_enough {
 225   my ($name, $r, $g, $b, $c) = @_;
 226
 227   my ($cr, $cg, $cb) = $c->rgba;
 228   ok(abs($cr-$r) <= 0.01 && abs($cg-$g) <= 0.01 && abs($cb-$b) <= 0.01,
 229     "$name - ($cr, $cg, $cb) <=> ($r, $g, $b)");
 230 }
 231
 232 sub color_ok {
 233   my ($name, $r, $g, $b, $a, $c) = @_;
 234
 235   unless (ok(test_col($c, $r, $g, $b, $a), $name)) {
 236     print "# ($r,$g,$b,$a) != (".join(",", $c ? $c->rgba: ()).")\n";
 237   }
 238 }
 239