4bdb50abc144ecc7ac5e535ab0eb645ae4f6821b
[imager-graph.git] / lib / Imager / Graph / Pie.pm
1 package Imager::Graph::Pie;
2
3 =head1 NAME
4
5   Imager::Graph::Pie - a tool for drawing pie charts on Imager images
6
7 =head1 SYNOPSIS
8
9   use Imager::Graph::Pie;
10
11   my $chart = Imager::Graph::Pie->new;
12   # see Imager::Graph for options
13   my $img = $chart->draw(
14                          data => [ $first_amount, $second_amount ],
15                          size => 350);
16
17 =head1 DESCRIPTION
18
19 Imager::Graph::Pie is intender to make it simple to use L<Imager> to
20 create good looking pie graphs.
21
22 Most of the basic layout and color selection is handed off to
23 L<Imager::Graph>.
24
25 =over
26
27 =cut
28
29 use strict;
30 use vars qw(@ISA);
31 use Imager::Graph;
32 @ISA = qw(Imager::Graph);
33 use Imager::Graph::Util;
34 use POSIX qw(floor);
35
36 use constant PI => 3.1415926535;
37
38 =item $graph->draw(...)
39
40 Draws a pie graph onto a new image and returns the image.
41
42 You must at least supply a C<data> parameter and should probably supply a C<labels> parameter.  If you supply a C<labels> parameter, you must supply a C<font> parameter.
43
44 The C<data> parameter should be a reference to an array containing the
45 data the pie graph should present.
46
47 The C<labels> parameter is a reference to an array of labels,
48 corresponding to the values in C<data>.
49
50 =back
51
52 =head1 FEATURES
53
54 As described in L<Imager::Graph> you can enable extra features for
55 your graph.  The features you can use with pie graphs are:
56
57 =over
58
59 =item legend
60
61 adds a legend to your graph.  Requires the labels parameter
62
63 =item labels
64
65 labels each segment of the graph.  If the label doesn't fit inside the
66 segment it is presented as a callout.
67
68 =item labelspc
69
70 adds the percentage of the pie to each label.
71
72 =item labelspconly
73
74 the segments are labels with their percentages only.
75
76 =item allcallouts
77
78 all labels are presented as callouts
79
80 =item outline
81
82 the pie segments are outlined.
83
84 =item dropshadow
85
86 the pie is given a drop shadow.
87
88 =back
89
90 =head1 PIE CHART STYLES
91
92 The following style values are specific to pie charts:
93
94 Controlling callouts, the C<callout> option:
95
96 =over
97
98 =item *
99
100 color - the color of the callout line and the callout text.
101
102 =item *
103
104 font, size - font and size of the callout text
105
106 =item *
107
108 outside - the distance the radial callout line goes outside the pie
109
110 =item *
111
112 leadlen - the length of the horizontal callout line from the end of
113 the radial line.
114
115 =item *
116
117 gap - the distance between the end of the horizontal callout line and
118 the label.
119
120 =item *
121
122 inside - the length of the radial callout line within the pie.
123
124 =back
125
126 The outline, line option controls the color of the pie segment
127 outlines, if enabled with the C<outline> feature.
128
129 Under C<pie>:
130
131 =over
132
133 =item *
134
135 maxsegment - any segment below this fraction of the total of the
136 segments will be put into the "others" segment.  Default: 0.01
137
138 =back
139
140 The top level C<otherlabel> setting controls the label for the
141 "others" segment, default "(others)".
142
143 =head1 EXAMPLES
144
145 Assuming:
146
147   # from the Netcraft September 2001 web survey
148   # http://www.netcraft.com/survey/
149   my @data   = qw(17874757  8146372   1321544  811406 );
150   my @labels = qw(Apache    Microsoft iPlanet  Zeus   );
151
152   my $pie = Imager::Graph::Pie->new;
153
154 First a simple graph, normal size, no labels:
155
156   my $img = $pie->draw(data=>\@data)
157     or die $pie->error;
158
159 label the segments:
160
161   # error handling omitted for brevity from now on
162   $img = $pie->draw(data=>\@data, labels=>\@labels, features=>'labels');
163
164 just percentages in the segments:
165
166   $img = $pie->draw(data=>\@data, features=>'labelspconly');
167
168 add a legend as well:
169
170   $img = $pie->draw(data=>\@data, labels=>\@labels,
171                     features=>[ 'labelspconly', 'legend' ]);
172
173 and a title, but move the legend down, and add a dropshadow:
174
175   $img = $pie->draw(data=>\@data, labels=>\@labels,
176                     title=>'Netcraft Web Survey',
177                     legend=>{ valign=>'bottom' },
178                     features=>[ qw/labelspconly legend dropshadow/ ]);
179
180 something a bit prettier:
181
182   # requires Imager > 0.38
183   $img = $pie->draw(data=>\@data, labels=>\@labels,
184                     style=>'fount_lin', features=>'legend');
185
186 suitable for monochrome output:
187
188   # requires Imager > 0.38
189   $img = $pie->draw(data=>\@data, labels=>\@labels,
190                     style=>'mono', features=>'legend');
191
192 =cut
193
194 # this function is too long
195 sub draw {
196   my ($self, %opts) = @_;
197
198   $opts{data} 
199     or return $self->_error("No data parameter supplied");
200   my @data = @{$opts{data}};
201   my @labels;
202   @labels = @{$opts{labels}} if $opts{labels};
203
204   $self->_style_setup(\%opts);
205
206   my $style = $self->{_style};
207
208   my $img = $self->_make_img()
209     or return;
210
211   my $total = 0;
212   for my $item (@data) {
213     $total += $item;
214   }
215
216   my @chart_box = ( 0, 0, $img->getwidth-1, $img->getheight-1 );
217   if ($style->{title}{text}) {
218     $self->_draw_title($img, \@chart_box)
219       or return;
220   }
221
222   # consolidate any segments that are too small to display
223   $self->_consolidate_segments(\@data, \@labels, $total);
224
225   if ($style->{features}{legend} && $opts{labels}) {
226     $self->_draw_legend($img, \@labels, \@chart_box)
227       or return;
228   }
229
230   # the following code is fairly ugly
231   # it attempts to work out a good layout for the components of the chart
232   my @info;
233   my $index = 0;
234   my $pos = 0;
235   my @ebox = (0, 0, 0, 0);
236   defined(my $callout_outside = $self->_get_number('callout.outside'))
237     or return;
238   defined(my $callout_leadlen = $self->_get_number('callout.leadlen'))
239     or return;
240   defined(my $callout_gap = $self->_get_number('callout.gap'))
241     or return;
242   defined(my $label_vpad = $self->_get_number('label.vpad'))
243     or return;
244   defined(my $label_hpad = $self->_get_number('label.hpad'))
245     or return;
246   my $guessradius = 
247     int($self->_small_extent(\@chart_box) * $style->{pie}{guessfactor} * 0.5);
248   for my $data (@data) {
249     my $item = { data=>$data, index=>$index };
250     my $size = 2 * PI * $data / $total;
251     $item->{begin} = $pos;
252     $pos += $size;
253     $item->{end} = $pos;
254     if ($opts{labels}) {
255       $item->{text} = $labels[$index];
256     }
257     if ($style->{features}{labelspconly}) {
258       $item->{text} = 
259         $style->{label}{pconlyformat}->($data/$total * 100);
260     }
261     if ($item->{text}) {
262       if ($style->{features}{labelspc}) {
263         $item->{text} = 
264           $style->{label}{pcformat}->($item->{text}, $data/$total * 100);
265         $item->{label} = 1;
266       }
267       elsif ($style->{features}{labelspconly}) {
268         $item->{text} = 
269           $style->{label}{pconlyformat}->($data/$total * 100);
270         $item->{label} = 1;
271       }
272       elsif ($style->{features}{labels}) {
273         $item->{label} = 1;
274       }
275       $item->{lbox} = [ $self->_text_bbox($item->{text}, 'label') ];
276       if ($item->{label}) {
277         unless ($self->_fit_text(0, 0, 'label', $item->{text}, $guessradius,
278                                  $item->{begin}, $item->{end})) {
279           $item->{callout} = 1;
280         }
281       }
282       $item->{callout} = 1 if $style->{features}{allcallouts};
283       if ($item->{callout}) {
284         $item->{label} = 0;
285         $item->{cbox} = [ $self->_text_bbox($item->{text}, 'callout') ];
286         $item->{cangle} = ($item->{begin} + $item->{end}) / 2;
287         my $dist = cos($item->{cangle}) * ($guessradius+
288                                            $callout_outside);
289         my $co_size = $callout_leadlen + $callout_gap + $item->{cbox}[2];
290         if ($dist < 0) {
291           $dist -= $co_size - $guessradius;
292           $dist < $ebox[0] and $ebox[0] = $dist;
293         }
294         else {
295           $dist += $co_size - $guessradius;
296           $dist > $ebox[2] and $ebox[2] = $dist;
297         }
298       }
299     }
300     push(@info, $item);
301     ++$index;
302   }
303
304   my $radius = 
305     int($self->_small_extent(\@chart_box) * $style->{pie}{size} * 0.5);
306   my $max_width = $chart_box[2] - $chart_box[0] + $ebox[0] - $ebox[2];
307   if ($radius > $max_width / 2) {
308     $radius = int($max_width / 2);
309   }
310   $chart_box[0] -= $ebox[0];
311   $chart_box[2] -= $ebox[2];
312   my $cx = int(($chart_box[0] + $chart_box[2]) / 2);
313   my $cy = int(($chart_box[1] + $chart_box[3]) / 2);
314   if ($style->{features}{dropshadow}) {
315     my @shadow_fill = $self->_get_fill('dropshadow.fill')
316       or return;
317     my $offx = $self->_get_number('dropshadow.offx')
318       or return;
319     my $offy = $self->_get_number('dropshadow.offy');
320     for my $item (@info) {
321       $img->arc(x=>$cx+$offx, 'y'=>$cy+$offy, r=>$radius+1, aa => 1,
322                 d1=>180/PI * $item->{begin}, d2=>180/PI * $item->{end},
323                 @shadow_fill);
324     }
325     $self->_filter_region($img, 
326                           $cx+$offx-$radius-10, $cy+$offy-$radius-10, 
327                           $cx+$offx+$radius+10, $cy+$offy+$radius+10,
328                           'dropshadow.filter')
329       if $style->{dropshadow}{filter};
330   }
331
332   my @fill_box = ( $cx-$radius, $cy-$radius, $cx+$radius, $cy+$radius );
333   for my $item (@info) {
334     $item->{begin} < $item->{end}
335       or next;
336     my @fill = $self->_data_fill($item->{index}, \@fill_box)
337       or return;
338     $img->arc(x=>$cx, 'y'=>$cy, r=>$radius, aa => 1,
339               d1=>180/PI * $item->{begin}, d2=>180/PI * $item->{end},
340               @fill);
341   }
342   if ($style->{features}{outline}) {
343     my $outcolor = $self->_get_color('outline.line');
344     for my $item (@info) {
345       my $px = int($cx + $radius * cos($item->{begin}));
346       my $py = int($cy + $radius * sin($item->{begin}));
347       $item->{begin} < $item->{end}
348         or next;
349       $img->line(x1=>$cx, y1=>$cy, x2=>$px, y2=>$py, color=>$outcolor);
350       for (my $i = $item->{begin}; $i < $item->{end}; $i += PI/180) {
351         my $stroke_end = $i + PI/180;
352         $stroke_end = $item->{end} if $stroke_end > $item->{end};
353         my $nx = int($cx + $radius * cos($stroke_end));
354         my $ny = int($cy + $radius * sin($stroke_end));
355         $img->line(x1=>$px, y1=>$py, x2=>$nx, y2=>$ny, color=>$outcolor,
356                   antialias=>1);
357         ($px, $py) = ($nx, $ny);
358       }
359     }
360   }
361
362   my $callout_inside = $radius - $self->_get_number('callout.inside');
363   $callout_outside += $radius;
364   my %callout_text = $self->_text_style('callout');
365   my %label_text = $self->_text_style('label');
366   for my $label (@info) {
367     if ($label->{label}) {
368       my @loc = $self->_fit_text($cx, $cy, 'label', $label->{text}, $radius,
369                                  $label->{begin}, $label->{end});
370       if (@loc) {
371         my $tcx = ($loc[0]+$loc[2])/2;
372         my $tcy = ($loc[1]+$loc[3])/2;
373         #$img->box(xmin=>$loc[0], ymin=>$loc[1], xmax=>$loc[2], ymax=>$loc[3],
374         #          color=>Imager::Color->new(0,0,0));
375         $img->string(%label_text, x=>$tcx-$label->{lbox}[2]/2,
376                      'y'=>$tcy+$label->{lbox}[3]/2+$label->{lbox}[1],
377                      text=>$label->{text});
378       }
379       else {
380         $label->{callout} = 1;
381         $label->{cbox} = [ $self->_text_bbox($label->{text}, 'callout') ]; 
382         $label->{cangle} = ($label->{begin} + $label->{end}) / 2;
383       }
384     }
385     if ($label->{callout}) {
386       my $ix = floor(0.5 + $cx + $callout_inside * cos($label->{cangle}));
387       my $iy = floor(0.5 + $cy + $callout_inside * sin($label->{cangle}));
388       my $ox = floor(0.5 + $cx + $callout_outside * cos($label->{cangle}));
389       my $oy = floor(0.5 + $cy + $callout_outside * sin($label->{cangle}));
390       my $lx = ($ox < $cx) ? $ox - $callout_leadlen : $ox + $callout_leadlen;
391       $img->line(x1=>$ix, y1=>$iy, x2=>$ox, y2=>$oy, antialias=>1,
392                  color=>$self->_get_color('callout.color'));
393       $img->line(x1=>$ox, y1=>$oy, x2=>$lx, y2=>$oy, antialias=>1,
394                  color=>$self->_get_color('callout.color'));
395       #my $tx = $lx + $callout_gap;
396       my $ty = $oy + $label->{cbox}[3]/2+$label->{cbox}[1];
397       if ($lx < $cx) {
398         $img->string(%callout_text, x=>$lx-$callout_gap-$label->{cbox}[2], 
399                      'y'=>$ty, text=>$label->{text});
400       }
401       else {
402         $img->string(%callout_text, x=>$lx+$callout_gap, 'y'=>$ty, 
403                      text=>$label->{text});
404       }
405     }
406   }
407
408   $img;
409 }
410
411 =head1 INTERNAL FUNCTIONS
412
413 These are used in the implementation of Imager::Graph, and are
414 documented for debuggers and developers.
415
416 =over
417
418 =item _consolidate_segments($data, $labels, $total)
419
420 Consolidate segments that are too small into an 'others' segment.
421
422 =cut
423
424 sub _consolidate_segments {
425   my ($self, $data, $labels, $total) = @_;
426
427   my @others;
428   my $index;
429   for my $item (@$data) {
430     if ($item / $total < $self->{_style}{pie}{maxsegment}) {
431       push(@others, $index);
432     }
433     ++$index;
434   }
435   if (@others) {
436     my $others = 0;
437     for my $index (reverse @others) {
438       $others += $data->[$index];
439       splice(@$labels, $index, 1);
440       splice(@$data, $index, 1);
441     }
442     push(@$labels, $self->{_style}{otherlabel}) if @$labels;
443     push(@$data, $others);
444   }
445 }
446
447 # used for debugging
448 sub _test_line {
449   my ($x, $y, @l) = @_;
450
451   my $res = $l[0]*$x + $l[1] * $y + $l[2];
452   print "test ", (abs($res) < 0.000001) ? "success\n" : "failure $res\n";
453 }
454
455 =item _fit_text($cx, $cy, $name, $text, $radius, $begin, $end)
456
457 Attempts to fit text into a pie segment with its center at ($cx, $cy)
458 with the given radius, covering the angles $begin through $end.
459
460 Returns a list defining the bounding box of the text if it does fit.
461
462 =cut
463
464 sub _fit_text {
465   my ($self, $cx, $cy, $name, $text, $radius, $begin, $end) = @_;
466
467   #print "fit: $cx, $cy '$text' $radius $begin $end\n";
468   my @tbox = $self->_text_bbox($text, $name);
469   my $tcx = floor(0.5+$cx + cos(($begin+$end)/2) * $radius *3/5);
470   my $tcy = floor(0.5+$cy + sin(($begin+$end)/2) * $radius *3/5);
471   my $topy = $tcy - $tbox[3]/2;
472   my $boty = $topy + $tbox[3];
473   my @lines;
474   for my $y ($topy, $boty) {
475     my %entry = ( 'y'=>$y );
476     $entry{line} = [ line_from_points($tcx, $y, $tcx+1, $y) ];
477     $entry{left} = -$radius;
478     $entry{right} = $radius;
479     for my $angle ($begin, $end) {
480       my $ex = $cx + cos($angle)*$radius;
481       my $ey = $cy + sin($angle)*$radius;
482       my @line = line_from_points($cx, $cy, $ex, $ey);
483       #_test_line($cx, $cy, @line);
484       #_test_line($ex, $ey, @line);
485       my $goodsign = $line[0] * $tcx + $line[1] * $tcy + $line[2];
486       for my $pos (@entry{qw/left right/}) {
487         my $sign = $line[0] * ($pos+$tcx) + $line[1] * $y + $line[2];
488         if ($goodsign * $sign < 0) {
489           if (my @p = intersect_lines(@line, @{$entry{line}})) {
490             # die "$goodsign $sign ($pos, $tcx) no intersect (@line) (@{$entry{line}})"  ; # this would be wierd
491             #_test_line(@p, @line);
492             #_test_line(@p, @{$entry{line}});
493             $pos = $p[0]-$tcx;
494           }
495           else {
496             return;
497           }
498             
499         }
500
501         # circle
502         my $dist2 = ($pos+$tcx-$cx) * ($pos+$tcx-$cx) 
503           + ($y - $cy) * ($y - $cy);
504         if ($dist2 > $radius * $radius) {
505           my @points = 
506             intersect_line_and_circle(@{$entry{line}}, $cx, $cy, $radius);
507           while (@points) {
508             my @p = splice(@points, 0, 2);
509             if ($p[0] < $cx && $tcx+$pos < $p[0]) {
510               $pos = $p[0]-$tcx;
511             }
512             elsif ($p[0] > $cx && $tcx+$pos > $p[0]) {
513               $pos = $p[0]-$tcx;
514             }
515           }
516         }
517       }
518     }
519     push(@lines, \%entry);
520   }
521   my $left = $lines[0]{left} > $lines[1]{left} ? $lines[0]{left} : $lines[1]{left};
522   my $right = $lines[0]{right} < $lines[1]{right} ? $lines[0]{right} : $lines[1]{right};
523   return if $right - $left < $tbox[2];
524
525   return ($tcx+$left, $topy, $tcx+$right, $boty);
526 }
527
528 sub _composite {
529   ( 'pie', $_[0]->SUPER::_composite() );
530 }
531
532 sub _style_defs {
533   my ($self) = @_;
534
535   my %work = %{$self->SUPER::_style_defs()};
536   $work{otherlabel} = "(others)";
537   $work{pie} = 
538     {
539      guessfactor=>0.6,
540      size=>0.8,
541      maxsegment=> 0.01,
542     };
543
544   \%work;
545 }
546
547 1;
548 __END__
549
550 =back
551
552 =head1 AUTHOR
553
554 Tony Cook <tony@develop-help.com>
555
556 =head1 SEE ALSO
557
558 Imager::Graph(3), Imager(3), perl(1)
559
560 =cut