- die with a message automated cpan testers treat as a non-fail when
[imager-screenshot.git] / Makefile.PL
1 #!perl -w
2 use strict;
3 use ExtUtils::MakeMaker;
4 use Imager 0.54;
5 use Imager::ExtUtils;
6 use Config;
7 use File::Spec;
8 use Getopt::Long;
9
10 my @incpaths; # places to look for headers
11 my @libpaths; # places to look for libraries
12
13 GetOptions("incpath=s", \@incpaths,
14            "libpath=s" => \@libpaths);
15
16 my @objs = qw/Screenshot.o/;
17 my @cflags;
18 my @lflags;
19 my %seen_incdir;
20 my %seen_libdir;
21 my $X11_lib = $^O eq 'cygwin' ? 'X11.dll' : 'X11';
22 if (find_header("X11/Xlib.h", "X11 header") 
23     and find_lib($X11_lib, "X11 library")) {
24   push @objs, 'scx11.o';
25   push @cflags, '-DSS_X11';
26   push @lflags, '-l'.$X11_lib;
27   print "Found X11\n";
28 }
29 if (find_header('windows.h', "Win32 header")
30     and find_lib('gdi32', "Win32 library")) {
31   push @objs, 'scwin32.o';
32   push @cflags, '-DSS_WIN32';
33   if ($^O eq 'cygwin') {
34     push @lflags, '-L/usr/lib/w32api', '-lgdi32';
35   }
36   print "Found Win32\n";
37 }
38
39 unless (@objs > 1) {
40   die <<DEAD;
41 OS unsupported: Headers or libraries not found for a supported GUI
42
43 Sorry, I can't find headers or libraries for a supported GUI
44 You need to install development headers and libraries for your GUI
45 For Win32: Platform SDK or a substitute
46 For X11: X11 headers and libraries, eg. the libX11-dev package on Debian
47
48 DEAD
49 }
50
51 my %opts = 
52   (
53    NAME => 'Imager::Screenshot',
54    VERSION_FROM => 'Screenshot.pm',
55    OBJECT => "@objs",
56    PREREQ_PM => {
57                  'Imager'    => 0.54,
58                 },
59    INC => Imager::ExtUtils->includes,
60    TYPEMAPS => [ Imager::ExtUtils->typemap ],
61   );
62
63 $opts{LIBS} = "@lflags" if @lflags;
64 $opts{INC} .= " @cflags" if @cflags;
65
66 # avoid "... isn't numberic in numeric gt ..." warnings for dev versions
67 my $eu_mm_version = eval $ExtUtils::MakeMaker::VERSION;
68 if ($eu_mm_version > 6.06) {
69   $opts{AUTHOR} = 'Tony Cook <tonyc@cpan.org>';
70   $opts{ABSTRACT} = 'Screen/Window capture to Imager images';
71 }
72
73 # LICENSE was introduced in 6.30_01, but Debian etch includes
74 # (as of 2007/01/12) an ExtUtils::MakeMaker versioned 6.30_01 without
75 # LICENSE support
76 # EXTRA_META was also introduced in 6.30_01
77 if ($eu_mm_version > 6.3001) {
78   $opts{LICENSE} = 'perl';
79   $opts{EXTRA_META} = <<META;
80 configure_requires:
81   Imager: 0.54
82 build_requires:
83   Imager: 0.54
84   Test::More: 0.47
85 META
86 }
87
88 WriteMakefile(%opts);
89
90 my @incs;
91 sub header_search_path {
92   @incs and return @incs;
93
94   push @incs, map {; split /\Q$Config{path_sep}/ } @incpaths;
95   push @incs, split /\Q$Config{path_sep}/, $ENV{IM_INCPATH}
96     if defined $ENV{IM_INCPATH};
97   push @incs, '/usr/include', '/usr/X11R6/include'
98     unless $^O eq 'MSWin32' && $Config{cc} =~ /\bcl\b/;
99   push @incs, split /\Q$Config{path_sep}/, $ENV{INCLUDE}
100     if $^O eq 'MSWin32' && $Config{cc} =~ /\bcl\b/ and $ENV{INCLUDE};
101   push @incs, split ' ', $Config{locincpth}
102     if $Config{locincpth};
103   push @incs, split /\Q$Config{path_sep}/, $Config{incpath}
104     if $Config{incpath};
105   push @incs, '/usr/include/w32api', '/usr/X11R6/include'
106     if $^O eq 'cygwin';
107
108   @incs = grep -d, @incs;
109
110   @incs;
111 }
112
113 my @libs;
114 sub library_search_path {
115   @libs and return @libs;
116
117   push @libs, map {; split /\Q$Config{path_sep}/ } @libpaths;
118   push @incs, split /\Q$Config{path_sep}/, $ENV{IM_LIBPATH}
119     if defined $ENV{IM_LIBPATH};
120   push @libs, '/usr/lib', '/usr/X11R6/lib'
121     unless $^O eq 'MSWin32' && $Config{cc} =~ /\bcl\b/;
122   push @libs, split /\Q$Config{path_sep}/, $ENV{LIB}
123     if $^O eq 'MSWin32' && $Config{cc} =~ /\bcl\b/ and $ENV{LIB};
124   push @libs, split ' ', $Config{loclibpth}
125     if $Config{loclibpth};
126   push @libs, split /\Q$Config{path_sep}/, $Config{libpth}
127     if $Config{libpth};
128   push @libs, '/usr/lib/w32api', '/usr/X11R6/lib'
129     if $^O eq 'cygwin';
130
131   @libs = grep -d, @libs;
132
133   @libs;
134 }
135
136 sub _find_file {
137   my ($name, @where) = @_;
138
139   grep -f File::Spec->catfile($_, $name), @where;
140 }
141
142 sub find_header {
143   my ($name, $description) = @_;
144   my @found = _find_file($_[0], header_search_path());
145
146   if (@found) {
147     push @cflags, "-I$_" for grep !$seen_incdir{$_}, @found;
148     @seen_incdir{@found} = (1) x @found;
149   }
150   else {
151     print STDERR "Could not find $name ($description)\n";
152   }
153
154   @found;
155 }
156
157 sub find_lib {
158   my ($name, $description) = shift;
159   my @found;
160   my $libname;
161   if ($^O eq 'MSWin32' && $Config{_a} eq '.lib') {
162     $libname = $name . $Config{_a};
163     @found = _find_file($libname, library_search_path());
164   }
165   else {
166     $libname = "lib" . $name . $Config{_a};
167     @found = _find_file($libname, library_search_path());
168     if (!@found && $Config{so}) {
169       $libname = "lib" . $name . "." . $Config{so};
170       @found = _find_file($libname, library_search_path());
171     }
172   }
173   if (@found) {
174     push @lflags, "-L$_" for grep !$seen_libdir{$_}, @found;
175     @seen_libdir{@found} = (1) x @found;
176   }
177   else {
178     print STDERR "Could not find $libname ($description)\n";
179   }
180
181   @found;
182 }