PNG re-work: handle libpng 1.5 correctly
[imager.git] / PNG / Makefile.PL
1 #!perl -w
2 use strict;
3 use ExtUtils::MakeMaker;
4 use Getopt::Long;
5 use Config;
6
7 my $verbose = $ENV{IM_VERBOSE};
8 my @libpaths;
9 my @incpaths;
10
11 GetOptions("incpath=s", \@incpaths,
12            "libpath=s" => \@libpaths,
13            "verbose|v" => \$verbose);
14
15 our $BUILDING_IMAGER;
16 our %IMAGER_LIBS;
17
18 my $MM_ver = eval $ExtUtils::MakeMaker::VERSION;
19
20 my %opts = 
21   (
22    NAME => 'Imager::File::PNG',
23    VERSION_FROM => 'PNG.pm',
24    OBJECT => 'PNG.o impng.o',
25    clean => { FILES => 'testout' },
26   );
27
28 my @inc;
29 if ($BUILDING_IMAGER) {
30   push @inc, "-I..";
31   unshift @INC, "../lib";
32 }
33 else {
34   unshift @INC, "inc";
35   print "PNG: building independently\n";
36   require Imager::ExtUtils;
37   push @inc, Imager::ExtUtils->includes;
38   $opts{TYPEMAPS} = [ Imager::ExtUtils->typemap ];
39
40   # Imager required configure through use
41   my @Imager_req = ( Imager => "0.86" );
42   if ($MM_ver >= 6.46) {
43     $opts{META_MERGE} =
44       {
45        configure_requires => 
46        {
47         @Imager_req,
48        },
49        build_requires => 
50        {
51         @Imager_req,
52         "Test::More" => "0.47",
53        },
54        resources =>
55        {
56         homepage => "http://imager.perl.org/",
57         repository => "git://git.imager.perl.org/imager.git",
58         bugtracker => "http://rt.cpan.org/NoAuth/Bugs.html?Dist=Imager",
59        },
60       };
61     $opts{PREREQ_PM} =
62       {
63        @Imager_req,
64        XSLoader => 0,
65       };
66   }
67 }
68
69 require Imager::Probe;
70
71 my %probe =
72   (
73    name => "PNG",
74    altname => "Generic",
75    pkg => [ qw/libpng15 libpng14 libpng12 libpng10 libpng/ ],
76    inccheck => sub { -e File::Spec->catfile($_[0], "png.h") },
77    libbase => "png",
78    testcode => _png_test_code(),
79    testcodeheaders => [ "png.h", "stdio.h" ],
80    incpath => \@incpaths,
81    libpath => \@libpaths,
82    alternatives =>
83    [
84     {
85      altname => "v1.5",
86      incsuffix => "libpng14",
87      libbase => "png14",
88     },
89     {
90      altname => "v1.4",
91      incsuffix => "libpng14",
92      libbase => "png14",
93     },
94     {
95      altname => "v1.2",
96      incsuffix => "libpng12",
97      libbase => "png12",
98     },
99     {
100      altname => "v1.0",
101      incsuffix => "libpng10",
102      libbase => "png10",
103     },
104    ],
105   );
106
107 my $probe_res = Imager::Probe->probe(\%probe);
108 if ($probe_res) {
109   $IMAGER_LIBS{PNG} = 1;
110
111   push @inc, $probe_res->{INC};
112   $opts{LIBS} = $probe_res->{LIBS};
113   $opts{DEFINE} = $probe_res->{DEFINE};
114   $opts{INC} = "@inc";
115   
116   if ($MM_ver > 6.06) {
117     $opts{AUTHOR} = 'Tony Cook <tonyc@cpan.org>';
118     $opts{ABSTRACT} = 'PNG Image file support';
119   }
120   
121   WriteMakefile(%opts);
122 }
123 else {
124   $IMAGER_LIBS{PNG} = 0;
125
126   if ($BUILDING_IMAGER) {
127     ExtUtils::MakeMaker::WriteEmptyMakefile(%opts);
128   }
129   else {
130     # fail in good way
131     die "OS unsupported: PNG libraries or headers not found\n";
132   }
133 }
134
135 sub _png_test_code {
136   return <<'CODE';
137
138 fprintf(stderr, "PNG: library version %ld, header version %ld\n", (long)png_access_version_number(),  (long)PNG_LIBPNG_VER);
139 return 0;
140 CODE
141 }