Various changes:
[imager.git] / t / t15color.t
1 #!perl -w
2 # Before `make install' is performed this script should be runnable with
3 # `make test'. After `make install' it should work as `perl test.pl'
4
5 ######################### We start with some black magic to print on failure.
6
7 # Change 1..1 below to 1..last_test_to_print .
8 # (It may become useful if the test is moved to ./t subdirectory.)
9
10 use Test::More tests => 47;
11
12 BEGIN { use_ok('Imager'); };
13
14 init_log("testout/t15color.log",1);
15
16 my $c1 = Imager::Color->new(100, 150, 200, 250);
17 ok(test_col($c1, 100, 150, 200, 250), 'simple 4-arg');
18 my $c2 = Imager::Color->new(100, 150, 200);
19 ok(test_col($c2, 100, 150, 200, 255), 'simple 3-arg');
20 my $c3 = Imager::Color->new("#6496C8");
21 ok(test_col($c3, 100, 150, 200, 255), 'web color');
22 # crashes in Imager-0.38pre8 and earlier
23 my @foo;
24 for (1..1000) {
25   push(@foo, Imager::Color->new("#FFFFFF"));
26 }
27 my $fail;
28 for (@foo) {
29   Imager::Color::set_internal($_, 128, 128, 128, 128) == $_ or ++$fail;
30   Imager::Color::set_internal($_, 128, 128, 128, 128) == $_ or ++$fail;
31   test_col($_, 128, 128, 128, 128) or ++$fail;
32 }
33 ok(!$fail, 'consitency check');
34
35 # test the new OO methods
36 color_ok('r g b',, 100, 150, 200, 255, Imager::Color->new(r=>100, g=>150, b=>200));
37 color_ok('red green blue', 101, 151, 201, 255, 
38          Imager::Color->new(red=>101, green=>151, blue=>201));
39 color_ok('grey', 102, 255, 255, 255, Imager::Color->new(grey=>102));
40 color_ok('gray', 103, 255, 255, 255, Imager::Color->new(gray=>103));
41 SKIP:
42 {
43   skip "no X rgb.txt found", 1 unless -e '/usr/lib/X11/rgb.txt';
44   color_ok('xname', 0, 0, 255, 255, Imager::Color->new(xname=>'blue'));
45 }
46 color_ok('gimp', 255, 250, 250, 255, 
47          Imager::Color->new(gimp=>'snow', palette=>'testimg/test_gimp_pal'));
48 color_ok('h s v', 255, 255, 255, 255, Imager::Color->new(h=>0, 's'=>0, 'v'=>1.0));
49 color_ok('h s v again', 255, 0, 0, 255, Imager::Color->new(h=>0, 's'=>1, v=>1));
50 color_ok('web 6 digit', 128, 129, 130, 255, Imager::Color->new(web=>'#808182'));
51 color_ok('web 3 digit', 0x11, 0x22, 0x33, 255, Imager::Color->new(web=>'#123'));
52 color_ok('rgb arrayref', 255, 150, 121, 255, Imager::Color->new(rgb=>[ 255, 150, 121 ]));
53 color_ok('rgba arrayref', 255, 150, 121, 128, 
54          Imager::Color->new(rgba=>[ 255, 150, 121, 128 ]));
55 color_ok('hsv arrayref', 255, 0, 0, 255, Imager::Color->new(hsv=>[ 0, 1, 1 ]));
56 color_ok('channel0-3', 129, 130, 131, 134, 
57          Imager::Color->new(channel0=>129, channel1=>130, channel2=>131,
58                             channel3=>134));
59 color_ok('c0-3', 129, 130, 131, 134, 
60          Imager::Color->new(c0=>129, c1=>130, c2=>131, c3=>134));
61 color_ok('channels arrayref', 200, 201, 203, 204, 
62          Imager::Color->new(channels=>[ 200, 201, 203, 204 ]));
63 color_ok('name', 255, 250, 250, 255, 
64          Imager::Color->new(name=>'snow', palette=>'testimg/test_gimp_pal'));
65
66 # test the internal HSV <=> RGB conversions
67 # these values were generated using the GIMP
68 # all but hue is 0..360, saturation and value from 0 to 1
69 # rgb from 0 to 255
70 my @hsv_vs_rgb =
71   (
72    { hsv => [ 0, 0.2, 0.1 ], rgb=> [ 25, 20, 20 ] },
73    { hsv => [ 0, 0.5, 1.0 ], rgb => [ 255, 127, 127 ] },
74    { hsv => [ 100, 0.5, 1.0 ], rgb => [ 170, 255, 127 ] },
75    { hsv => [ 100, 1.0, 1.0 ], rgb=> [ 85, 255, 0 ] },
76    { hsv => [ 335, 0.5, 0.5 ], rgb=> [127, 63, 90 ] },
77   );
78
79 use Imager::Color::Float;
80 my $test_num = 23;
81 my $index = 0;
82 for my $entry (@hsv_vs_rgb) {
83   print "# color index $index\n";
84   my $hsv = $entry->{hsv};
85   my $rgb = $entry->{rgb};
86   my $fhsvo = Imager::Color::Float->new($hsv->[0]/360.0, $hsv->[1], $hsv->[2]);
87   my $fc = Imager::Color::Float::i_hsv_to_rgb($fhsvo);
88   fcolor_close_enough("i_hsv_to_rgbf $index", $rgb->[0]/255, $rgb->[1]/255, 
89                       $rgb->[2]/255, $fc);
90   my $fc2 = Imager::Color::Float::i_rgb_to_hsv($fc);
91   fcolor_close_enough("i_rgbf_to_hsv $index", $hsv->[0]/360.0, $hsv->[1], $hsv->[2], 
92                       $fc2);
93
94   my $hsvo = Imager::Color->new($hsv->[0]*255/360.0, $hsv->[1] * 255, 
95                                 $hsv->[2] * 255);
96   my $c = Imager::Color::i_hsv_to_rgb($hsvo);
97   color_close_enough("i_hsv_to_rgb $index", @$rgb, $c);
98   my $c2 = Imager::Color::i_rgb_to_hsv($c);
99   color_close_enough_hsv("i_rgb_to_hsv $index", $hsv->[0]*255/360.0, $hsv->[1] * 255, 
100                      $hsv->[2] * 255, $c2);
101   ++$index;
102 }
103
104 # check the built-ins table
105 color_ok('builtin black', 0, 0, 0, 255, 
106         Imager::Color->new(builtin=>'black'));
107
108 {
109   my $c1 = Imager::Color->new(255, 255, 255, 0);
110   my $c2 = Imager::Color->new(255, 255, 255, 255);
111   ok(!$c1->equals(other=>$c2), "not equal no ignore alpha");
112   ok(scalar($c1->equals(other=>$c2, ignore_alpha=>1)), 
113       "equal with ignore alpha");
114   ok($c1->equals(other=>$c1), "equal to itself");
115 }
116
117 { # http://rt.cpan.org/NoAuth/Bug.html?id=13143
118   # Imager::Color->new(color_name) warning if HOME environment variable not set
119   local $ENV{HOME};
120   my @warnings;
121   local $SIG{__WARN__} = sub { push @warnings, "@_" };
122
123   # presumably no-one will name a color like this.
124   my $c1 = Imager::Color->new(gimp=>"ABCDEFGHIJKLMNOP");
125   is(@warnings, 0, "Should be no warnings")
126     or do { print "# $_" for @warnings };
127 }
128  
129 sub test_col {
130   my ($c, $r, $g, $b, $a) = @_;
131   unless ($c) {
132     print "# $Imager::ERRSTR\n";
133     return 0;
134   }
135   my ($cr, $cg, $cb, $ca) = $c->rgba;
136   return $r == $cr && $g == $cg && $b == $cb && $a == $ca;
137 }
138
139 sub color_close_enough {
140   my ($name, $r, $g, $b, $c) = @_;
141
142   my ($cr, $cg, $cb) = $c->rgba;
143   ok(abs($cr-$r) <= 5 && abs($cg-$g) <= 5 && abs($cb-$b) <= 5,
144     "$name - ($cr, $cg, $cb) <=> ($r, $g, $b)");
145 }
146
147 sub color_close_enough_hsv {
148   my ($name, $h, $s, $v, $c) = @_;
149
150   my ($ch, $cs, $cv) = $c->rgba;
151   if ($ch < 5 && $h > 250) {
152     $ch += 255;
153   }
154   elsif ($ch > 250 && $h < 5) {
155     $h += 255;
156   }
157   ok(abs($ch-$h) <= 5 && abs($cs-$s) <= 5 && abs($cv-$v) <= 5,
158     "$name - ($ch, $cs, $cv) <=> ($h, $s, $v)");
159 }
160
161 sub fcolor_close_enough {
162   my ($name, $r, $g, $b, $c) = @_;
163
164   my ($cr, $cg, $cb) = $c->rgba;
165   ok(abs($cr-$r) <= 0.01 && abs($cg-$g) <= 0.01 && abs($cb-$b) <= 0.01,
166     "$name - ($cr, $cg, $cb) <=> ($r, $g, $b)");
167 }
168
169 sub color_ok {
170   my ($name, $r, $g, $b, $a, $c) = @_;
171
172   unless (ok(test_col($c, $r, $g, $b, $a), $name)) {
173     print "# ($r,$g,$b,$a) != (".join(",", $c ? $c->rgba: ()).")\n";
174   }
175 }
176