e314bd36ae74b1215774f87c84f8eb42d2626f1d
[imager-screenshot.git] / Makefile.PL
1 #!perl -w
2 use strict;
3 use ExtUtils::MakeMaker;
4 use Imager 0.54;
5 use Imager::ExtUtils;
6 use Config;
7 use File::Spec;
8 use Getopt::Long;
9
10 my @incpaths; # places to look for headers
11 my @libpaths; # places to look for libraries
12
13 GetOptions("incpath=s", \@incpaths,
14            "libpath=s" => \@libpaths);
15
16 my @objs = qw/Screenshot.o/;
17 my @cflags;
18 my @lflags;
19 my %seen_incdir;
20 my %seen_libdir;
21 my $X11_lib = $^O eq 'cygwin' ? 'X11.dll' : 'X11';
22 if (find_header("X11/Xlib.h", "X11 header") 
23     and find_lib($X11_lib, "X11 library")) {
24   push @objs, 'scx11.o';
25   push @cflags, '-DSS_X11';
26   push @lflags, '-l'.$X11_lib;
27   print "Found X11\n";
28 }
29 if (find_header('windows.h', "Win32 header")
30     and find_lib('gdi32', "Win32 library")) {
31   push @objs, 'scwin32.o';
32   push @cflags, '-DSS_WIN32';
33   if ($^O eq 'cygwin') {
34     push @lflags, '-L/usr/lib/w32api', '-lgdi32';
35   }
36   print "Found Win32\n";
37 }
38
39 unless (@objs > 1) {
40   die <<DEAD;
41
42 NA: Sorry, I can't find headers or libraries for a supported GUI
43 You need to install development headers and libraries for your GUI
44 For Win32: Platform SDK or a substitute
45 For X11: X11 headers and libraries, eg. the libX11-dev package on Debian
46
47 DEAD
48 }
49
50 my $extra_meta = <<META;
51 configure_requires:
52   Imager: 0.54
53 build_requires:
54   Imager: 0.54
55   Test::More: 0.47
56 META
57
58 my %opts = 
59   (
60    NAME => 'Imager::Screenshot',
61    VERSION_FROM => 'Screenshot.pm',
62    OBJECT => "@objs",
63    PREREQ_PM => {
64                  'Imager'    => 0.54,
65                 },
66    INC => Imager::ExtUtils->includes,
67    TYPEMAPS => [ Imager::ExtUtils->typemap ],
68    EXTRA_META => $extra_meta,
69   );
70
71 $opts{LIBS} = "@lflags" if @lflags;
72 $opts{INC} .= " @cflags" if @cflags;
73
74 # avoid "... isn't numberic in numeric gt ..." warnings for dev versions
75 my $eu_mm_version = eval $ExtUtils::MakeMaker::VERSION;
76 if ($eu_mm_version > 6.06) {
77   $opts{AUTHOR} = 'Tony Cook <tonyc@cpan.org>';
78   $opts{ABSTRACT} = 'Screen/Window capture to Imager images';
79 }
80
81 # LICENSE was introduced in 6.30_01, but Debian etch includes
82 # (as of 2007/01/12) an ExtUtils::MakeMaker versioned 6.30_01 without
83 # LICENSE support
84 if ($eu_mm_version > 6.3001) {
85   $opts{LICENSE} = 'perl';
86 }
87
88 WriteMakefile(%opts);
89
90 my @incs;
91 sub header_search_path {
92   @incs and return @incs;
93
94   push @incs, map {; split /\Q$Config{path_sep}/ } @incpaths;
95   push @incs, split /\Q$Config{path_sep}/, $ENV{IM_INCPATH}
96     if defined $ENV{IM_INCPATH};
97   push @incs, '/usr/include', '/usr/X11R6/include'
98     unless $^O eq 'MSWin32' && $Config{cc} =~ /\bcl\b/;
99   push @incs, split /\Q$Config{path_sep}/, $ENV{INCLUDE}
100     if $^O eq 'MSWin32' && $Config{cc} =~ /\bcl\b/ and $ENV{INCLUDE};
101   push @incs, split ' ', $Config{locincpth}
102     if $Config{locincpth};
103   push @incs, split /\Q$Config{path_sep}/, $Config{incpath}
104     if $Config{incpath};
105   push @incs, '/usr/include/w32api', '/usr/X11R6/include'
106     if $^O eq 'cygwin';
107
108   @incs = grep -d, @incs;
109
110   @incs;
111 }
112
113 my @libs;
114 sub library_search_path {
115   @libs and return @libs;
116
117   push @libs, map {; split /\Q$Config{path_sep}/ } @libpaths;
118   push @incs, split /\Q$Config{path_sep}/, $ENV{IM_LIBPATH}
119     if defined $ENV{IM_LIBPATH};
120   push @libs, '/usr/lib', '/usr/X11R6/lib'
121     unless $^O eq 'MSWin32' && $Config{cc} =~ /\bcl\b/;
122   push @libs, split /\Q$Config{path_sep}/, $ENV{LIB}
123     if $^O eq 'MSWin32' && $Config{cc} =~ /\bcl\b/ and $ENV{LIB};
124   push @libs, split ' ', $Config{loclibpth}
125     if $Config{loclibpth};
126   push @libs, split /\Q$Config{path_sep}/, $Config{libpth}
127     if $Config{libpth};
128   push @libs, '/usr/lib/w32api', '/usr/X11R6/lib'
129     if $^O eq 'cygwin';
130
131   @libs = grep -d, @libs;
132
133   @libs;
134 }
135
136 sub _find_file {
137   my ($name, @where) = @_;
138
139   grep -f File::Spec->catfile($_, $name), @where;
140 }
141
142 sub find_header {
143   my ($name, $description) = @_;
144   my @found = _find_file($_[0], header_search_path());
145
146   if (@found) {
147     push @cflags, "-I$_" for grep !$seen_incdir{$_}, @found;
148     @seen_incdir{@found} = (1) x @found;
149   }
150   else {
151     print STDERR "Could not find $name ($description)\n";
152   }
153
154   @found;
155 }
156
157 sub find_lib {
158   my ($name, $description) = shift;
159   my @found;
160   my $libname;
161   if ($^O eq 'MSWin32' && $Config{_a} eq '.lib') {
162     $libname = $name . $Config{_a};
163   }
164   else {
165     $libname = "lib" . $name . $Config{_a};
166   }
167   @found = _find_file($libname, library_search_path());
168   if (@found) {
169     push @lflags, "-L$_" for grep !$seen_libdir{$_}, @found;
170     @seen_libdir{@found} = (1) x @found;
171   }
172   else {
173     print STDERR "Could not find $libname ($description)\n";
174   }
175
176   @found;
177 }