PNG re-work: remove unused variables
[imager.git] / PNG / Makefile.PL
1 #!perl -w
2 use strict;
3 use ExtUtils::MakeMaker;
4 use Getopt::Long;
5 use Config;
6
7 my $verbose = $ENV{IM_VERBOSE};
8 my @libpaths;
9 my @incpaths;
10
11 GetOptions("incpath=s", \@incpaths,
12            "libpath=s" => \@libpaths,
13            "verbose|v" => \$verbose);
14
15 our $BUILDING_IMAGER;
16 our %IMAGER_LIBS;
17
18 my $MM_ver = eval $ExtUtils::MakeMaker::VERSION;
19
20 my %opts = 
21   (
22    NAME => 'Imager::File::PNG',
23    VERSION_FROM => 'PNG.pm',
24    OBJECT => 'PNG.o impng.o',
25    clean => { FILES => 'testout' },
26   );
27
28 my @inc;
29 if ($BUILDING_IMAGER) {
30   push @inc, "-I..";
31   unshift @INC, "../lib";
32 }
33 else {
34   unshift @INC, "inc";
35   print "PNG: building independently\n";
36   require Imager::ExtUtils;
37   push @inc, Imager::ExtUtils->includes;
38   $opts{TYPEMAPS} = [ Imager::ExtUtils->typemap ];
39
40   # Imager required configure through use
41   my @Imager_req = ( Imager => "0.90" );
42   if ($MM_ver >= 6.46) {
43     $opts{META_MERGE} =
44       {
45        configure_requires => 
46        {
47         @Imager_req,
48        },
49        build_requires => 
50        {
51         @Imager_req,
52         "Test::More" => "0.47",
53        },
54        resources =>
55        {
56         homepage => "http://imager.perl.org/",
57         repository => "git://git.imager.perl.org/imager.git",
58         bugtracker => "http://rt.cpan.org/NoAuth/Bugs.html?Dist=Imager",
59        },
60       };
61     $opts{PREREQ_PM} =
62       {
63        @Imager_req,
64        XSLoader => 0,
65       };
66   }
67 }
68
69 require Imager::Probe;
70
71 my @alts =
72   (
73    {
74     altname => "v1.5",
75     incsuffix => "libpng15",
76     libbase => "png15",
77    },
78    {
79     altname => "v1.4",
80     incsuffix => "libpng14",
81     libbase => "png14",
82    },
83    {
84     altname => "v1.2",
85     incsuffix => "libpng12",
86     libbase => "png12",
87    },
88    {
89     altname => "v1.0",
90     incsuffix => "libpng10",
91     libbase => "png10",
92    },
93   );
94
95 my %probe =
96   (
97    name => "PNG",
98    altname => "Generic",
99    pkg => [ qw/libpng15 libpng14 libpng12 libpng10 libpng/ ],
100    inccheck => sub { -e File::Spec->catfile($_[0], "png.h") },
101    libbase => "png",
102    testcode => _png_test_code(),
103    testcodeheaders => [ "png.h", "stdio.h" ],
104    incpath => \@incpaths,
105    libpath => \@libpaths,
106    alternatives =>
107    [
108     @alts,
109     {
110      altname => "base (+libz)",
111      libbase => [ "png", "z" ],
112     },
113     ( # a static libpng may require libz too
114      map +{
115            %$_,
116            altname => "$_->{altname} (+libz)",
117            libbase => [ $_->{libbase}, "z" ],
118           }, @alts
119     ),
120    ],
121   );
122
123 my $probe_res = Imager::Probe->probe(\%probe);
124 if ($probe_res) {
125   $IMAGER_LIBS{PNG} = 1;
126
127   push @inc, $probe_res->{INC};
128   $opts{LIBS} = $probe_res->{LIBS};
129   $opts{DEFINE} = $probe_res->{DEFINE};
130   $opts{INC} = "@inc";
131   
132   if ($MM_ver > 6.06) {
133     $opts{AUTHOR} = 'Tony Cook <tonyc@cpan.org>';
134     $opts{ABSTRACT} = 'PNG Image file support';
135   }
136   
137   WriteMakefile(%opts);
138 }
139 else {
140   $IMAGER_LIBS{PNG} = 0;
141
142   if ($BUILDING_IMAGER) {
143     ExtUtils::MakeMaker::WriteEmptyMakefile(%opts);
144   }
145   else {
146     # fail in good way
147     die "OS unsupported: PNG libraries or headers not found\n";
148   }
149 }
150
151 sub _png_test_code {
152   return <<'CODE';
153
154 fprintf(stderr, "PNG: library version %ld, header version %ld\n", (long)png_access_version_number(),  (long)PNG_LIBPNG_VER);
155 return 0;
156 CODE
157 }