t/t15color.t

   1 #!perl -w
   2 # Before `make install' is performed this script should be runnable with
   3 # `make test'. After `make install' it should work as `perl test.pl'
   4
   5 ######################### We start with some black magic to print on failure.
   6
   7 # Change 1..1 below to 1..last_test_to_print .
   8 # (It may become useful if the test is moved to ./t subdirectory.)
   9
  10 use lib 't';
  11 use Test::More tests => 47;
  12
  13 BEGIN { use_ok('Imager'); };
  14
  15 require "t/testtools.pl";
  16
  17 init_log("testout/t15color.log",1);
  18
  19 my $c1 = Imager::Color->new(100, 150, 200, 250);
  20 ok(test_col($c1, 100, 150, 200, 250), 'simple 4-arg');
  21 my $c2 = Imager::Color->new(100, 150, 200);
  22 ok(test_col($c2, 100, 150, 200, 255), 'simple 3-arg');
  23 my $c3 = Imager::Color->new("#6496C8");
  24 ok(test_col($c3, 100, 150, 200, 255), 'web color');
  25 # crashes in Imager-0.38pre8 and earlier
  26 my @foo;
  27 for (1..1000) {
  28   push(@foo, Imager::Color->new("#FFFFFF"));
  29 }
  30 my $fail;
  31 for (@foo) {
  32   Imager::Color::set_internal($_, 128, 128, 128, 128) == $_ or ++$fail;
  33   Imager::Color::set_internal($_, 128, 128, 128, 128) == $_ or ++$fail;
  34   test_col($_, 128, 128, 128, 128) or ++$fail;
  35 }
  36 ok(!$fail, 'consitency check');
  37
  38 # test the new OO methods
  39 color_ok('r g b',, 100, 150, 200, 255, Imager::Color->new(r=>100, g=>150, b=>200));
  40 color_ok('red green blue', 101, 151, 201, 255,
  41          Imager::Color->new(red=>101, green=>151, blue=>201));
  42 color_ok('grey', 102, 255, 255, 255, Imager::Color->new(grey=>102));
  43 color_ok('gray', 103, 255, 255, 255, Imager::Color->new(gray=>103));
  44 SKIP:
  45 {
  46   skip "no X rgb.txt found", 1 unless -e '/usr/lib/X11/rgb.txt';
  47   color_ok('xname', 0, 0, 255, 255, Imager::Color->new(xname=>'blue'));
  48 }
  49 color_ok('gimp', 255, 250, 250, 255,
  50          Imager::Color->new(gimp=>'snow', palette=>'testimg/test_gimp_pal'));
  51 color_ok('h s v', 255, 255, 255, 255, Imager::Color->new(h=>0, 's'=>0, 'v'=>1.0));
  52 color_ok('h s v again', 255, 0, 0, 255, Imager::Color->new(h=>0, 's'=>1, v=>1));
  53 color_ok('web 6 digit', 128, 129, 130, 255, Imager::Color->new(web=>'#808182'));
  54 color_ok('web 3 digit', 0x11, 0x22, 0x33, 255, Imager::Color->new(web=>'#123'));
  55 color_ok('rgb arrayref', 255, 150, 121, 255, Imager::Color->new(rgb=>[ 255, 150, 121 ]));
  56 color_ok('rgba arrayref', 255, 150, 121, 128,
  57          Imager::Color->new(rgba=>[ 255, 150, 121, 128 ]));
  58 color_ok('hsv arrayref', 255, 0, 0, 255, Imager::Color->new(hsv=>[ 0, 1, 1 ]));
  59 color_ok('channel0-3', 129, 130, 131, 134,
  60          Imager::Color->new(channel0=>129, channel1=>130, channel2=>131,
  61                             channel3=>134));
  62 color_ok('c0-3', 129, 130, 131, 134,
  63          Imager::Color->new(c0=>129, c1=>130, c2=>131, c3=>134));
  64 color_ok('channels arrayref', 200, 201, 203, 204,
  65          Imager::Color->new(channels=>[ 200, 201, 203, 204 ]));
  66 color_ok('name', 255, 250, 250, 255,
  67          Imager::Color->new(name=>'snow', palette=>'testimg/test_gimp_pal'));
  68
  69 # test the internal HSV <=> RGB conversions
  70 # these values were generated using the GIMP
  71 # all but hue is 0..360, saturation and value from 0 to 1
  72 # rgb from 0 to 255
  73 my @hsv_vs_rgb =
  74   (
  75    { hsv => [ 0, 0.2, 0.1 ], rgb=> [ 25, 20, 20 ] },
  76    { hsv => [ 0, 0.5, 1.0 ], rgb => [ 255, 127, 127 ] },
  77    { hsv => [ 100, 0.5, 1.0 ], rgb => [ 170, 255, 127 ] },
  78    { hsv => [ 100, 1.0, 1.0 ], rgb=> [ 85, 255, 0 ] },
  79    { hsv => [ 335, 0.5, 0.5 ], rgb=> [127, 63, 90 ] },
  80   );
  81
  82 use Imager::Color::Float;
  83 my $test_num = 23;
  84 my $index = 0;
  85 for my $entry (@hsv_vs_rgb) {
  86   print "# color index $index\n";
  87   my $hsv = $entry->{hsv};
  88   my $rgb = $entry->{rgb};
  89   my $fhsvo = Imager::Color::Float->new($hsv->[0]/360.0, $hsv->[1], $hsv->[2]);
  90   my $fc = Imager::Color::Float::i_hsv_to_rgb($fhsvo);
  91   fcolor_close_enough("i_hsv_to_rgbf $index", $rgb->[0]/255, $rgb->[1]/255,
  92                       $rgb->[2]/255, $fc);
  93   my $fc2 = Imager::Color::Float::i_rgb_to_hsv($fc);
  94   fcolor_close_enough("i_rgbf_to_hsv $index", $hsv->[0]/360.0, $hsv->[1], $hsv->[2],
  95                       $fc2);
  96
  97   my $hsvo = Imager::Color->new($hsv->[0]*255/360.0, $hsv->[1] * 255,
  98                                 $hsv->[2] * 255);
  99   my $c = Imager::Color::i_hsv_to_rgb($hsvo);
 100   color_close_enough("i_hsv_to_rgb $index", @$rgb, $c);
 101   my $c2 = Imager::Color::i_rgb_to_hsv($c);
 102   color_close_enough_hsv("i_rgb_to_hsv $index", $hsv->[0]*255/360.0, $hsv->[1] * 255,
 103                      $hsv->[2] * 255, $c2);
 104   ++$index;
 105 }
 106
 107 # check the built-ins table
 108 color_ok('builtin black', 0, 0, 0, 255,
 109         Imager::Color->new(builtin=>'black'));
 110
 111 {
 112   my $c1 = Imager::Color->new(255, 255, 255, 0);
 113   my $c2 = Imager::Color->new(255, 255, 255, 255);
 114   ok(!$c1->equals(other=>$c2), "not equal no ignore alpha");
 115   ok(scalar($c1->equals(other=>$c2, ignore_alpha=>1)),
 116       "equal with ignore alpha");
 117   ok($c1->equals(other=>$c1), "equal to itself");
 118 }
 119
 120 { # http://rt.cpan.org/NoAuth/Bug.html?id=13143
 121   # Imager::Color->new(color_name) warning if HOME environment variable not set
 122   local $ENV{HOME};
 123   my @warnings;
 124   local $SIG{__WARN__} = sub { push @warnings, "@_" };
 125
 126   # presumably no-one will name a color like this.
 127   my $c1 = Imager::Color->new(gimp=>"ABCDEFGHIJKLMNOP");
 128   is(@warnings, 0, "Should be no warnings")
 129     or do { print "# $_" for @warnings };
 130 }
 131
 132 sub test_col {
 133   my ($c, $r, $g, $b, $a) = @_;
 134   unless ($c) {
 135     print "# $Imager::ERRSTR\n";
 136     return 0;
 137   }
 138   my ($cr, $cg, $cb, $ca) = $c->rgba;
 139   return $r == $cr && $g == $cg && $b == $cb && $a == $ca;
 140 }
 141
 142 sub color_close_enough {
 143   my ($name, $r, $g, $b, $c) = @_;
 144
 145   my ($cr, $cg, $cb) = $c->rgba;
 146   ok(abs($cr-$r) <= 5 && abs($cg-$g) <= 5 && abs($cb-$b) <= 5,
 147     "$name - ($cr, $cg, $cb) <=> ($r, $g, $b)");
 148 }
 149
 150 sub color_close_enough_hsv {
 151   my ($name, $h, $s, $v, $c) = @_;
 152
 153   my ($ch, $cs, $cv) = $c->rgba;
 154   if ($ch < 5 && $h > 250) {
 155     $ch += 255;
 156   }
 157   elsif ($ch > 250 && $h < 5) {
 158     $h += 255;
 159   }
 160   ok(abs($ch-$h) <= 5 && abs($cs-$s) <= 5 && abs($cv-$v) <= 5,
 161     "$name - ($ch, $cs, $cv) <=> ($h, $s, $v)");
 162 }
 163
 164 sub fcolor_close_enough {
 165   my ($name, $r, $g, $b, $c) = @_;
 166
 167   my ($cr, $cg, $cb) = $c->rgba;
 168   ok(abs($cr-$r) <= 0.01 && abs($cg-$g) <= 0.01 && abs($cb-$b) <= 0.01,
 169     "$name - ($cr, $cg, $cb) <=> ($r, $g, $b)");
 170 }
 171
 172 sub color_ok {
 173   my ($name, $r, $g, $b, $a, $c) = @_;
 174
 175   unless (ok(test_col($c, $r, $g, $b, $a), $name)) {
 176     print "# ($r,$g,$b,$a) != (".join(",", $c ? $c->rgba: ()).")\n";
 177   }
 178 }
 179