Makefile.PL

   1 #!perl -w
   2 use strict;
   3 use ExtUtils::MakeMaker;
   4 use Imager 0.54;
   5 use Imager::ExtUtils;
   6 use Config;
   7 use File::Spec;
   8 use Getopt::Long;
   9
  10 my @incpaths; # places to look for headers
  11 my @libpaths; # places to look for libraries
  12
  13 GetOptions("incpath=s", \@incpaths,
  14            "libpath=s" => \@libpaths);
  15
  16 my @objs = qw/Screenshot.o/;
  17 my @cflags;
  18 my @lflags;
  19 my %seen_incdir;
  20 my %seen_libdir;
  21 my $X11_lib = $^O eq 'cygwin' ? 'X11.dll' : 'X11';
  22 if (find_header("X11/Xlib.h", "X11 header")
  23     and find_lib($X11_lib, "X11 library")) {
  24   push @objs, 'scx11.o';
  25   push @cflags, '-DSS_X11';
  26   push @lflags, '-l'.$X11_lib;
  27   print "Found X11\n";
  28 }
  29 if (find_header('windows.h', "Win32 header")
  30     and find_lib('gdi32', "Win32 library")) {
  31   push @objs, 'scwin32.o';
  32   push @cflags, '-DSS_WIN32';
  33   if ($^O eq 'cygwin') {
  34     push @lflags, '-L/usr/lib/w32api', '-lgdi32';
  35   }
  36   print "Found Win32\n";
  37 }
  38
  39 unless (@objs > 1) {
  40   die <<DEAD;
  41 OS unsupported: Headers or libraries not found for a supported GUI
  42
  43 Sorry, I can't find headers or libraries for a supported GUI
  44 You need to install development headers and libraries for your GUI
  45 For Win32: Platform SDK or a substitute
  46 For X11: X11 headers and libraries, eg. the libX11-dev package on Debian
  47
  48 DEAD
  49 }
  50
  51 my %opts =
  52   (
  53    NAME => 'Imager::Screenshot',
  54    VERSION_FROM => 'Screenshot.pm',
  55    OBJECT => "@objs",
  56    PREREQ_PM => {
  57                  'Imager'    => 0.54,
  58                 },
  59    INC => Imager::ExtUtils->includes,
  60    TYPEMAPS => [ Imager::ExtUtils->typemap ],
  61   );
  62
  63 $opts{LIBS} = "@lflags" if @lflags;
  64 $opts{INC} .= " @cflags" if @cflags;
  65
  66 # avoid "... isn't numberic in numeric gt ..." warnings for dev versions
  67 my $eu_mm_version = eval $ExtUtils::MakeMaker::VERSION;
  68 if ($eu_mm_version > 6.06) {
  69   $opts{AUTHOR} = 'Tony Cook <tonyc@cpan.org>';
  70   $opts{ABSTRACT} = 'Screen/Window capture to Imager images';
  71 }
  72
  73 # LICENSE was introduced in 6.30_01, but Debian etch includes
  74 # (as of 2007/01/12) an ExtUtils::MakeMaker versioned 6.30_01 without
  75 # LICENSE support
  76 # EXTRA_META was also introduced in 6.30_01
  77 if ($eu_mm_version > 6.3001) {
  78   $opts{LICENSE} = 'perl';
  79 }
  80 if ($eu_mm_version >= 6.46) {
  81   $opts{META_MERGE} =
  82     {
  83      configure_requires =>
  84      {
  85       Imager => "0.54"
  86      },
  87      build_requires =>
  88      {
  89       Imager => "0.54",
  90       "Test::More" => "0.47",
  91      }
  92     };
  93 }
  94
  95 WriteMakefile(%opts);
  96
  97 my @incs;
  98 sub header_search_path {
  99   @incs and return @incs;
 100
 101   push @incs, map {; split /\Q$Config{path_sep}/ } @incpaths;
 102   push @incs, split /\Q$Config{path_sep}/, $ENV{IM_INCPATH}
 103     if defined $ENV{IM_INCPATH};
 104   push @incs, '/usr/include', '/usr/X11R6/include'
 105     unless $^O eq 'MSWin32' && $Config{cc} =~ /\bcl\b/;
 106   push @incs, split /\Q$Config{path_sep}/, $ENV{INCLUDE}
 107     if $^O eq 'MSWin32' && $Config{cc} =~ /\bcl\b/ and $ENV{INCLUDE};
 108   push @incs, split ' ', $Config{locincpth}
 109     if $Config{locincpth};
 110   push @incs, split /\Q$Config{path_sep}/, $Config{incpath}
 111     if $Config{incpath};
 112   push @incs, '/usr/include/w32api', '/usr/X11R6/include'
 113     if $^O eq 'cygwin';
 114
 115   @incs = grep -d, @incs;
 116
 117   @incs;
 118 }
 119
 120 my @libs;
 121 sub library_search_path {
 122   @libs and return @libs;
 123
 124   push @libs, map {; split /\Q$Config{path_sep}/ } @libpaths;
 125   push @incs, split /\Q$Config{path_sep}/, $ENV{IM_LIBPATH}
 126     if defined $ENV{IM_LIBPATH};
 127   push @libs, '/usr/lib', '/usr/X11R6/lib'
 128     unless $^O eq 'MSWin32' && $Config{cc} =~ /\bcl\b/;
 129   push @libs, split /\Q$Config{path_sep}/, $ENV{LIB}
 130     if $^O eq 'MSWin32' && $Config{cc} =~ /\bcl\b/ and $ENV{LIB};
 131   push @libs, split ' ', $Config{loclibpth}
 132     if $Config{loclibpth};
 133   push @libs, split /\Q$Config{path_sep}/, $Config{libpth}
 134     if $Config{libpth};
 135   push @libs, '/usr/lib/w32api', '/usr/X11R6/lib'
 136     if $^O eq 'cygwin';
 137
 138   @libs = grep -d, @libs;
 139
 140   @libs;
 141 }
 142
 143 sub _find_file {
 144   my ($name, @where) = @_;
 145
 146   grep -f File::Spec->catfile($_, $name), @where;
 147 }
 148
 149 sub find_header {
 150   my ($name, $description) = @_;
 151   my @found = _find_file($_[0], header_search_path());
 152
 153   if (@found) {
 154     push @cflags, "-I$_" for grep !$seen_incdir{$_}, @found;
 155     @seen_incdir{@found} = (1) x @found;
 156   }
 157   else {
 158     print STDERR "Could not find $name ($description)\n";
 159   }
 160
 161   @found;
 162 }
 163
 164 sub find_lib {
 165   my ($name, $description) = shift;
 166   my @found;
 167   my $libname;
 168   if ($^O eq 'MSWin32' && $Config{_a} eq '.lib') {
 169     $libname = $name . $Config{_a};
 170     @found = _find_file($libname, library_search_path());
 171   }
 172   else {
 173     $libname = "lib" . $name . $Config{_a};
 174     @found = _find_file($libname, library_search_path());
 175     if (!@found && $Config{so}) {
 176       $libname = "lib" . $name . "." . $Config{so};
 177       @found = _find_file($libname, library_search_path());
 178     }
 179   }
 180   if (@found) {
 181     push @lflags, "-L$_" for grep !$seen_libdir{$_}, @found;
 182     @seen_libdir{@found} = (1) x @found;
 183   }
 184   else {
 185     print STDERR "Could not find $libname ($description)\n";
 186   }
 187
 188   @found;
 189 }