lib/Imager/Graph/Vertical.pm

   1 package Imager::Graph::Vertical;
   2
   3 =head1 NAME
   4
   5   Imager::Graph::Vertical- A super class for line/bar/column charts
   6
   7 =cut
   8
   9 use strict;
  10 use vars qw(@ISA);
  11 use Imager::Graph;
  12 @ISA = qw(Imager::Graph);
  13
  14 use constant STARTING_MIN_VALUE => 99999;
  15 =over 4
  16
  17 =item add_data_series(\@data, $series_name)
  18
  19 Add a data series to the graph, of the default type.
  20
  21 =cut
  22
  23 sub add_data_series {
  24   my $self = shift;
  25   my $data_ref = shift;
  26   my $series_name = shift;
  27
  28   my $series_type = $self->_get_default_series_type();
  29   $self->_add_data_series($series_type, $data_ref, $series_name);
  30
  31   return;
  32 }
  33
  34 =item add_column_data_series(\@data, $series_name)
  35
  36 Add a column data series to the graph.
  37
  38 =cut
  39
  40 sub add_column_data_series {
  41   my $self = shift;
  42   my $data_ref = shift;
  43   my $series_name = shift;
  44
  45   $self->_add_data_series('column', $data_ref, $series_name);
  46
  47   return;
  48 }
  49
  50 =item add_stacked_column_data_series(\@data, $series_name)
  51
  52 Add a stacked column data series to the graph.
  53
  54 =cut
  55
  56 sub add_stacked_column_data_series {
  57   my $self = shift;
  58   my $data_ref = shift;
  59   my $series_name = shift;
  60
  61   $self->_add_data_series('stacked_column', $data_ref, $series_name);
  62
  63   return;
  64 }
  65
  66 =item add_line_data_series(\@data, $series_name)
  67
  68 Add a line data series to the graph.
  69
  70 =cut
  71
  72 sub add_line_data_series {
  73   my $self = shift;
  74   my $data_ref = shift;
  75   my $series_name = shift;
  76
  77   $self->_add_data_series('line', $data_ref, $series_name);
  78
  79   return;
  80 }
  81
  82 =item set_y_max($value)
  83
  84 Sets the maximum y value to be displayed.  This will be ignored if the y_max is lower than the highest value.
  85
  86 =cut
  87
  88 sub set_y_max {
  89   $_[0]->{'custom_style'}->{'y_max'} = $_[1];
  90 }
  91
  92 =item set_y_min($value)
  93
  94 Sets the minimum y value to be displayed.  This will be ignored if the y_min is higher than the lowest value.
  95
  96 =cut
  97
  98 sub set_y_min {
  99   $_[0]->{'custom_style'}->{'y_min'} = $_[1];
 100 }
 101
 102 =item set_column_padding($int)
 103
 104 Sets the padding between columns.  This is a percentage of the column width.  Defaults to 0.
 105
 106 =cut
 107
 108 sub set_column_padding {
 109   $_[0]->{'custom_style'}->{'column_padding'} = $_[1];
 110 }
 111
 112 =item set_range_padding($percentage)
 113
 114 Sets the padding to be used, as a percentage.  For example, if your data ranges from 0 to 10, and you have a 20 percent padding, the y axis will go to 12.
 115
 116 Defaults to 10.  This attribute is ignored for positive numbers if set_y_max() has been called, and ignored for negative numbers if set_y_min() has been called.
 117
 118 =cut
 119
 120 sub set_range_padding {
 121   $_[0]->{'custom_style'}->{'range_padding'} = $_[1];
 122 }
 123
 124 =item set_negative_background($color)
 125
 126 Sets the background color used below the x axis.
 127
 128 =cut
 129
 130 sub set_negative_background {
 131   $_[0]->{'custom_style'}->{'negative_bg'} = $_[1];
 132 }
 133
 134 =item draw()
 135
 136 Draw the graph
 137
 138 =cut
 139
 140 sub draw {
 141   my ($self, %opts) = @_;
 142
 143   if (!$self->_valid_input()) {
 144     return;
 145   }
 146
 147   $self->_style_setup(\%opts);
 148
 149   my $style = $self->{_style};
 150
 151   my $img = $self->_get_image()
 152     or return;
 153
 154   my @image_box = ( 0, 0, $img->getwidth-1, $img->getheight-1 );
 155   $self->_set_image_box(\@image_box);
 156
 157   my @chart_box = ( 0, 0, $img->getwidth-1, $img->getheight-1 );
 158   $self->_draw_legend(\@chart_box);
 159   if ($style->{title}{text}) {
 160     $self->_draw_title($img, \@chart_box)
 161       or return;
 162   }
 163
 164   # Scale the graph box down to the widest graph that can cleanly hold the # of columns.
 165   return unless $self->_get_data_range();
 166   $self->_remove_tics_from_chart_box(\@chart_box);
 167   my $column_count = $self->_get_column_count();
 168
 169   my $width = $self->_get_number('width');
 170   my $height = $self->_get_number('height');
 171
 172   my $graph_width = $chart_box[2] - $chart_box[0];
 173   my $graph_height = $chart_box[3] - $chart_box[1];
 174
 175   my $col_width = int(($graph_width - 1) / $column_count) -1;
 176   $graph_width = $col_width * $column_count + 1;
 177
 178   my $tic_count = $self->_get_y_tics();
 179   my $tic_distance = int(($graph_height-1) / ($tic_count - 1));
 180   $graph_height = $tic_distance * ($tic_count - 1);
 181
 182   my $bottom = $chart_box[1];
 183   my $left   = $chart_box[0];
 184
 185   $self->{'_style'}{'graph_width'} = $graph_width;
 186   $self->{'_style'}{'graph_height'} = $graph_height;
 187
 188   my @graph_box = ($left, $bottom, $left + $graph_width, $bottom + $graph_height);
 189   $self->_set_graph_box(\@graph_box);
 190
 191   $img->box(
 192             color   => $self->_get_color('outline.line'),
 193             xmin    => $left,
 194             xmax    => $left+$graph_width,
 195             ymin    => $bottom,
 196             ymax    => $bottom+$graph_height,
 197             );
 198
 199   $img->box(
 200             color   => $self->_get_color('bg'),
 201             xmin    => $left + 1,
 202             xmax    => $left+$graph_width - 1,
 203             ymin    => $bottom + 1,
 204             ymax    => $bottom+$graph_height-1 ,
 205             filled  => 1,
 206             );
 207
 208   my $min_value = $self->_get_min_value();
 209   my $max_value = $self->_get_max_value();
 210   my $value_range = $max_value - $min_value;
 211
 212   my $zero_position;
 213   if ($value_range) {
 214     $zero_position =  $bottom + $graph_height - (-1*$min_value / $value_range) * ($graph_height-1);
 215   }
 216
 217   if ($min_value < 0) {
 218     $img->box(
 219             color   => $self->_get_color('negative_bg'),
 220             xmin    => $left + 1,
 221             xmax    => $left+$graph_width- 1,
 222             ymin    => $zero_position,
 223             ymax    => $bottom+$graph_height - 1,
 224             filled  => 1,
 225     );
 226     $img->line(
 227             x1 => $left+1,
 228             y1 => $zero_position,
 229             x2 => $left + $graph_width,
 230             y2 => $zero_position,
 231             color => $self->_get_color('outline.line'),
 232     );
 233   }
 234
 235   if ($self->_get_data_series()->{'stacked_column'}) {
 236     return unless $self->_draw_stacked_columns();
 237   }
 238   if ($self->_get_data_series()->{'column'}) {
 239     return unless $self->_draw_columns();
 240   }
 241   if ($self->_get_data_series()->{'line'}) {
 242     return unless $self->_draw_lines();
 243   }
 244
 245   if ($self->_get_y_tics()) {
 246     $self->_draw_y_tics();
 247   }
 248   if ($self->_get_labels()) {
 249     $self->_draw_x_tics();
 250   }
 251
 252   return $self->_get_image();
 253 }
 254
 255 sub _get_data_range {
 256   my $self = shift;
 257
 258   my $max_value = 0;
 259   my $min_value = 0;
 260   my $column_count = 0;
 261
 262   my ($sc_min, $sc_max, $sc_cols) = $self->_get_stacked_column_range();
 263   my ($c_min, $c_max, $c_cols) = $self->_get_column_range();
 264   my ($l_min, $l_max, $l_cols) = $self->_get_line_range();
 265
 266   # These are side by side...
 267   $sc_cols += $c_cols;
 268
 269   $min_value = $self->_min(STARTING_MIN_VALUE, $sc_min, $c_min, $l_min);
 270   $max_value = $self->_max(0, $sc_max, $c_max, $l_max);
 271
 272   my $config_min = $self->_get_number('y_min');
 273   my $config_max = $self->_get_number('y_max');
 274
 275   if (defined $config_max && $config_max < $max_value) {
 276     $config_max = undef;
 277   }
 278   if (defined $config_min && $config_min > $min_value) {
 279     $config_min = undef;
 280   }
 281
 282   my $range_padding = $self->_get_number('range_padding');
 283   if (defined $config_min) {
 284     $min_value = $config_min;
 285   }
 286   else {
 287     if ($min_value > 0) {
 288       $min_value = 0;
 289     }
 290     if ($range_padding && $min_value < 0) {
 291       my $difference = $min_value * $range_padding / 100;
 292       if ($min_value < -1 && $difference > -1) {
 293         $difference = -1;
 294       }
 295       $min_value += $difference;
 296     }
 297   }
 298   if (defined $config_max) {
 299     $max_value = $config_max;
 300   }
 301   else {
 302     if ($range_padding && $max_value > 0) {
 303       my $difference = $max_value * $range_padding / 100;
 304       if ($max_value > 1 && $difference < 1) {
 305         $difference = 1;
 306       }
 307       $max_value += $difference;
 308     }
 309   }
 310   $column_count = $self->_max(0, $sc_cols, $l_cols);
 311
 312   if ($self->_get_number('automatic_axis')) {
 313     # In case this was set via a style, and not by the api method
 314     eval { require Chart::Math::Axis; };
 315     if ($@) {
 316       return $self->_error("Can't use automatic_axis - $@");
 317     }
 318
 319     my $axis = Chart::Math::Axis->new();
 320     $axis->include_zero();
 321     $axis->add_data($min_value, $max_value);
 322     $max_value = $axis->top;
 323     $min_value = $axis->bottom;
 324     my $ticks     = $axis->ticks;
 325     # The +1 is there because we have the bottom tick as well
 326     $self->set_y_tics($ticks+1);
 327   }
 328
 329   $self->_set_max_value($max_value);
 330   $self->_set_min_value($min_value);
 331   $self->_set_column_count($column_count);
 332
 333   return 1;
 334 }
 335
 336 sub _min {
 337   my $self = shift;
 338   my $min = shift;
 339
 340   foreach my $value (@_) {
 341     next unless defined $value;
 342     if ($value < $min) { $min = $value; }
 343   }
 344   return $min;
 345 }
 346
 347 sub _max {
 348   my $self = shift;
 349   my $min = shift;
 350
 351   foreach my $value (@_) {
 352     next unless defined $value;
 353     if ($value > $min) { $min = $value; }
 354   }
 355   return $min;
 356 }
 357
 358 sub _get_line_range {
 359   my $self = shift;
 360   my $series = $self->_get_data_series()->{'line'};
 361   return (undef, undef, 0) unless $series;
 362
 363   my $max_value = 0;
 364   my $min_value = STARTING_MIN_VALUE;
 365   my $column_count = 0;
 366
 367   my @series = @{$series};
 368   foreach my $series (@series) {
 369     my @data = @{$series->{'data'}};
 370
 371     if (scalar @data > $column_count) {
 372       $column_count = scalar @data;
 373     }
 374
 375     foreach my $value (@data) {
 376       if ($value > $max_value) { $max_value = $value; }
 377       if ($value < $min_value) { $min_value = $value; }
 378     }
 379   }
 380
 381   return ($min_value, $max_value, $column_count);
 382 }
 383
 384 sub _get_column_range {
 385   my $self = shift;
 386
 387   my $series = $self->_get_data_series()->{'column'};
 388   return (undef, undef, 0) unless $series;
 389
 390   my $max_value = 0;
 391   my $min_value = STARTING_MIN_VALUE;
 392   my $column_count = 0;
 393
 394   my @series = @{$series};
 395   foreach my $series (@series) {
 396     my @data = @{$series->{'data'}};
 397
 398     foreach my $value (@data) {
 399       $column_count++;
 400       if ($value > $max_value) { $max_value = $value; }
 401       if ($value < $min_value) { $min_value = $value; }
 402     }
 403   }
 404
 405   return ($min_value, $max_value, $column_count);
 406 }
 407
 408 sub _get_stacked_column_range {
 409   my $self = shift;
 410
 411   my $max_value = 0;
 412   my $min_value = STARTING_MIN_VALUE;
 413   my $column_count = 0;
 414
 415   return (undef, undef, 0) unless $self->_get_data_series()->{'stacked_column'};
 416   my @series = @{$self->_get_data_series()->{'stacked_column'}};
 417
 418   my @max_entries;
 419   my @min_entries;
 420   for (my $i = scalar @series - 1; $i >= 0; $i--) {
 421     my $series = $series[$i];
 422     my $data = $series->{'data'};
 423
 424     for (my $i = 0; $i < scalar @$data; $i++) {
 425       my $value = 0;
 426       if ($data->[$i] > 0) {
 427         $value = $data->[$i] + ($max_entries[$i] || 0);
 428         $data->[$i] = $value;
 429         $max_entries[$i] = $value;
 430       }
 431       elsif ($data->[$i] < 0) {
 432         $value = $data->[$i] + ($min_entries[$i] || 0);
 433         $data->[$i] = $value;
 434         $min_entries[$i] = $value;
 435       }
 436       if ($value > $max_value) { $max_value = $value; }
 437       if ($value < $min_value) { $min_value = $value; }
 438     }
 439     if (scalar @$data > $column_count) {
 440       $column_count = scalar @$data;
 441     }
 442   }
 443
 444   return ($min_value, $max_value, $column_count);
 445 }
 446
 447 sub _draw_legend {
 448   my $self = shift;
 449   my $chart_box = shift;
 450   my $style = $self->{'_style'};
 451
 452   my @labels;
 453   my $img = $self->_get_image();
 454   if (my $series = $self->_get_data_series()->{'stacked_column'}) {
 455     push @labels, map { $_->{'series_name'} } @$series;
 456   }
 457   if (my $series = $self->_get_data_series()->{'column'}) {
 458     push @labels, map { $_->{'series_name'} } @$series;
 459   }
 460   if (my $series = $self->_get_data_series()->{'line'}) {
 461     push @labels, map { $_->{'series_name'} } @$series;
 462   }
 463
 464   if ($style->{features}{legend} && (scalar @labels)) {
 465     $self->SUPER::_draw_legend($self->_get_image(), \@labels, $chart_box)
 466       or return;
 467   }
 468   return;
 469 }
 470
 471 sub _draw_flat_legend {
 472   return 1;
 473 }
 474
 475 sub _draw_lines {
 476   my $self = shift;
 477   my $style = $self->{'_style'};
 478
 479   my $img = $self->_get_image();
 480
 481   my $max_value = $self->_get_max_value();
 482   my $min_value = $self->_get_min_value();
 483   my $column_count = $self->_get_column_count();
 484
 485   my $value_range = $max_value - $min_value;
 486
 487   my $width = $self->_get_number('width');
 488   my $height = $self->_get_number('height');
 489
 490   my $graph_width = $self->_get_number('graph_width');
 491   my $graph_height = $self->_get_number('graph_height');
 492
 493   my $line_series = $self->_get_data_series()->{'line'};
 494   my $series_counter = $self->_get_series_counter() || 0;
 495
 496   my $has_columns = (defined $self->_get_data_series()->{'column'} || $self->_get_data_series->{'stacked_column'}) ? 1 : 0;
 497
 498   my $col_width = int($graph_width / $column_count) -1;
 499
 500   my $graph_box = $self->_get_graph_box();
 501   my $left = $graph_box->[0] + 1;
 502   my $bottom = $graph_box->[1];
 503
 504   my $zero_position =  $bottom + $graph_height - (-1*$min_value / $value_range) * ($graph_height - 1);
 505
 506
 507   my $line_aa = $self->_get_number("lineaa");
 508   foreach my $series (@$line_series) {
 509     my @data = @{$series->{'data'}};
 510     my $data_size = scalar @data;
 511
 512     my $interval;
 513     if ($has_columns) {
 514       $interval = $graph_width / ($data_size);
 515     }
 516     else {
 517       $interval = $graph_width / ($data_size - 1);
 518     }
 519     my $color = $self->_data_color($series_counter);
 520
 521     # We need to add these last, otherwise the next line segment will overwrite half of the marker
 522     my @marker_positions;
 523     for (my $i = 0; $i < $data_size - 1; $i++) {
 524       my $x1 = $left + $i * $interval;
 525       my $x2 = $left + ($i + 1) * $interval;
 526
 527       $x1 += $has_columns * $interval / 2;
 528       $x2 += $has_columns * $interval / 2;
 529
 530       my $y1 = $bottom + ($value_range - $data[$i] + $min_value)/$value_range * $graph_height;
 531       my $y2 = $bottom + ($value_range - $data[$i + 1] + $min_value)/$value_range * $graph_height;
 532
 533       push @marker_positions, [$x1, $y1];
 534       $img->line(x1 => $x1, y1 => $y1, x2 => $x2, y2 => $y2, aa => $line_aa, color => $color) || die $img->errstr;
 535     }
 536
 537     my $x2 = $left + ($data_size - 1) * $interval;
 538     $x2 += $has_columns * $interval / 2;
 539
 540     my $y2 = $bottom + ($value_range - $data[$data_size - 1] + $min_value)/$value_range * $graph_height;
 541
 542     push @marker_positions, [$x2, $y2];
 543     foreach my $position (@marker_positions) {
 544       $self->_draw_line_marker($position->[0], $position->[1], $series_counter);
 545     }
 546     $series_counter++;
 547   }
 548
 549   $self->_set_series_counter($series_counter);
 550   return 1;
 551 }
 552
 553 sub _line_marker {
 554   my ($self, $index) = @_;
 555
 556   my $markers = $self->{'_style'}{'line_markers'};
 557   if (!$markers) {
 558     return;
 559   }
 560   my $marker = $markers->[$index % @$markers];
 561
 562   return $marker;
 563 }
 564
 565 sub _draw_line_marker {
 566   my $self = shift;
 567   my ($x1, $y1, $series_counter) = @_;
 568
 569   my $img = $self->_get_image();
 570
 571   my $style = $self->_line_marker($series_counter);
 572   return unless $style;
 573
 574   my $type = $style->{'shape'};
 575   my $radius = $style->{'radius'};
 576
 577   my $line_aa = $self->_get_number("lineaa");
 578   my $fill_aa = $self->_get_number("fill.aa");
 579   if ($type eq 'circle') {
 580     my @fill = $self->_data_fill($series_counter, [$x1 - $radius, $y1 - $radius, $x1 + $radius, $y1 + $radius]);
 581     $img->circle(x => $x1, y => $y1, r => $radius, aa => $fill_aa, filled => 1, @fill);
 582   }
 583   elsif ($type eq 'square') {
 584     my @fill = $self->_data_fill($series_counter, [$x1 - $radius, $y1 - $radius, $x1 + $radius, $y1 + $radius]);
 585     $img->box(xmin => $x1 - $radius, ymin => $y1 - $radius, xmax => $x1 + $radius, ymax => $y1 + $radius, @fill);
 586   }
 587   elsif ($type eq 'diamond') {
 588     # The gradient really doesn't work for diamond
 589     my $color = $self->_data_color($series_counter);
 590     $img->polygon(
 591         points => [
 592                     [$x1 - $radius, $y1],
 593                     [$x1, $y1 + $radius],
 594                     [$x1 + $radius, $y1],
 595                     [$x1, $y1 - $radius],
 596                   ],
 597         filled => 1, color => $color, aa => $fill_aa);
 598   }
 599   elsif ($type eq 'triangle') {
 600     # The gradient really doesn't work for triangle
 601     my $color = $self->_data_color($series_counter);
 602     $img->polygon(
 603         points => [
 604                     [$x1 - $radius, $y1 + $radius],
 605                     [$x1 + $radius, $y1 + $radius],
 606                     [$x1, $y1 - $radius],
 607                   ],
 608         filled => 1, color => $color, aa => $fill_aa);
 609
 610   }
 611   elsif ($type eq 'x') {
 612     my $color = $self->_data_color($series_counter);
 613     $img->line(x1 => $x1 - $radius, y1 => $y1 -$radius, x2 => $x1 + $radius, y2 => $y1+$radius, aa => $line_aa, color => $color) || die $img->errstr;
 614     $img->line(x1 => $x1 + $radius, y1 => $y1 -$radius, x2 => $x1 - $radius, y2 => $y1+$radius, aa => $line_aa, color => $color) || die $img->errstr;
 615   }
 616   elsif ($type eq 'plus') {
 617     my $color = $self->_data_color($series_counter);
 618     $img->line(x1 => $x1, y1 => $y1 -$radius, x2 => $x1, y2 => $y1+$radius, aa => $line_aa, color => $color) || die $img->errstr;
 619     $img->line(x1 => $x1 + $radius, y1 => $y1, x2 => $x1 - $radius, y2 => $y1, aa => $line_aa, color => $color) || die $img->errstr;
 620   }
 621 }
 622
 623 sub _draw_columns {
 624   my $self = shift;
 625   my $style = $self->{'_style'};
 626
 627   my $img = $self->_get_image();
 628
 629   my $max_value = $self->_get_max_value();
 630   my $min_value = $self->_get_min_value();
 631   my $column_count = $self->_get_column_count();
 632
 633   my $value_range = $max_value - $min_value;
 634
 635   my $width = $self->_get_number('width');
 636   my $height = $self->_get_number('height');
 637
 638   my $graph_width = $self->_get_number('graph_width');
 639   my $graph_height = $self->_get_number('graph_height');
 640
 641
 642   my $graph_box = $self->_get_graph_box();
 643   my $left = $graph_box->[0] + 1;
 644   my $bottom = $graph_box->[1];
 645   my $zero_position =  int($bottom + $graph_height - (-1*$min_value / $value_range) * ($graph_height -1));
 646
 647   my $bar_width = int($graph_width / $column_count - 1);
 648
 649   my $outline_color;
 650   if ($style->{'features'}{'outline'}) {
 651     $outline_color = $self->_get_color('outline.line');
 652   }
 653
 654   my $series_counter = $self->_get_series_counter() || 0;
 655   my $col_series = $self->_get_data_series()->{'column'};
 656   my $column_padding_percent = $self->_get_number('column_padding') || 0;
 657   my $column_padding = int($column_padding_percent * $bar_width / 100);
 658
 659   # This tracks the series we're in relative to the starting series - this way colors stay accurate, but the columns don't start out too far to the right.
 660   my $column_series = 0;
 661
 662   # If there are stacked columns, non-stacked columns need to start one to the right of where they would otherwise
 663   my $has_stacked_columns = (defined $self->_get_data_series()->{'stacked_column'} ? 1 : 0);
 664
 665   for (my $series_pos = 0; $series_pos < scalar @$col_series; $series_pos++) {
 666     my $series = $col_series->[$series_pos];
 667     my @data = @{$series->{'data'}};
 668     my $data_size = scalar @data;
 669     my $color = $self->_data_color($series_counter);
 670     for (my $i = 0; $i < $data_size; $i++) {
 671       my $x1 = int($left + $bar_width * (scalar @$col_series * $i + $series_pos)) + scalar @$col_series * $i + $series_pos + ($column_padding / 2);
 672       if ($has_stacked_columns) {
 673         $x1 += ($i + 1) * $bar_width + $i + 1;
 674       }
 675       my $x2 = $x1 + $bar_width - $column_padding;
 676
 677       my $y1 = int($bottom + ($value_range - $data[$i] + $min_value)/$value_range * $graph_height);
 678
 679       my $color = $self->_data_color($series_counter);
 680
 681     #  my @fill = $self->_data_fill($series_counter, [$x1, $y1, $x2, $zero_position]);
 682       if ($data[$i] > 0) {
 683         $img->box(xmin => $x1, xmax => $x2, ymin => $y1, ymax => $zero_position-1, color => $color, filled => 1);
 684         if ($style->{'features'}{'outline'}) {
 685           $img->box(xmin => $x1, xmax => $x2, ymin => $y1, ymax => $zero_position, color => $outline_color);
 686         }
 687       }
 688       else {
 689         $img->box(xmin => $x1, xmax => $x2, ymin => $zero_position+1, ymax => $y1, color => $color, filled => 1);
 690         if ($style->{'features'}{'outline'}) {
 691           $img->box(xmin => $x1, xmax => $x2, ymin => $zero_position+1, ymax => $y1+1, color => $outline_color);
 692         }
 693       }
 694     }
 695
 696     $series_counter++;
 697     $column_series++;
 698   }
 699   $self->_set_series_counter($series_counter);
 700   return 1;
 701 }
 702
 703 sub _draw_stacked_columns {
 704   my $self = shift;
 705   my $style = $self->{'_style'};
 706
 707   my $img = $self->_get_image();
 708
 709   my $max_value = $self->_get_max_value();
 710   my $min_value = $self->_get_min_value();
 711   my $column_count = $self->_get_column_count();
 712   my $value_range = $max_value - $min_value;
 713
 714   my $graph_box = $self->_get_graph_box();
 715   my $left = $graph_box->[0] + 1;
 716   my $bottom = $graph_box->[1];
 717
 718   my $graph_width = $self->_get_number('graph_width');
 719   my $graph_height = $self->_get_number('graph_height');
 720
 721   my $bar_width = int($graph_width / $column_count -1);
 722   my $column_series = 0;
 723   if (my $column_series_data = $self->_get_data_series()->{'column'}) {
 724     $column_series = (scalar @$column_series_data);
 725   }
 726   $column_series++;
 727
 728   my $column_padding_percent = $self->_get_number('column_padding') || 0;
 729   if ($column_padding_percent < 0) {
 730     return $self->_error("Column padding less than 0");
 731   }
 732   if ($column_padding_percent > 100) {
 733     return $self->_error("Column padding greater than 0");
 734   }
 735   my $column_padding = int($column_padding_percent * $bar_width / 100);
 736
 737   my $outline_color;
 738   if ($style->{'features'}{'outline'}) {
 739     $outline_color = $self->_get_color('outline.line');
 740   }
 741
 742   my $zero_position =  $bottom + $graph_height - (-1*$min_value / $value_range) * ($graph_height -1);
 743   my $col_series = $self->_get_data_series()->{'stacked_column'};
 744   my $series_counter = $self->_get_series_counter() || 0;
 745
 746   foreach my $series (@$col_series) {
 747     my @data = @{$series->{'data'}};
 748     my $data_size = scalar @data;
 749     my $color = $self->_data_color($series_counter);
 750     for (my $i = 0; $i < $data_size; $i++) {
 751       my $x1 = int($left + $bar_width * ($column_series * $i)) + $column_series * $i + ($column_padding / 2);
 752       my $x2 = $x1 + $bar_width - $column_padding;
 753
 754       my $y1 = int($bottom + ($value_range - $data[$i] + $min_value)/$value_range * $graph_height);
 755
 756       if ($data[$i] > 0) {
 757         $img->box(xmin => $x1, xmax => $x2, ymin => $y1, ymax => $zero_position-1, color => $color, filled => 1);
 758         if ($style->{'features'}{'outline'}) {
 759           $img->box(xmin => $x1, xmax => $x2, ymin => $y1, ymax => $zero_position, color => $outline_color);
 760         }
 761       }
 762       else {
 763         $img->box(xmin => $x1, xmax => $x2, ymin => $zero_position+1, ymax => $y1, color => $color, filled => 1);
 764         if ($style->{'features'}{'outline'}) {
 765           $img->box(xmin => $x1, xmax => $x2, ymin => $zero_position+1, ymax => $y1+1, color => $outline_color);
 766         }
 767       }
 768     }
 769
 770     $series_counter++;
 771   }
 772   $self->_set_series_counter($series_counter);
 773   return 1;
 774 }
 775
 776 sub _add_data_series {
 777   my $self = shift;
 778   my $series_type = shift;
 779   my $data_ref = shift;
 780   my $series_name = shift;
 781
 782   my $graph_data = $self->{'graph_data'} || {};
 783
 784   my $series = $graph_data->{$series_type} || [];
 785
 786   push @$series, { data => $data_ref, series_name => $series_name };
 787
 788   $graph_data->{$series_type} = $series;
 789
 790   $self->{'graph_data'} = $graph_data;
 791   return;
 792 }
 793
 794 =over
 795
 796 =item show_horizontal_gridlines()
 797
 798 Shows horizontal gridlines at the y-tics.
 799
 800 =cut
 801
 802 sub show_horizontal_gridlines {
 803     $_[0]->{'custom_style'}->{'horizontal_gridlines'} = 1;
 804 }
 805
 806 =item use_automatic_axis()
 807
 808 Automatically scale the Y axis, based on L<Chart::Math::Axis>.  If Chart::Math::Axis isn't installed, this sets an error and returns undef.  Returns 1 if it is installed.
 809
 810 =cut
 811
 812 sub use_automatic_axis {
 813   eval { require Chart::Math::Axis; };
 814   if ($@) {
 815     return $_[0]->_error("use_automatic_axis - $@\nCalled from ".join(' ', caller)."\n");
 816   }
 817   $_[0]->{'custom_style'}->{'automatic_axis'} = 1;
 818   return 1;
 819 }
 820
 821
 822 =item set_y_tics($count)
 823
 824 Set the number of Y tics to use.  Their value and position will be determined by the data range.
 825
 826 =cut
 827
 828 sub set_y_tics {
 829   $_[0]->{'y_tics'} = $_[1];
 830 }
 831
 832 sub _get_y_tics {
 833   return $_[0]->{'y_tics'} || 0;
 834 }
 835
 836 sub _remove_tics_from_chart_box {
 837   my $self = shift;
 838   my $chart_box = shift;
 839
 840   # XXX - bad default
 841   my $tic_width = $self->_get_y_tic_width() || 10;
 842   my @y_tic_box = ($chart_box->[0], $chart_box->[1], $chart_box->[0] + $tic_width, $chart_box->[3]);
 843
 844   # XXX - bad default
 845   my $tic_height = $self->_get_x_tic_height() || 10;
 846   my @x_tic_box = ($chart_box->[0], $chart_box->[3] - $tic_height, $chart_box->[2], $chart_box->[3]);
 847
 848   $self->_remove_box($chart_box, \@y_tic_box);
 849   $self->_remove_box($chart_box, \@x_tic_box);
 850
 851   # If there's no title, the y-tics will be part off-screen.  Half of the x-tic height should be more than sufficient.
 852   my @y_tic_tops = ($chart_box->[0], $chart_box->[1], $chart_box->[2], $chart_box->[1] + int($tic_height / 2));
 853   $self->_remove_box($chart_box, \@y_tic_tops);
 854
 855 }
 856
 857 sub _get_y_tic_width{
 858   my $self = shift;
 859   my $min = $self->_get_min_value();
 860   my $max = $self->_get_max_value();
 861   my $tic_count = $self->_get_y_tics();
 862
 863   my $interval = ($max - $min) / ($tic_count - 1);
 864
 865   my %text_info = $self->_text_style('legend')
 866     or return;
 867
 868   my $max_width = 0;
 869   for my $count (0 .. $tic_count - 1) {
 870     my $value = sprintf("%.2f", ($count*$interval)+$min);
 871
 872     my @box = $self->_text_bbox($value, 'legend');
 873     my $width = $box[2] - $box[0];
 874
 875     # For the tic width
 876     $width += 10;
 877     if ($width > $max_width) {
 878       $max_width = $width;
 879     }
 880   }
 881
 882   return $max_width;
 883 }
 884
 885 sub _get_x_tic_height {
 886   my $self = shift;
 887
 888   my $labels = $self->_get_labels();
 889
 890   if (!$labels) {
 891         return;
 892   }
 893
 894   my $tic_count = (scalar @$labels) - 1;
 895
 896   my %text_info = $self->_text_style('legend')
 897     or return;
 898
 899   my $max_height = 0;
 900   for my $count (0 .. $tic_count) {
 901     my $label = $labels->[$count];
 902
 903     my @box = $self->_text_bbox($label, 'legend');
 904
 905     my $height = $box[3] - $box[1];
 906
 907     # Padding + the tic
 908     $height += 10;
 909     if ($height > $max_height) {
 910       $max_height = $height;
 911     }
 912   }
 913
 914   return $max_height;
 915 }
 916
 917 sub _draw_y_tics {
 918   my $self = shift;
 919   my $min = $self->_get_min_value();
 920   my $max = $self->_get_max_value();
 921   my $tic_count = $self->_get_y_tics();
 922
 923   my $img = $self->_get_image();
 924   my $graph_box = $self->_get_graph_box();
 925   my $image_box = $self->_get_image_box();
 926
 927   my $interval = ($max - $min) / ($tic_count - 1);
 928
 929   my %text_info = $self->_text_style('legend')
 930     or return;
 931
 932   my $show_gridlines = $self->_get_number('horizontal_gridlines');
 933   my $tic_distance = int(($graph_box->[3] - $graph_box->[1]) / ($tic_count - 1));
 934   for my $count (0 .. $tic_count - 1) {
 935     my $x1 = $graph_box->[0] - 5;
 936     my $x2 = $graph_box->[0] + 5;
 937     my $y1 = $graph_box->[3] - ($count * $tic_distance);
 938
 939     my $value = ($count*$interval)+$min;
 940     if ($interval < 1 || ($value != int($value))) {
 941         $value = sprintf("%.2f", $value);
 942     }
 943
 944     my @box = $self->_text_bbox($value, 'legend')
 945       or return;
 946
 947     $img->line(x1 => $x1, x2 => $x2, y1 => $y1, y2 => $y1, aa => 1, color => '000000');
 948
 949     my $width = $box[2];
 950     my $height = $box[3];
 951
 952     $img->string(%text_info,
 953                  x    => ($x1 - $width - 3),
 954                  y    => ($y1 + ($height / 2)),
 955                  text => $value
 956                 );
 957
 958     if ($show_gridlines) {
 959       # XXX - line styles!
 960       for (my $i = $graph_box->[0]; $i < $graph_box->[2]; $i += 6) {
 961         my $x1 = $i;
 962         my $x2 = $i + 2;
 963         if ($x2 > $graph_box->[2]) { $x2 = $graph_box->[2]; }
 964         $img->line(x1 => $x1, x2 => $x2, y1 => $y1, y2 => $y1, aa => 1, color => '000000');
 965       }
 966     }
 967   }
 968
 969 }
 970
 971 sub _draw_x_tics {
 972   my $self = shift;
 973
 974   my $img = $self->_get_image();
 975   my $graph_box = $self->_get_graph_box();
 976   my $image_box = $self->_get_image_box();
 977
 978   my $labels = $self->_get_labels();
 979
 980   my $tic_count = (scalar @$labels) - 1;
 981
 982   my $has_columns = (defined $self->_get_data_series()->{'column'} || defined $self->_get_data_series()->{'stacked_column'});
 983
 984   # If we have columns, we want the x-ticks to show up in the middle of the column, not on the left edge
 985   my $denominator = $tic_count;
 986   if ($has_columns) {
 987     $denominator ++;
 988   }
 989   my $tic_distance = ($graph_box->[2] - $graph_box->[0]) / ($denominator);
 990   my %text_info = $self->_text_style('legend')
 991     or return;
 992
 993   for my $count (0 .. $tic_count) {
 994     my $label = $labels->[$count];
 995     my $x1 = $graph_box->[0] + ($tic_distance * $count);
 996
 997     if ($has_columns) {
 998       $x1 += $tic_distance / 2;
 999     }
1000     my $y1 = $graph_box->[3] + 5;
1001     my $y2 = $graph_box->[3] - 5;
1002
1003     $img->line(x1 => $x1, x2 => $x1, y1 => $y1, y2 => $y2, aa => 1, color => '000000');
1004
1005     my @box = $self->_text_bbox($label, 'legend')
1006       or return;
1007
1008     my $width = $box[2];
1009     my $height = $box[3];
1010
1011     $img->string(%text_info,
1012                  x    => ($x1 - ($width / 2)),
1013                  y    => ($y1 + ($height + 5)),
1014                  text => $label
1015                 );
1016
1017   }
1018 }
1019
1020 sub _valid_input {
1021   my $self = shift;
1022
1023   if (!defined $self->_get_data_series() || !keys %{$self->_get_data_series()}) {
1024     return $self->_error("No data supplied");
1025   }
1026
1027   my $data = $self->_get_data_series();
1028   if (defined $data->{'line'} && !scalar @{$data->{'line'}->[0]->{'data'}}) {
1029     return $self->_error("No values in data series");
1030   }
1031   if (defined $data->{'column'} && !scalar @{$data->{'column'}->[0]->{'data'}}) {
1032     return $self->_error("No values in data series");
1033   }
1034   if (defined $data->{'stacked_column'} && !scalar @{$data->{'stacked_column'}->[0]->{'data'}}) {
1035     return $self->_error("No values in data series");
1036   }
1037
1038   return 1;
1039 }
1040
1041 sub _set_column_count   { $_[0]->{'column_count'} = $_[1]; }
1042 sub _set_min_value      { $_[0]->{'min_value'} = $_[1]; }
1043 sub _set_max_value      { $_[0]->{'max_value'} = $_[1]; }
1044 sub _set_image_box      { $_[0]->{'image_box'} = $_[1]; }
1045 sub _set_graph_box      { $_[0]->{'graph_box'} = $_[1]; }
1046 sub _set_series_counter { $_[0]->{'series_counter'} = $_[1]; }
1047 sub _get_column_count   { return $_[0]->{'column_count'} }
1048 sub _get_min_value      { return $_[0]->{'min_value'} }
1049 sub _get_max_value      { return $_[0]->{'max_value'} }
1050 sub _get_image_box      { return $_[0]->{'image_box'} }
1051 sub _get_graph_box      { return $_[0]->{'graph_box'} }
1052 sub _get_series_counter { return $_[0]->{'series_counter'} }
1053
1054 1;