JPEG/Makefile.PL

   1 #!perl -w
   2 use strict;
   3 use ExtUtils::MakeMaker;
   4 use Getopt::Long;
   5 use Config;
   6
   7 my $verbose = $ENV{IM_VERBOSE};
   8 my @libpaths;
   9 my @incpaths;
  10
  11 GetOptions("incpath=s", \@incpaths,
  12            "libpath=s" => \@libpaths,
  13            "verbose|v" => \$verbose);
  14
  15 our $BUILDING_IMAGER;
  16 our %IMAGER_LIBS;
  17
  18 my $MM_ver = eval $ExtUtils::MakeMaker::VERSION;
  19
  20 my %opts =
  21   (
  22    NAME => 'Imager::File::JPEG',
  23    VERSION_FROM => 'JPEG.pm',
  24    OBJECT => 'JPEG.o imjpeg.o imexif.o',
  25    clean => { FILES => 'testout' },
  26   );
  27
  28 my @inc;
  29 if ($BUILDING_IMAGER) {
  30   push @inc, "-I..";
  31   unshift @INC, "../lib";
  32 }
  33 else {
  34   unshift @INC, "inc";
  35   print "JPEG: building independently\n";
  36   require Imager::ExtUtils;
  37   push @inc, Imager::ExtUtils->includes;
  38   $opts{TYPEMAPS} = [ Imager::ExtUtils->typemap ];
  39
  40   # Imager required configure through use
  41   my @Imager_req = ( Imager => "0.86" );
  42   if ($MM_ver >= 6.46) {
  43     $opts{META_MERGE} =
  44       {
  45        configure_requires =>
  46        {
  47         @Imager_req,
  48        },
  49        build_requires =>
  50        {
  51         @Imager_req,
  52         "Test::More" => "0.47",
  53        },
  54        resources =>
  55        {
  56         homepage => "http://imager.perl.org/",
  57         repository => "git://git.imager.perl.org/imager.git",
  58         bugtracker => "http://rt.cpan.org/NoAuth/Bugs.html?Dist=Imager",
  59        },
  60       };
  61     $opts{PREREQ_PM} =
  62       {
  63        @Imager_req,
  64        XSLoader => 0,
  65       };
  66   }
  67 }
  68
  69 require Imager::Probe;
  70
  71 my %probe =
  72   (
  73    name => "JPEG",
  74    inccheck => sub { -e File::Spec->catfile($_[0], "jpeglib.h") },
  75    libbase => "jpeg",
  76    testcode => _jpeg_test_code(),
  77    testcodeheaders => [ "stdio.h", "stddef.h", "jpeglib.h" ],
  78    incpath => \@incpaths,
  79    libpath => \@libpaths,
  80   );
  81
  82 my $probe_res = Imager::Probe->probe(\%probe);
  83 if ($probe_res) {
  84   $IMAGER_LIBS{JPEG} = 1;
  85
  86   push @inc, $probe_res->{INC};
  87   $opts{LIBS} = $probe_res->{LIBS};
  88   $opts{DEFINE} = $probe_res->{DEFINE};
  89   $opts{INC} = "@inc";
  90
  91   if ($MM_ver > 6.06) {
  92     $opts{AUTHOR} = 'Tony Cook <tonyc@cpan.org>';
  93     $opts{ABSTRACT} = 'JPEG Image file support';
  94   }
  95
  96   WriteMakefile(%opts);
  97 }
  98 else {
  99   $IMAGER_LIBS{JPEG} = 0;
 100
 101   if ($BUILDING_IMAGER) {
 102     ExtUtils::MakeMaker::WriteEmptyMakefile(%opts);
 103   }
 104   else {
 105     # fail in good way
 106     die "OS unsupported: JPEG libraries or headers not found\n";
 107   }
 108 }
 109
 110 sub _jpeg_test_code {
 111   return <<'CODE';
 112 struct jpeg_decompress_struct cinfo;
 113 struct jpeg_error_mgr jerr;
 114
 115 cinfo.err = jpeg_std_error(&jerr);
 116 jpeg_create_decompress(&cinfo);
 117
 118 return 0;
 119 CODE
 120 }