allow metadata to be defined for new products

[bse.git] / site / cgi-bin / modules / BSE / Edit / Article.pm

package BSE::Edit::Article;
use strict;
use base qw(BSE::Edit::Base);
use BSE::Util::Tags qw(tag_error_img tag_article tag_object);
use BSE::Util::SQL qw(now_sqldate now_sqldatetime);
use BSE::Permissions;
use BSE::Util::HTML qw(:default popup_menu);
use BSE::Arrows;
use BSE::CfgInfo qw(custom_class admin_base_url cfg_image_dir cfg_dist_image_uri cfg_image_uri);
use BSE::Util::Iterate;
use BSE::Template;
use BSE::Util::ContentType qw(content_type);
use BSE::Regen 'generate_article';
use DevHelp::Date qw(dh_parse_date dh_parse_sql_date);
use List::Util qw(first);
use constant MAX_FILE_DISPLAYNAME_LENGTH => 255;
use constant ARTICLE_CUSTOM_FIELDS_CFG => "article custom fields";

our $VERSION = "1.054";

=head1 NAME

  BSE::Edit::Article - editing functionality for BSE articles

=head1 DESCRIPTION

Provides the base article editing functionality.

This is badly organized and documented.

=head1 METHODS

=over

=cut

sub not_logged_on {
  my ($self, $req) = @_;

  if ($req->is_ajax) {
    # AJAX/Prototype request
    return $req->json_content
      (
       {
	success => 0,
	message => "Access forbidden: user not logged on",
	errors => {},
	error_code => "LOGON",
       }
      );
  }
  elsif ($req->cgi->param('_service')) {
    return
      {
       content => 'Access Forbidden: login timed out',
       headers => [
		   "Status: 403", # forbidden
		  ],
      };
  }
  else {
    BSE::Template->get_refresh($req->url('logon'), $req->cfg);
  }
}

sub article_dispatch {
  my ($self, $req, $article, $articles) = @_;

  BSE::Permissions->check_logon($req)
    or return $self->not_logged_on($req);

  my $cgi = $req->cgi;
  my $action;
  my %actions = $self->article_actions;
  for my $check (keys %actions) {
    if ($cgi->param($check) || $cgi->param("$check.x")) {
      $action = $check;
      last;
    }
  }
  my @extraargs;
  unless ($action) {
    ($action, @extraargs) = $self->other_article_actions($cgi);
  }
  $action ||= 'edit';
  my $method = $actions{$action};
  return $self->$method($req, $article, $articles, @extraargs);
}

sub noarticle_dispatch {
  my ($self, $req, $articles) = @_;

  BSE::Permissions->check_logon($req)
    or return BSE::Template->get_refresh($req->url('logon'), $req->cfg);

  my $mymsg;
  my $article = $self->_dummy_article($req, $articles, \$mymsg);
  unless ($article) {
    require BSE::Edit::Site;
    my $site = BSE::Edit::Site->new(cfg=>$req->cfg, db=> BSE::DB->single);
    return $site->edit_sections($req, $articles, $mymsg);
  }

  my $cgi = $req->cgi;
  my $action = 'add';
  my %actions = $self->noarticle_actions;
  for my $check (keys %actions) {
    if ($cgi->param($check) || $cgi->param("$check.x")) {
      $action = $check;
      last;
    }
  }
  my $method = $actions{$action};
  return $self->$method($req, $article, $articles);
}

sub article_actions {
  my ($self) = @_;

  return
    (
     edit => 'edit_form',
     save => 'save',
     add_stepkid => 'add_stepkid',
     del_stepkid => 'del_stepkid',
     save_stepkids => 'save_stepkids',
     add_stepparent => 'add_stepparent',
     del_stepparent => 'del_stepparent',
     save_stepparents => 'save_stepparents',
     artimg => 'save_image_changes',
     addimg => 'add_image',
     a_edit_image => 'req_edit_image',
     a_save_image => 'req_save_image',
     a_order_images => 'req_order_images',
     remove => 'remove',
     showimages => 'show_images',
     process => 'save_image_changes',
     removeimg => 'remove_img',
     moveimgup => 'move_img_up',
     moveimgdown => 'move_img_down',
     filelist => 'filelist',
     fileadd => 'fileadd',
     fileswap => 'fileswap',
     filedel => 'filedel',
     filesave => 'filesave',
     a_edit_file => 'req_edit_file',
     a_save_file => 'req_save_file',
     hide => 'hide',
     unhide => 'unhide',
     a_thumb => 'req_thumb',
     a_ajax_get => 'req_ajax_get',
     a_ajax_save_body => 'req_ajax_save_body',
     a_ajax_set => 'req_ajax_set',
     a_filemeta => 'req_filemeta',
     a_csrfp => 'req_csrfp',
     a_tree => 'req_tree',
     a_article => 'req_article',
     a_config => 'req_config',
     a_restepkid => 'req_restepkid',
    );
}

sub other_article_actions {
  my ($self, $cgi) = @_;

  for my $param ($cgi->param) {
    if ($param =~ /^removeimg_(\d+)(\.x)?$/) {
      return ('removeimg', $1 );
    }
  }

  return;
}

sub noarticle_actions {
  return
    (
     add => 'add_form',
     save => 'save_new',
     a_csrfp => 'req_csrfp',
     a_config => 'req_config',
    );
}

sub get_parent {
  my ($self, $parentid, $articles) = @_;

  if ($parentid == -1) {
    return 
      {
       id => -1,
       title=>'All Sections',
       level => 0,
       listed => 0,
       parentid => undef,
      };
  }
  else {
    return $articles->getByPkey($parentid);
  }
}

sub tag_hash {
  my ($object, $args) = @_;

  my $value = $object->{$args};
  defined $value or $value = '';
  if ($value =~ /\cJ/ && $value =~ /\cM/) {
    $value =~ tr/\cM//d;
  }
  escape_html($value);
}

sub tag_hash_mbcs {
  my ($object, $args) = @_;

  my $value = $object->{$args};
  defined $value or $value = '';
  if ($value =~ /\cJ/ && $value =~ /\cM/) {
    $value =~ tr/\cM//d;
  }
  escape_html($value, '<>&"');
}

sub tag_art_type {
  my ($level, $cfg) = @_;

  escape_html($cfg->entry('level names', $level, 'Article'));
}

sub tag_if_new {
  my ($article) = @_;

  !$article->{id};
}

sub reparent_updown {
  return 1;
}

sub should_be_catalog {
  my ($self, $article, $parent, $articles) = @_;

  if ($article->{parentid} && (!$parent || $parent->{id} != $article->{parentid})) {
    $parent = $articles->getByPkey($article->{id});
  }

  my $shopid = $self->cfg->entryErr('articles', 'shop');

  return $article->{parentid} && $parent &&
    ($article->{parentid} == $shopid || 
     $parent->{generator} eq 'BSE::Generate::Catalog');
}

sub possible_parents {
  my ($self, $article, $articles, $req) = @_;

  my %labels;
  my @values;

  my $shopid = $self->cfg->entryErr('articles', 'shop');
  my @parents = $articles->getBy('level', $article->{level}-1);
  @parents = grep { $_->{generator} eq 'BSE::Generate::Article' 
		      && $_->{id} != $shopid } @parents;

  # user can only select parent they can add to
  @parents = grep $req->user_can('edit_add_child', $_), @parents;
  
  @values = ( map {$_->{id}} @parents );
  %labels = ( map { $_->{id} => "$_->{title} ($_->{id})" } @parents );
  
  if ($article->{level} == 1 && $req->user_can('edit_add_child')) {
    push @values, -1;
    $labels{-1} = "No parent - this is a section";
  }
  
  if ($article->{id} && $self->reparent_updown($article)) {
    # we also list the siblings and grandparent (if any)
    my @siblings = grep $_->{id} != $article->{id} && $_->{id} != $shopid,
    $articles->getBy(parentid => $article->{parentid});
    @siblings = grep $req->user_can('edit_add_child', $_), @siblings;
    push @values, map $_->{id}, @siblings;
    @labels{map $_->{id}, @siblings} =
      map { "-- move down a level -- $_->{title} ($_->{id})" } @siblings;
    
    if ($article->{parentid} != -1) {
      my $parent = $articles->getByPkey($article->{parentid});
      if ($parent->{parentid} != -1) {
	my $gparent = $articles->getByPkey($parent->{parentid});
	if ($req->user_can('edit_add_child', $gparent)) {
	  push @values, $gparent->{id};
	  $labels{$gparent->{id}} =
	    "-- move up a level -- $gparent->{title} ($gparent->{id})";
	}
      }
      else {
	if ($req->user_can('edit_add_child')) {
	  push @values, -1;
	  $labels{-1} = $req->catmsg("msg:bse/admin/edit/uplabelsect");
	}
      }
    }
  }

  return (\@values, \%labels);
}

sub tag_list {
  my ($self, $article, $articles, $cgi, $req, $what) = @_;

  if ($what eq 'listed') {
    my @values = qw(0 1);
    my %labels = ( 0=>"No", 1=>"Yes");
    if ($article->{level} <= 2) {
      $labels{2} = "In Sections, but not menu";
      push(@values, 2);
    }
    else {
      $labels{2} = "In content, but not menus";
      push(@values, 2);
    }
    return popup_menu(-name=>'listed',
		      -values=>\@values,
		      -labels=>\%labels,
		      -default=>$article->{listed});
  }
  else {
    my ($values, $labels) = $self->possible_parents($article, $articles, $req);
    my $html;
    if (defined $article->{parentid}) {
      $html = popup_menu(-name=>'parentid',
			 -values=> $values,
			 -labels => $labels,
			 -default => $article->{parentid},
			 -override=>1);
    }
    else {
      $html = popup_menu(-name=>'parentid',
			 -values=> $values,
			 -labels => $labels,
			 -override=>1);
    }

    # munge the html - we display a default value, so we need to wrap the 
    # default <select /> around this one
    $html =~ s!^<select[^>]+>|</select>!!gi;
    return $html;
  }
}

sub tag_checked {
  my ($arg, $acts, $funcname, $templater) = @_;
  my ($func, $args) = split ' ', $arg, 2;
  return $templater->perform($acts, $func, $args) ? 'checked' : '';
}

sub iter_get_images {
  my ($self, $article) = @_;

  $article->{id} or return;
  $self->get_images($article);
}

sub iter_get_kids {
  my ($article, $articles) = @_;

  my @children;
  $article->{id} or return;
  if (UNIVERSAL::isa($article, 'BSE::TB::Article')) {
    @children = $article->children;
  }
  elsif ($article->{id}) {
    @children = $articles->children($article->{id});
  }

  return sort { $b->{displayOrder} <=> $a->{displayOrder} } @children;
}

sub tag_if_have_child_type {
  my ($level, $cfg) = @_;

  defined $cfg->entry("level names", $level+1);
}

sub tag_is {
  my ($args, $acts, $isname, $templater) = @_;

  my ($func, $funcargs) = split ' ', $args, 2;
  return $templater->perform($acts, $func, $funcargs) ? 'Yes' : 'No';
}

sub default_template {
  my ($self, $article, $cfg, $templates) = @_;

  if ($article->{parentid}) {
    my $template = $cfg->entry("children of $article->{parentid}", "template");
    return $template 
      if $template && grep $_ eq $template, @$templates;
  }
  if ($article->{level}) {
    my $template = $cfg->entry("level $article->{level}", "template");
    return $template 
      if $template && grep $_ eq $template, @$templates;
  }
  return $templates->[0];
}

sub tag_templates {
  my ($self, $article, $cfg, $cgi) = @_;

  my @templates = sort { $a->{name} cmp $b->{name} } $self->templates_long($article);
  my $default;
  if ($article->{template} && grep $_->{name} eq $article->{template}, @templates) {
    $default = $article->{template};
  }
  else {
    my @template_names = map $_->{name}, @templates;
    $default = $self->default_template($article, $cfg, \@template_names);
  }
  my %labels =
    (
     map
     { ;
       $_->{name} => 
       $_->{name} eq $_->{description}
	 ? $_->{name}
	   : "$_->{description} ($_->{name})"
     } @templates
    );
  return popup_menu(-name => 'template',
		    -values => [ map $_->{name}, @templates ],
		    -labels => \%labels,
		    -default => $default,
		    -override => 1);
}

sub title_images {
  my ($self, $article) = @_;

  my @title_images;
  my $imagedir = cfg_image_dir($self->cfg);
  if (opendir TITLE_IMAGES, "$imagedir/titles") {
    @title_images = sort 
      grep -f "$imagedir/titles/$_" && /\.(gif|jpeg|jpg|png)$/i,
      readdir TITLE_IMAGES;
    closedir TITLE_IMAGES;
  }

  @title_images;
}

sub tag_title_images  {
  my ($self, $article, $cfg, $cgi) = @_;

  my @images = $self->title_images($article);
  my @values = ( '', @images );
  my %labels = ( '' => 'None', map { $_ => $_ } @images );
  return $cgi->
    popup_menu(-name=>'titleImage',
	       -values=>\@values,
	       -labels=>\%labels,
	       -default=>$article->{id} ? $article->{titleImage} : '',
	       -override=>1);
}

sub base_template_dirs {
  return ( "common" );
}

sub template_dirs {
  my ($self, $article) = @_;

  my @dirs = $self->base_template_dirs;
  if (my $parentid = $article->{parentid}) {
    my $section = "children of $parentid";
    if (my $dirs = $self->cfg->entry($section, 'template_dirs')) {
      push @dirs, split /,/, $dirs;
    }
  }
  if (my $id = $article->{id}) {
    my $section = "article $id";
    if (my $dirs = $self->{cfg}->entry($section, 'template_dirs')) {
      push @dirs, split /,/, $dirs;
    }
  }
  if ($article->{level}) {
    push @dirs, $article->{level};
    my $dirs = $self->{cfg}->entry("level $article->{level}", 'template_dirs');
    push @dirs, split /,/, $dirs if $dirs;
  }

  @dirs;
}

sub templates {
  my ($self, $article) = @_;

  my @dirs = $self->template_dirs($article);
  my @templates;
  my @basedirs = BSE::Template->template_dirs($self->{cfg});
  for my $basedir (@basedirs) {
    for my $dir (@dirs) {
      my $path = File::Spec->catdir($basedir, $dir);
      if (-d $path) {
	if (opendir TEMPLATE_DIR, $path) {
	  push(@templates, sort map "$dir/$_",
	       grep -f "$path/$_" && /\.(tmpl|html)$/i, readdir TEMPLATE_DIR);
	  closedir TEMPLATE_DIR;
	}
      }
    }
  }

  # eliminate any dups, and order it nicely
  my %seen;
  @templates = sort { lc($a) cmp lc($b) }
    grep !$seen{$_}++, @templates;
  
  return (@templates, $self->extra_templates($article));
}

sub extra_templates {
  my ($self, $article) = @_;

  my $basedir = $self->{cfg}->entryVar('paths', 'templates');
  my @templates;
  if (my $id = $article->{id}) {
    push @templates, 'index.tmpl'
      if $id == 1 && -f "$basedir/index.html";
    push @templates, 'index2.tmpl'
      if $id == 2 && -f "$basedir/index2.html";
    my $shopid = $self->{cfg}->entryErr('articles', 'shop');
    push @templates, "shop_sect.tmpl"
      if $id == $shopid && -f "$basedir/shop_sect.tmpl";
    my $section = "article $id";
    my $extras = $self->{cfg}->entry($section, 'extra_templates');
    push @templates, grep /\.(tmpl|html)$/i, split /,/, $extras
      if $extras;
  }

  @templates;
}

sub categories {
  my ($self, $articles) = @_;

  return $articles->categories;
}

sub edit_parent {
  my ($article) = @_;

  return '' unless $article->{id} && $article->{id} != -1;
  return <<HTML;
<a href="$ENV{SCRIPT_NAME}?id=$article->{parentid}">Edit parent</a> |
HTML
}

sub iter_allkids {
  my ($article) = @_;

  return unless $article->{id} && $article->{id} > 0;
  $article->allkids;
}

sub _load_step_kids {
  my ($article, $step_kids) = @_;

  require BSE::TB::OtherParents;
  my @stepkids = BSE::TB::OtherParents->getBy(parentId=>$article->{id}) if $article->{id};
  %$step_kids = map { $_->{childId} => $_ } @stepkids;
  $step_kids->{loaded} = 1;
}

sub tag_if_step_kid {
  my ($article, $allkids, $rallkid_index, $step_kids) = @_;

  _load_step_kids($article, $step_kids) unless $step_kids->{loaded};

  my $kid = $allkids->[$$rallkid_index]
    or return;
  exists $step_kids->{$kid->{id}};
}

sub tag_step_kid {
  my ($article, $allkids, $rallkid_index, $step_kids, $arg) = @_;

  _load_step_kids($article, $step_kids) unless $step_kids->{loaded};

  my $kid = $allkids->[$$rallkid_index]
    or return '';
  my $step_kid = $step_kids->{$kid->{id}}
    or return '';
  #use Data::Dumper;
  #print STDERR "found kid (want $arg): ", Dumper($kid), Dumper($step_kid);
  escape_html($step_kid->{$arg});
}

sub tag_move_stepkid {
  my ($self, $cgi, $req, $article, $allkids, $rallkids_index, $arg,
      $acts, $funcname, $templater) = @_;

  $req->user_can(edit_reorder_children => $article)
    or return '';

  @$allkids > 1 or return '';

  my ($img_prefix, $urladd) = DevHelp::Tags->get_parms($arg, $acts, $templater);
  $img_prefix = '' unless defined $img_prefix;
  $urladd = '' unless defined $urladd;

  my $cgi_uri = $self->{cfg}->entry('uri', 'cgi', '/cgi-bin');
  my $url = $ENV{SCRIPT_NAME} . "?id=$article->{id}";
  if ($cgi->param('_t')) {
    $url .= "&_t=".$cgi->param('_t');
  }
  $url .= $urladd;
  $url .= "#step";
  my $down_url = '';
  if ($$rallkids_index < $#$allkids) {
    $down_url = "$cgi_uri/admin/move.pl?stepparent=$article->{id}&d=swap&id=$allkids->[$$rallkids_index]{id}&other=$allkids->[$$rallkids_index+1]{id}";
  }
  my $up_url = '';
  if ($$rallkids_index > 0) {
    $up_url = "$cgi_uri/admin/move.pl?stepparent=$article->{id}&d=swap&id=$allkids->[$$rallkids_index]{id}&other=$allkids->[$$rallkids_index-1]{id}";
  }
  
  return make_arrows($req->cfg, $down_url, $up_url, $url, $img_prefix);
}

sub possible_stepkids {
  my ($req, $article, $articles, $stepkids) = @_;

  $req->user_can(edit_stepkid_add => $article)
    or return;

  $article->{id} == -1
    and return;

  my @possible = sort { lc $a->{title} cmp lc $b->{title} }
     $article->possible_stepchildren;
  if ($req->access_control && $req->cfg->entry('basic', 'access_filter_steps', 0)) {
    @possible = grep $req->user_can(edit_stepparent_add => $_->{id}), @possible;
  }
  return @possible;
}

sub tag_possible_stepkids {
  my ($step_kids, $req, $article, $possstepkids, $articles, $cgi) = @_;

  _load_step_kids($article, $step_kids) unless $step_kids->{loaded};
  @$possstepkids = possible_stepkids($req, $article, $articles, $step_kids)
    unless @$possstepkids;
  my %labels = map { $_->{id} => "$_->{title} ($_->{id})" } @$possstepkids;
  return
    popup_menu(-name=>'stepkid',
	       -values=> [ map $_->{id}, @$possstepkids ],
	       -labels => \%labels);
}

sub tag_if_possible_stepkids {
  my ($step_kids, $req, $article, $possstepkids, $articles, $cgi) = @_;

  _load_step_kids($article, $step_kids) unless $step_kids->{loaded};
  @$possstepkids = possible_stepkids($req, $article, $articles, $step_kids)
    unless @$possstepkids;
  
  @$possstepkids;
}

sub iter_get_stepparents {
  my ($article) = @_;

  return unless $article->{id} && $article->{id} > 0;

  require BSE::TB::OtherParents;
  BSE::TB::OtherParents->getBy(childId=>$article->{id});
}

sub tag_ifStepParents {
  my ($args, $acts, $funcname, $templater) = @_;

  return $templater->perform($acts, 'ifStepparents', '');
}

sub tag_stepparent_targ {
  my ($article, $targs, $rindex, $arg) = @_;

  if ($article->{id} && $article->{id} > 0 && !@$targs) {
    @$targs = $article->step_parents;
  }
  escape_html($targs->[$$rindex]{$arg});
}

sub tag_move_stepparent {
  my ($self, $cgi, $req, $article, $stepparents, $rindex, $arg,
      $acts, $funcname, $templater) = @_;

  $req->user_can(edit_reorder_stepparents => $article)
    or return '';

  @$stepparents > 1 or return '';

  my ($img_prefix, $urladd) = DevHelp::Tags->get_parms($arg, $acts, $templater);
  $img_prefix = '' unless defined $img_prefix;
  $urladd = '' unless defined $urladd;

  my $cgi_uri = $self->{cfg}->entry('uri', 'cgi', '/cgi-bin');
  my $images_uri = cfg_dist_image_uri();
  my $html = '';
  my $url = $ENV{SCRIPT_NAME} . "?id=$article->{id}";
  if ($cgi->param('_t')) {
    $url .= "&_t=".$cgi->param('_t');
  }
  $url .= $urladd;
  $url .= "#stepparents";
  my $blank = qq!<img src="$images_uri/trans_pixel.gif" width="17" height="13" border="0" align="absbottom" alt="" />!;
  my $down_url = '';
  if ($$rindex < $#$stepparents) {
    $down_url = "$cgi_uri/admin/move.pl?stepchild=$article->{id}&id=$stepparents->[$$rindex]{parentId}&d=swap&other=$stepparents->[$$rindex+1]{parentId}";
  }
  my $up_url = '';
  if ($$rindex > 0) {
    $up_url = "$cgi_uri/admin/move.pl?stepchild=$article->{id}&id=$stepparents->[$$rindex]{parentId}&d=swap&other=$stepparents->[$$rindex-1]{parentId}";
  }

  return make_arrows($req->cfg, $down_url, $up_url, $url, $img_prefix);
}

sub _stepparent_possibles {
  my ($req, $article, $articles, $targs) = @_;

  $req->user_can(edit_stepparent_add => $article)
    or return;

  $article->{id} == -1
    and return;

  @$targs = $article->step_parents unless @$targs;
  my %targs = map { $_->{id}, 1 } @$targs;
  my @possibles = $article->possible_stepparents;
  if ($req->access_control && $req->cfg->entry('basic', 'access_filter_steps', 0)) {
    @possibles = grep $req->user_can(edit_stepkid_add => $_->{id}), @possibles;
  }
  @possibles = sort { lc $a->{title} cmp lc $b->{title} } @possibles;

  return @possibles;
}

sub tag_if_stepparent_possibles {
  my ($req, $article, $articles, $targs, $possibles) = @_;

  if ($article->{id} && $article->{id} > 0 && !@$possibles) {
    @$possibles = _stepparent_possibles($req, $article, $articles, $targs);
  }
  scalar @$possibles;
}

sub tag_stepparent_possibles {
  my ($cgi, $req, $article, $articles, $targs, $possibles) = @_;

  if ($article->{id} && $article->{id} > 0 && !@$possibles) {
    @$possibles = _stepparent_possibles($req, $article, $articles, $targs);
  }
  popup_menu(-name=>'stepparent',
	     -values => [ map $_->{id}, @$possibles ],
	     -labels => { map { $_->{id}, "$_->{title} ($_->{id})" }
			  @$possibles });
}

sub iter_files {
  my ($self, $article) = @_;

  return $self->get_files($article);
}

sub get_files {
  my ($self, $article) = @_;

  return unless $article->{id} && $article->{id} > 0;

  return $article->files;
}

sub tag_edit_parent {
  my ($article) = @_;

  return '' unless $article->{id} && $article->{id} != -1;

  return <<HTML;
<a href="$ENV{SCRIPT_NAME}?id=$article->{parentid}">Edit parent</a> |
HTML
}

sub tag_if_children {
  my ($args, $acts, $funcname, $templater) = @_;

  return $templater->perform($acts, 'ifChildren', '');
}

sub tag_movechild {
  my ($self, $req, $article, $kids, $rindex, $arg,
      $acts, $funcname, $templater) = @_;

  $req->user_can('edit_reorder_children', $article)
    or return '';

  @$kids > 1 or return '';

  $$rindex >=0 && $$rindex < @$kids
    or return '** movechild can only be used in the children iterator **';

  my ($img_prefix, $urladd) = DevHelp::Tags->get_parms($arg, $acts, $templater);
  $img_prefix = '' unless defined $img_prefix;
  $urladd = '' unless defined $urladd;

  my $cgi_uri = $self->{cfg}->entry('uri', 'cgi', '/cgi-bin');
  my $images_uri = cfg_dist_image_uri();
  my $urlbase = admin_base_url($req->cfg);
  my $refresh_url = "$urlbase$ENV{SCRIPT_NAME}?id=$article->{id}";
  my $t = $req->cgi->param('_t');
  if ($t && $t =~ /^\w+$/) {
    $refresh_url .= "&_t=$t";
  }

  $refresh_url .= $urladd;

  my $id = $kids->[$$rindex]{id};
  my $down_url = '';
  if ($$rindex < $#$kids) {
    $down_url = "$cgi_uri/admin/move.pl?id=$id&d=down&edit=1&all=1";
  }
  my $up_url = '';
  if ($$rindex > 0) {
    $up_url = "$cgi_uri/admin/move.pl?id=$id&d=up&edit=1&all=1"
  }

  return make_arrows($req->cfg, $down_url, $up_url, $refresh_url, $img_prefix);
}

sub tag_category {
  my ($self, $articles, $article) = @_;

  my @cats = $self->categories($articles);

  my %labels = map { $_->{id}, $_->{name} } @cats;

  return popup_menu(-name => 'category',
		    -values => [ map $_->{id}, @cats ],
		    -labels => \%labels,
		    -default => $article->{category});
}

sub tag_edit_link {
  my ($cfg, $article, $args, $acts, $funcname, $templater) = @_;
  my ($which, $name) = split / /, $args, 2;
  $name ||= 'Edit';
  my $gen_class;
  if ($acts->{$which} 
      && ($gen_class = $templater->perform($acts, $which, 'generator'))) {
    eval "use $gen_class";
    unless ($@) {
      my $gen = $gen_class->new(top => $article, cfg => $cfg);
      my $link = $gen->edit_link($templater->perform($acts, $which, 'id'));
      return qq!<a href="$link">$name</a>!;
    }
  }
  return '';
}

sub tag_imgmove {
  my ($req, $article, $rindex, $images, $arg,
      $acts, $funcname, $templater) = @_;

  $req->user_can(edit_images_reorder => $article)
    or return '';

  @$images > 1 or return '';

  $$rindex >= 0 && $$rindex < @$images 
    or return '** imgmove can only be used in image iterator **';

  my ($img_prefix, $urladd) = DevHelp::Tags->get_parms($arg, $acts, $templater);
  $img_prefix = '' unless defined $img_prefix;
  $urladd = '' unless defined $urladd;

  my $urlbase = admin_base_url($req->cfg);
  my $url = "$urlbase$ENV{SCRIPT_NAME}?id=$article->{id}";
  my $t = $req->cgi->param('_t');
  if ($t && $t =~ /^\w+$/) {
    $url .= "&_t=$t";
  }
  $url .= $urladd;

  my $image = $images->[$$rindex];
  my $csrfp = $req->get_csrf_token("admin_move_image");
  my $baseurl = "$ENV{SCRIPT_NAME}?id=$article->{id}&imageid=$image->{id}&";
  $baseurl .= "_csrfp=$csrfp&";
  my $down_url = "";
  if ($$rindex < $#$images) {
    $down_url = $baseurl . "moveimgdown=1";
  }
  my $up_url = "";
  if ($$rindex > 0) {
    $up_url = $baseurl . "moveimgup=1";
  }
  return make_arrows($req->cfg, $down_url, $up_url, $url, $img_prefix);
}

sub tag_movefiles {
  my ($self, $req, $article, $files, $rindex, $arg,
      $acts, $funcname, $templater) = @_;

  $req->user_can('edit_files_reorder', $article)
    or return '';

  @$files > 1 or return '';

  my ($img_prefix, $urladd) = DevHelp::Tags->get_parms($arg, $acts, $templater);
  $img_prefix = '' unless defined $img_prefix;
  $urladd = '' unless defined $urladd;

  $$rindex >= 0 && $$rindex < @$files
    or return '** movefiles can only be used in the files iterator **';

  my $urlbase = admin_base_url($req->cfg);
  my $url = "$urlbase$ENV{SCRIPT_NAME}?id=$article->{id}$urladd";
  my $t = $req->cgi->param('_t');
  if ($t && $t =~ /^\w+$/) {
    $url .= "&_t=$t";
  }

  my $down_url = "";
  my $csrfp = $req->get_csrf_token("admin_move_file");
  my $baseurl = "$ENV{SCRIPT_NAME}?fileswap=1&id=$article->{id}&";
  $baseurl .= "_csrfp=$csrfp&";
  if ($$rindex < $#$files) {
    $down_url = $baseurl . "file1=$files->[$$rindex]{id}&file2=$files->[$$rindex+1]{id}";
  }
  my $up_url = "";
  if ($$rindex > 0) {
    $up_url = $baseurl . "file1=$files->[$$rindex]{id}&file2=$files->[$$rindex-1]{id}";
  }

  return make_arrows($req->cfg, $down_url, $up_url, $url, $img_prefix);
}

sub tag_old {
  my ($article, $cgi, $args, $acts, $funcname, $templater) = @_;

  my ($col, $func, $funcargs) = split ' ', $args, 3;
  my $value = $cgi->param($col);
  if (defined $value) {
    return escape_html($value);
  }
  else {
    if ($func) {
      return $templater->perform($acts, $func, $funcargs);
    }
    else {
      $value = $article->{$args};
      defined $value or $value = '';
      return escape_html($value);
    }
  }
}

sub iter_admin_users {
  require BSE::TB::AdminUsers;

  BSE::TB::AdminUsers->all;
}

sub iter_admin_groups {
  require BSE::TB::AdminGroups;

  BSE::TB::AdminGroups->all;
}

sub tag_if_field_perm {
  my ($req, $article, $field) = @_;

  unless ($field =~ /^\w+$/) {
    print STDERR "Bad fieldname '$field'\n";
    return;
  }
  if ($article->{id}) {
    return $req->user_can("edit_field_edit_$field", $article);
  }
  else {
    #print STDERR "adding, always successful\n";
    return 1;
  }
}

sub tag_default {
  my ($self, $req, $article, $args, $acts, $funcname, $templater) = @_;

  my ($col, $func, $funcargs) = split ' ', $args, 3;
  if ($article->{id}) {
    if ($func) {
      return $templater->perform($acts, $func, $funcargs);
    }
    else {
      my $value = $article->{$args};
      defined $value or $value = '';
      return escape_html($value, '<>&"');
    }
  }
  else {
    my $value = $self->default_value($req, $article, $col);
    defined $value or $value = '';
    return escape_html($value, '<>&"');
  }
}

sub iter_flags {
  my ($self) = @_;

  $self->flags;
}

sub tag_if_flag_set {
  my ($article, $arg, $acts, $funcname, $templater) = @_;

  my @args = DevHelp::Tags->get_parms($arg, $acts, $templater);
  @args or return;

  return index($article->{flags}, $args[0]) >= 0;
}

sub iter_crumbs {
  my ($article, $articles) = @_;

  my @crumbs;
  my $temp = $article;
  defined($temp->{parentid}) or return;
  while ($temp->{parentid} > 0
	 and my $crumb = $articles->getByPkey($temp->{parentid})) {
    unshift @crumbs, $crumb;
    $temp = $crumb;
  }

  @crumbs;
}

sub tag_typename {
  my ($args, $acts, $funcname, $templater) = @_;

  exists $acts->{$args} or return "** need an article name **";
  my $generator = $templater->perform($acts, $args, 'generator');

  $generator =~ /^(?:BSE::)?Generate::(\w+)$/
    or return "** invalid generator $generator **";

  return $1;
}

sub _get_thumbs_class {
  my ($self) = @_;

  $self->{cfg}->entry('editor', 'allow_thumb', 0)
    or return;

  my $class = $self->{cfg}->entry('editor', 'thumbs_class')
    or return;
  
  (my $filename = "$class.pm") =~ s!::!/!g;
  eval { require $filename; };
  if ($@) {
    print STDERR "** Error loading thumbs_class $class ($filename): $@\n";
    return;
  }
  my $obj;
  eval { $obj = $class->new($self->{cfg}) };
  if ($@) {
    print STDERR "** Error creating thumbs objects $class: $@\n";
    return;
  }

  return $obj;
}

sub tag_thumbimage {
  my ($cfg, $thumbs_obj, $current_image, $args) = @_;

  $thumbs_obj or return '';

  $$current_image or return '** no current image **';

  my $imagedir = cfg_image_dir($cfg);

  my $filename = "$imagedir/$$current_image->{image}";
  -e $filename or return "** image file missing **";

  defined $args && $args =~ /\S/
    or $args = "editor";

  my $image = $$current_image;
  return $image->thumb
    (
     geo => $args,
     cfg => $cfg,
     nolink => 1,
    );
}

sub tag_file_display {
  my ($self, $files, $file_index) = @_;

  $$file_index >= 0 && $$file_index < @$files
    or return "* file_display only usable inside a files iterator *";
  my $file = $files->[$$file_index];

  my $disp_type = $self->cfg->entry("editor", "file_display", "");

  return $file->inline
    (
     cfg => $self->cfg,
     field => $disp_type,
    );
}

sub tag_image {
  my ($self, $cfg, $rcurrent, $args) = @_;

  my $im = $$rcurrent
    or return '';

  my ($align, $rest) = split ' ', $args, 2;

  if ($align && exists $im->{$align}) {
    if ($align eq 'src') {
      return escape_html($im->image_url($self->{cfg}));
    }
    else {
      return escape_html($im->{$align});
    }
  }
  else {
    return $im->formatted
      (
       cfg => $cfg,
       align => $align,
       extras => $rest,
      );
  }
}

sub iter_tags {
  my ($self, $article) = @_;

  $article->{id}
    or return;

  return $article->tag_objects;
}

my %base_custom_validation =
  (
   customDate1 =>
   {
    rules => "date",
    htmltype => "text",
    width => 10,
    default => "",
    type => "date",
   },
   customDate2 =>
   {
    rules => "date",
    htmltype => "text",
    width => 10,
    default => "",
    type => "date",
   },
   customStr1 =>
   {
    htmltype => "text",
    default => "",
   },
   customStr2 =>
   {
    htmltype => "text",
    default => "",
   },
   customInt1 =>
   {
    rules => "integer",
    htmltype => "text",
    width => 10,
    default => "",
   },
   customInt2 =>
   {
    rules => "integer",
    htmltype => "text",
    width => 10,
    default => "",
   },
   customInt3 =>
   {
    rules => "integer",
    htmltype => "text",
    width => 10,
    default => "",
   },
   customInt4 =>
   {
    rules => "integer",
    htmltype => "text",
    width => 10,
    default => "",
   },
  );

sub custom_fields {
  my $self = shift;

  require DevHelp::Validate;
  DevHelp::Validate->import;
  return DevHelp::Validate::dh_configure_fields
    (
     \%base_custom_validation,
     $self->cfg,
     ARTICLE_CUSTOM_FIELDS_CFG,
     BSE::DB->single->dbh,
    );
}

sub _custom_fields {
  my $self = shift;

  my $fields = $self->custom_fields;
  my %active;
  for my $key (keys %$fields) {
    $fields->{$key}{description}
      and $active{$key} = $fields->{$key};
  }

  return \%active;
}

sub low_edit_tags {
  my ($self, $acts, $request, $article, $articles, $msg, $errors) = @_;

  my $cgi = $request->cgi;
  my $show_full = $cgi->param('f_showfull');
  my $if_error = $msg || ($errors && keys %$errors) || $request->cgi->param("_e");
  #$msg ||= join "\n", map escape_html($_), $cgi->param('message'), $cgi->param('m');
  $msg .= $request->message($errors);
  my $parent;
  if ($article->{id}) {
    if ($article->{parentid} > 0) {
      $parent = $article->parent;
    }
    else {
      $parent = { title=>"No parent - this is a section", id=>-1 };
    }
  }
  else {
    $parent = { title=>"How did we get here?", id=>0 };
  }
  $request->set_article(article => $article);
  $request->set_variable(ifnew => !$article->{id});
  my $cfg = $self->{cfg};
  my $mbcs = $cfg->entry('html', 'mbcs', 0);
  my $tag_hash = $mbcs ? \&tag_hash_mbcs : \&tag_hash;
  my $thumbs_obj_real = $self->_get_thumbs_class();
  my $thumbs_obj = $show_full ? undef : $thumbs_obj_real;
  my @images;
  my $image_index;
  my $current_image;
  my @children;
  my $child_index;
  my %stepkids;
  my @allkids;
  my $allkid_index;
  my @possstepkids;
  my @stepparents;
  my $stepparent_index;
  my @stepparent_targs;
  my @stepparentpossibles;
  my @files;
  my $file_index;
  my @groups;
  my $current_group;
  my $it = BSE::Util::Iterate->new;
  my $ito = BSE::Util::Iterate::Objects->new;
  my $ita = BSE::Util::Iterate::Article->new(req => $request);

  my $custom = $self->_custom_fields;
  # only return the fields that are defined
  $request->set_variable(custom => $custom);
  $request->set_variable(errors => $errors || {});
  my $article_type = $cfg->entry('level names', $article->{level}, 'Article');
  $request->set_variable(article_type => $article_type);

  return
    (
     $request->admin_tags,
     article => sub { tag_article($article, $cfg, $_[0]) },
     old => [ \&tag_old, $article, $cgi ],
     default => [ \&tag_default, $self, $request, $article ],
     articleType => escape_html($article_type),
     parentType => [ \&tag_art_type, $article->{level}-1, $cfg ],
     ifNew => [ \&tag_if_new, $article ],
     list => [ \&tag_list, $self, $article, $articles, $cgi, $request ],
     script => $ENV{SCRIPT_NAME},
     level => $article->{level},
     checked => \&tag_checked,
     $it->make_iterator
     ([ \&iter_get_images, $self, $article ], 'image', 'images', \@images, 
      \$image_index, undef, \$current_image),
     image => [ tag_image => $self, $cfg, \$current_image ],
     thumbimage => [ \&tag_thumbimage, $cfg, $thumbs_obj, \$current_image ],
     ifThumbs => defined($thumbs_obj),
     ifCanThumbs => defined($thumbs_obj_real),
     imgmove => [ \&tag_imgmove, $request, $article, \$image_index, \@images ],
     message => $msg,
     ifError => $if_error,
     $ita->make
     (
      code => [ \&iter_get_kids, $article, $articles ], 
      single => 'child',
      plural => 'children',
      data => \@children,
      index => \$child_index,
     ),
     ifchildren => \&tag_if_children,
     childtype => [ \&tag_art_type, $article->{level}+1, $cfg ],
     ifHaveChildType => [ \&tag_if_have_child_type, $article->{level}, $cfg ],
     movechild => [ \&tag_movechild, $self, $request, $article, \@children, 
		    \$child_index],
     is => \&tag_is,
     templates => [ \&tag_templates, $self, $article, $cfg, $cgi ],
     titleImages => [ \&tag_title_images, $self, $article, $cfg, $cgi ],
     editParent => [ \&tag_edit_parent, $article ],
     $ita->make
     (
      code => [ \&iter_allkids, $article ],
      single => 'kid',
      plural => 'kids',
      data => \@allkids,
      index => \$allkid_index,
     ),
     ifStepKid => 
     [ \&tag_if_step_kid, $article, \@allkids, \$allkid_index, \%stepkids ],
     stepkid => [ \&tag_step_kid, $article, \@allkids, \$allkid_index, 
		  \%stepkids ],
     movestepkid => 
     [ \&tag_move_stepkid, $self, $cgi, $request, $article, \@allkids, 
       \$allkid_index ],
     possible_stepkids =>
     [ \&tag_possible_stepkids, \%stepkids, $request, $article, 
       \@possstepkids, $articles, $cgi ],
     ifPossibles => 
     [ \&tag_if_possible_stepkids, \%stepkids, $request, $article, 
       \@possstepkids, $articles, $cgi ],
     $ita->make
     (
      code => [ \&iter_get_stepparents, $article ],
      single => 'stepparent',
      plural => 'stepparents',
      data => \@stepparents,
      index => \$stepparent_index,
     ),
     ifStepParents => \&tag_ifStepParents,
     stepparent_targ => 
     [ \&tag_stepparent_targ, $article, \@stepparent_targs, 
       \$stepparent_index ],
     movestepparent => 
     [ \&tag_move_stepparent, $self, $cgi, $request, $article, \@stepparents, 
       \$stepparent_index ],
     ifStepparentPossibles =>
     [ \&tag_if_stepparent_possibles, $request, $article, $articles, 
       \@stepparent_targs, \@stepparentpossibles, ],
     stepparent_possibles =>
     [ \&tag_stepparent_possibles, $cgi, $request, $article, $articles, 
       \@stepparent_targs, \@stepparentpossibles, ],
     $ito->make
     (
      code => [ iter_files => $self, $article ],
      single => 'file',
      plural => 'files',
      data => \@files,
      index => \$file_index,
     ),
     movefiles => 
     [ \&tag_movefiles, $self, $request, $article, \@files, \$file_index ],
     $it->make
     (
      code => [ iter_file_metas => $self, \@files, \$file_index ],
      plural => "file_metas",
      single => "file_meta",
      nocache => 1,
     ),
     ifFileExists => sub {
       @files && $file_index >= 0 && $file_index < @files
	 or return 0;

       return -f ($files[$file_index]->full_filename($cfg));
     },
     file_display => [ tag_file_display => $self, \@files, \$file_index ],
     DevHelp::Tags->make_iterator2
     (\&iter_admin_users, 'iadminuser', 'adminusers'),
     DevHelp::Tags->make_iterator2
     (\&iter_admin_groups, 'iadmingroup', 'admingroups'),
     edit => [ \&tag_edit_link, $cfg, $article ],
     error => [ $tag_hash, $errors ],
     error_img => [ \&tag_error_img, $cfg, $errors ],
     ifFieldPerm => [ \&tag_if_field_perm, $request, $article ],
     parent => [ \&tag_article, $parent, $cfg ],
     DevHelp::Tags->make_iterator2
     ([ \&iter_flags, $self ], 'flag', 'flags' ),
     ifFlagSet => [ \&tag_if_flag_set, $article ],
     DevHelp::Tags->make_iterator2
     ([ \&iter_crumbs, $article, $articles ], 'crumb', 'crumbs' ),
     typename => \&tag_typename,
     $it->make_iterator([ \&iter_groups, $request ], 
			'group', 'groups', \@groups, undef, undef,
			\$current_group),
     $it->make_iterator([ iter_image_stores => $self], 
			'image_store', 'image_stores'),
     $it->make_iterator([ iter_file_stores => $self], 
			'file_store', 'file_stores'),
     ifGroupRequired => [ \&tag_ifGroupRequired, $article, \$current_group ],
     category => [ tag_category => $self, $articles, $article ],
     $ito->make
     (
      single => "tag",
      plural => "tags",
      code => [ iter_tags => $self, $article ],
     ),
    );
}

sub iter_image_stores {
  my ($self) = @_;

  my $mgr = $self->_image_manager;

  return map +{ name => $_->name, description => $_->description },
    $mgr->all_stores;
}

sub _file_manager {
  my ($self) = @_;

  require BSE::TB::ArticleFiles;

  return BSE::TB::ArticleFiles->file_manager($self->cfg);
}

sub iter_file_stores {
  my ($self) = @_;

  require BSE::TB::ArticleFiles;
  my $mgr = $self->_file_manager($self->cfg);

  return map +{ name => $_->name, description => $_->description },
    $mgr->all_stores;
}

sub iter_groups {
  my ($req) = @_;

  require BSE::TB::SiteUserGroups;
  BSE::TB::SiteUserGroups->admin_and_query_groups($req->cfg);
}

sub tag_ifGroupRequired {
  my ($article, $rgroup) = @_;

  $article->{id}
    or return 0;

  $$rgroup or return 0;

  $article->is_accessible_to($$rgroup);
}

sub edit_template {
  my ($self, $article, $cgi) = @_;

  my $base = $article->{level};
  my $t = $cgi->param('_t');
  if ($t && $t =~ /^\w+$/) {
    $base = $t;
  }
  return $self->{cfg}->entry('admin templates', $base, 
			     "admin/edit_$base");
}

sub add_template {
  my ($self, $article, $cgi) = @_;

  $self->edit_template($article, $cgi);
}

sub low_edit_form {
  my ($self, $request, $article, $articles, $msg, $errors) = @_;

  my $cgi = $request->cgi;
  my %acts;
  %acts = $self->low_edit_tags(\%acts, $request, $article, $articles, $msg,
			      $errors);
  my $template = $article->{id} ? 
    $self->edit_template($article, $cgi) : $self->add_template($article, $cgi);

  return $request->response($template, \%acts);
}

sub edit_form {
  my ($self, $request, $article, $articles, $msg, $errors) = @_;

  return $self->low_edit_form($request, $article, $articles, $msg, $errors);
}

sub _dummy_article {
  my ($self, $req, $articles, $rmsg) = @_;

  my $level;
  my $cgi = $req->cgi;
  my $parentid = $cgi->param('parentid');
  if ($parentid) {
    if ($parentid =~ /^\d+$/) {
      if (my $parent = $self->get_parent($parentid, $articles)) {
	$level = $parent->{level}+1;
      }
      else {
	$parentid = undef;
      }
    }
    elsif ($parentid eq "-1") {
      $level = 1;
    }
  }
  unless (defined $level) {
    $level = $cgi->param('level');
    undef $level unless defined $level && $level =~ /^\d+$/
      && $level > 0 && $level < 100;
    defined $level or $level = 3;
  }
  
  my %article;
  my @cols = BSE::TB::Article->columns;
  @article{@cols} = ('') x @cols;
  $article{id} = '';
  $article{parentid} = $parentid;
  $article{level} = $level;
  $article{body} = '<maximum of 64Kb>';
  $article{listed} = 1;
  $article{generator} = $self->generator;

  my ($values, $labels) = $self->possible_parents(\%article, $articles, $req);
  unless (@$values) {
    $$rmsg = "You can't add children to any article at that level";
    return;
  }

  return $self->_make_dummy_article(\%article);
}

sub _make_dummy_article {
  my ($self, $article) = @_;

  require BSE::DummyArticle;
  return bless $article, "BSE::DummyArticle";
}

sub add_form {
  my ($self, $req, $article, $articles, $msg, $errors) = @_;

  return $self->low_edit_form($req, $article, $articles, $msg, $errors);
}

sub generator { 'BSE::Generate::Article' }

sub typename {
  my ($self) = @_;

  my $gen = $self->generator;

  ($gen =~ /(\w+)$/)[0] || 'Article';
}

sub _validate_common {
  my ($self, $data, $articles, $errors, $article) = @_;

#   if (defined $data->{parentid} && $data->{parentid} =~ /^(?:-1|\d+)$/) {
#     unless ($data->{parentid} == -1 or 
# 	    $articles->getByPkey($data->{parentid})) {
#       $errors->{parentid} = "Selected parent article doesn't exist";
#     }
#   }
#   else {
#     $errors->{parentid} = "You need to select a valid parent";
#   }
  if (exists $data->{title} && $data->{title} !~ /\S/) {
    $errors->{title} = "Please enter a title";
  }

  if (exists $data->{template} && $data->{template} =~ /\.\./) {
    $errors->{template} = "Please only select templates from the list provided";
  }
  if (exists $data->{linkAlias} 
      && length $data->{linkAlias}) {
    unless ($data->{linkAlias} =~ /\A[a-zA-Z0-9-_]+\z/
	    && $data->{linkAlias} =~ /[A-Za-z]/) {
      $errors->{linkAlias} = "Link alias must contain only alphanumerics and contain at least one letter";
    }
  }

  if (defined $data->{category}) {
    unless (first { $_->{id} eq $data->{category} } $self->categories($articles)) {
      $errors->{category} = "msg:bse/admin/edit/category/unknown";
    }
  }

  require DevHelp::Validate;
  DevHelp::Validate->import('dh_validate_hash');
  dh_validate_hash($data, $errors,
		   {
		    fields => $self->_custom_fields,
		    optional => 1,
		    dbh => BSE::DB->single->dbh,
		   },
		   $self->cfg, ARTICLE_CUSTOM_FIELDS_CFG);
}

sub validate {
  my ($self, $data, $articles, $errors) = @_;

  $self->_validate_common($data, $articles, $errors);
  if (!$errors->{linkAlias} && defined $data->{linkAlias} && length $data->{linkAlias}) {
    my $other = $articles->getBy(linkAlias => $data->{linkAlias});
    $other
      and $errors->{linkAlias} =
	"Duplicate link alias - already used by article $other->{id}";
  }
  custom_class($self->{cfg})
    ->article_validate($data, undef, $self->typename, $errors);

  return !keys %$errors;
}

sub validate_old {
  my ($self, $article, $data, $articles, $errors, $ajax) = @_;

  $self->_validate_common($data, $articles, $errors, $article);
  custom_class($self->{cfg})
    ->article_validate($data, $article, $self->typename, $errors);

  if (exists $data->{release}) {
    if ($ajax && !dh_parse_sql_date($data->{release})
	|| !$ajax && !dh_parse_date($data->{release})) {
      $errors->{release} = "Invalid release date";
    }
  }

  if (!$errors->{linkAlias} 
      && defined $data->{linkAlias} 
      && length $data->{linkAlias} 
      && $data->{linkAlias} ne $article->{linkAlias}) {
    my $other = $articles->getBy(linkAlias => $data->{linkAlias});
    $other && $other->{id} != $article->{id}
      and $errors->{linkAlias} = "Duplicate link alias - already used by article $other->{id}";
  }

  return !keys %$errors;
}

sub validate_parent {
  1;
}

sub fill_new_data {
  my ($self, $req, $data, $articles) = @_;

  my $custom = $self->_custom_fields;
  for my $key (keys %$custom) {
    my ($value) = $req->cgi->param($key);
    if (defined $value) {
      if ($key =~ /^customDate/) {
	require DevHelp::Date;
	my $msg;
	if (my ($year, $month, $day) =
	    DevHelp::Date::dh_parse_date($value, \$msg)) {
	  $data->{$key} = sprintf("%04d-%02d-%02d", $year, $month, $day);
	}
	else {
	  $data->{$key} = undef;
	}
      }
      elsif ($key =~ /^customInt/) {
	if ($value =~ /\S/) {
	  $data->{$key} = $value;
	}
	else {
	  $data->{$key} = undef;
	}
      }
      else {
	$data->{$key} = $value;
      }
    }
  }

  custom_class($self->{cfg})
    ->article_fill_new($data, $self->typename);

  1;
}

sub link_path {
  my ($self, $article) = @_;

  # check the config for the article and any of its ancestors
  my $work_article = $article;
  my $path = $self->{cfg}->entry('article uris', $work_article->{id});
  while (!$path) {
    last if $work_article->{parentid} == -1;
    $work_article = $work_article->parent;
    $path = $self->{cfg}->entry('article uris', $work_article->{id});
  }
  return $path if $path;

  $self->default_link_path($article);
}

sub default_link_path {
  my ($self, $article) = @_;

  $self->{cfg}->entry('uri', 'articles', '/a');
}

sub make_link {
  my ($self, $article) = @_;

  $article->is_linked
    or return "";

  my $title = $article->title;
  if ($article->is_dynamic) {
    (my $extra = $title) =~ tr/A-Za-z0-9/-/sc;
    return "/cgi-bin/page.pl?page=$article->{id}&title=".escape_uri($extra);
  }

  my $article_uri = $self->link_path($article);
  my $link = "$article_uri/$article->{id}.html";
  my $link_titles = $self->{cfg}->entryBool('basic', 'link_titles', 0);
  if ($link_titles) {
    (my $extra = $title) =~ tr/A-Za-z0-9/-/sc;
    $link .= "/" . $extra . "_html";
  }

  $link;
}

sub save_columns {
  my ($self, $table_object) = @_;

  my @columns = $table_object->rowClass->columns;
  shift @columns;

  return @columns;
}

sub _validate_tags {
  my ($self, $tags, $errors) = @_;

  my $fail = 0;
  my @errors;
  for my $tag (@$tags) {
    my $error;
    if ($tag =~ /\S/
	&& !BSE::TB::Tags->valid_name($tag, \$error)) {
      push @errors, "msg:bse/admin/edit/tags/invalid/$error";
      $errors->{tags} = \@errors;
      ++$fail;
    }
    else {
      push @errors, undef;
    }
  }

  return $fail;
}

sub save_new {
  my ($self, $req, $article, $articles) = @_;

  $req->check_csrf("admin_add_article")
    or return $self->csrf_error($req, undef, "admin_add_article", "Add Article");
  
  my $cgi = $req->cgi;
  my %data;
  my $table_object = $self->table_object($articles);
  my @columns = $self->save_columns($table_object);
  $self->save_thumbnail($cgi, undef, \%data);
  for my $name (@columns) {
    $data{$name} = $cgi->param($name) 
      if defined $cgi->param($name);
  }
  $data{flags} = join '', sort $cgi->param('flags');

  my $msg;
  my %errors;
  if (!defined $data{parentid} || $data{parentid} eq '') {
    $errors{parentid} = "Please select a parent";
  }
  elsif ($data{parentid} !~ /^(?:-1|\d+)$/) {
    $errors{parentid} = "Invalid parent selection (template bug)";
  }
  $self->validate(\%data, $articles, \%errors);

  my $save_tags = $cgi->param("_save_tags");
  my @tags;
  if ($save_tags) {
    @tags = $cgi->param("tags");
    $self->_validate_tags(\@tags, \%errors);
  }

  my $meta;
  if ($cgi->param("_save_meta")) {
    require BSE::ArticleMetaMeta;
    $meta = BSE::ArticleMetaMeta->retrieve($req, $article, \%errors);
  }

  if (keys %errors) {
    if ($req->is_ajax) {
      return $req->json_content
	(
	 success => 0,
	 errors => \%errors,
	 error_code => "FIELD",
	 message => $req->message(\%errors),
	);
    }
    else {
      return $self->add_form($req, $article, $articles, $msg, \%errors);
    }
  }

  my $parent;
  my $parent_msg;
  my $parent_code;
  if ($data{parentid} > 0) {
    $parent = $articles->getByPkey($data{parentid}) or die;
    if ($req->user_can('edit_add_child', $parent)) {
      for my $name (@columns) {
	if (exists $data{$name} && 
	    !$req->user_can("edit_add_field_$name", $parent)) {
	  delete $data{$name};
	}
      }
    }
    else {
      $parent_msg = "You cannot add a child to that article";
      $parent_code = "ACCESS";
    }
  }
  else {
    if ($req->user_can('edit_add_child')) {
      for my $name (@columns) {
	if (exists $data{$name} && 
	    !$req->user_can("edit_add_field_$name")) {
	  delete $data{$name};
	}
      }
    }
    else {
      $parent_msg = "You cannot create a top-level article";
      $parent_code = "ACCESS";
    }
  }
  if (!$parent_msg) {
    $self->validate_parent(\%data, $articles, $parent, \$parent_msg)
      or $parent_code = "PARENT";
  }
  if ($parent_msg) {
    if ($req->is_ajax) {
      return $req->json_content
	(
	 success => 0,
	 message => $parent_msg,
	 error_code => $parent_code,
	 errors => {},
	);
    }
    else {
      return $self->add_form($req, $article, $articles, $parent_msg);
    }
  }

  my $level = $parent ? $parent->{level}+1 : 1;
  $data{level} = $level;
  $data{displayOrder} = time;
  $data{link} ||= '';
  $data{admin} ||= '';
  $data{generator} = $self->generator;
  $data{lastModified} = now_sqldatetime();
  $data{listed} = 1 unless defined $data{listed};

# Added by adrian
  $data{pageTitle} = '' unless defined $data{pageTitle};
  my $user = $req->getuser;
  $data{createdBy} = $user ? $user->{logon} : '';
  $data{lastModifiedBy} = $user ? $user->{logon} : '';
  $data{created} =  now_sqldatetime();
# end adrian

  $data{force_dynamic} = 0;
  $data{cached_dynamic} = 0;
  $data{inherit_siteuser_rights} = 1;

# Added by adrian
  $data{metaDescription} = '' unless defined $data{metaDescription};
  $data{metaKeywords} = '' unless defined $data{metaKeywords};
# end adrian

  $self->fill_new_data($req, \%data, $articles);
  for my $col (qw(titleImage imagePos template keyword menu titleAlias linkAlias body author summary category)) {
    defined $data{$col} 
      or $data{$col} = $self->default_value($req, \%data, $col);
  }

  for my $col (qw/force_dynamic inherit_siteuser_rights/) {
    if ($req->user_can("edit_add_field_$col", $parent)
	&& $cgi->param("save_$col")) {
      $data{$col} = $cgi->param($col) ? 1 : 0;
    }
    else {
      $data{$col} = $self->default_value($req, \%data, $col);
    }
  }

  unless ($req->is_ajax) {
    for my $col (qw(release expire)) {
      $data{$col} = sql_date($data{$col});
    }
  }

  # these columns are handled a little differently
  for my $col (qw(release expire threshold summaryLength )) {
    $data{$col} 
      or $data{$col} = $self->default_value($req, \%data, $col);
  }

  my @cols = $table_object->rowClass->columns;
  shift @cols;

  # fill out anything else from defaults
  for my $col (@columns) {
    exists $data{$col}
      or $data{$col} = $self->default_value($req, \%data, $col);
  }

  $article = $table_object->add(@data{@cols});

  $self->save_new_more($req, $article, \%data);

  # we now have an id - generate the links

  $article->update_dynamic($self->{cfg});
  my $cgi_uri = $self->{cfg}->entry('uri', 'cgi', '/cgi-bin');
  $article->setAdmin("$cgi_uri/admin/admin.pl?id=$article->{id}");
  $article->setLink($self->make_link($article));
  $article->save();

  my ($after_id) = $cgi->param("_after");
  if (defined $after_id) {
    BSE::TB::Articles->reorder_child($article->{parentid}, $article->{id}, $after_id);
    # reload, the displayOrder probably changed
    $article = $articles->getByPkey($article->{id});
  }

  if ($save_tags) {
    my $error;
    $article->set_tags([ grep /\S/, @tags ], \$error);
  }

  if ($meta) {
    BSE::ArticleMetaMeta->save($article, $meta);
  }

  generate_article($articles, $article) if $Constants::AUTO_GENERATE;

  if ($req->is_ajax) {
    return $req->json_content
      (
       {
	success => 1,
	article => $self->_article_data($req, $article),
       },
      );
  }

  my $r = $cgi->param('r');
  if ($r) {
    $r .= ($r =~ /\?/) ? '&' : '?';
    $r .= "id=$article->{id}";
  }
  else {
    $r = admin_base_url($req->cfg) . $article->{admin};
  }
  return BSE::Template->get_refresh($r, $self->{cfg});
}

sub fill_old_data {
  my ($self, $req, $article, $data) = @_;

  if (exists $data->{body}) {
    $data->{body} =~ s/\x0D\x0A/\n/g;
    $data->{body} =~ tr/\r/\n/;
  }
  for my $col (BSE::TB::Article->columns) {
    next if $col =~ /^custom/;
    $article->{$col} = $data->{$col}
      if exists $data->{$col} && $col ne 'id' && $col ne 'parentid';
  }
  my $custom = $self->_custom_fields;
  for my $key (keys %$custom) {
    if (exists $data->{$key}) {
      if ($key =~ /^customDate/) {
	require DevHelp::Date;
	my $msg;
	if (my ($year, $month, $day) =
	    DevHelp::Date::dh_parse_date($data->{$key}, \$msg)) {
	  $article->set($key, sprintf("%04d-%02d-%02d", $year, $month, $day));
	}
	else {
	  $article->set($key => undef);
	}
      }
      elsif ($key =~ /^customInt/) {
	if ($data->{$key} =~ /\S/) {
	  $article->set($key => $data->{$key});
	}
	else {
	  $article->set($key => undef);
	}
      }
      else {
	$article->set($key => $data->{$key});
      }
    }
  }
  custom_class($self->{cfg})
    ->article_fill_old($article, $data, $self->typename);

  return 1;
}

sub _article_data {
  my ($self, $req, $article) = @_;

  my $article_data = $article->data_only;
  $article_data->{link} = $article->link($req->cfg);
  $article_data->{images} =
    [
     map $self->_image_data($req->cfg, $_), $article->images
    ];
  $article_data->{files} =
    [
     map $_->data_only, $article->files,
    ];
  $article_data->{tags} =
    [
     $article->tags, # just the names
    ];

  return $article_data;
}

sub save_more {
  my ($self, $req, $article, $data) = @_;
  # nothing to do here
}

sub save_new_more {
  my ($self, $req, $article, $data) = @_;
  # nothing to do here
}

=item save

Error codes:

=over

=item *

ACCESS - user doesn't have access to this article.

=item *

LASTMOD - lastModified value doesn't match that in the article

=item *

PARENT - invalid parentid specified

=back

=cut

sub save {
  my ($self, $req, $article, $articles) = @_;

  $req->check_csrf("admin_save_article")
    or return $self->csrf_error($req, $article, "admin_save_article", "Save Article");

  $req->user_can(edit_save => $article)
    or return $self->_service_error
      ($req, $article, $articles, "You don't have access to save this article",
       {}, "ACCESS");

  my $old_dynamic = $article->is_dynamic;
  my $cgi = $req->cgi;
  my %data;
  my $table_object = $self->table_object($articles);
  my @save_cols = $self->save_columns($table_object);
  for my $name (@save_cols) {
    $data{$name} = $cgi->param($name) 
      if defined($cgi->param($name)) and $name ne 'id' && $name ne 'parentid'
	&& $req->user_can("edit_field_edit_$name", $article);
  }
  
# Added by adrian
# checks editor lastModified against record lastModified
  if ($self->{cfg}->entry('editor', 'check_modified')) {
    if ($article->{lastModified} ne $cgi->param('lastModified')) {
      my $whoModified = '';
      my $timeModified = ampm_time($article->{lastModified});
      if ($article->{lastModifiedBy}) {
        $whoModified = "by '$article->{lastModifiedBy}'";
      }
      print STDERR "non-matching lastModified, article not saved\n";
      my $msg = "Article changes not saved, this article was modified $whoModified at $timeModified since this editor was loaded";
      return $self->_service_error($req, $article, $articles, $msg, {}, "LASTMOD");
    }
  }
# end adrian
  
  # possibly this needs tighter error checking
  $data{flags} = join '', sort $cgi->param('flags')
    if $req->user_can("edit_field_edit_flags", $article);
  my %errors;
  if (exists $article->{template} &&
      $article->{template} =~ m|\.\.|) {
    $errors{template} = "Please only select templates from the list provided";
  }

  my $meta;
  if ($cgi->param("_save_meta")) {
    require BSE::ArticleMetaMeta;
    $meta = BSE::ArticleMetaMeta->retrieve($req, $article, \%errors);
  }

  my $save_tags = $cgi->param("_save_tags");
  my @tags;
  if ($save_tags) {
    @tags = $cgi->param("tags");
    $self->_validate_tags(\@tags, \%errors);
  }
  $self->validate_old($article, \%data, $articles, \%errors, scalar $req->is_ajax)
    or return $self->_service_error($req, $article, $articles, undef, \%errors, "FIELD");
  $self->save_thumbnail($cgi, $article, \%data)
    if $req->user_can('edit_field_edit_thumbImage', $article);
  if (exists $data{flags} && $data{flags} =~ /D/) {
    $article->remove_html;
  }
  $self->fill_old_data($req, $article, \%data);
  
  # reparenting
  my $newparentid = $cgi->param('parentid');
  if ($newparentid
      && $req->user_can('edit_field_edit_parentid', $article)
      && $newparentid != $article->{parentid}) {
    my $newparent;
    my $parent_editor;
    if ($newparentid == -1) {
      require BSE::Edit::Site;
      $newparent = BSE::TB::Site->new;
      $parent_editor = BSE::Edit::Site->new(cfg => $req->cfg);
    }
    else {
      $newparent = $articles->getByPkey($newparentid);
      ($parent_editor, $newparent) = $self->article_class($newparent, $articles, $req->cfg);
    }
    if ($newparent) {
      my $msg;
      if ($self->can_reparent_to($article, $newparent, $parent_editor, $articles, \$msg)
	 && $self->reparent($article, $newparentid, $articles, \$msg)) {
	# nothing to do here
      }
      else {
	return $self->_service_error($req, $article, $articles, $msg, {}, "PARENT");
      }
    }
    else {
      return $self->_service_error($req, $article, $articles, "No such parent article", {}, "PARENT");
    }
  }

  $article->{listed} = $cgi->param('listed')
   if defined $cgi->param('listed') && 
      $req->user_can('edit_field_edit_listed', $article);

  if ($req->user_can('edit_field_edit_release', $article)) {
    my $release = $cgi->param("release");
    if (defined $release && $release =~ /\S/) {
      if ($req->is_ajax) {
	$article->{release} = $release;
      }
      else {
	$article->{release} = sql_date($release)
      }
    }
  }

  $article->{expire} = sql_date($cgi->param('expire')) || $Constants::D_99
    if defined $cgi->param('expire') && 
      $req->user_can('edit_field_edit_expire', $article);
  for my $col (qw/force_dynamic inherit_siteuser_rights/) {
    if ($req->user_can("edit_field_edit_$col", $article)
	&& $cgi->param("save_$col")) {
      $article->{$col} = $cgi->param($col) ? 1 : 0;
    }
  }

  $article->mark_modified(actor => $req->getuser || "U");

  my @save_group_ids = $cgi->param('save_group_id');
  if ($req->user_can('edit_field_edit_group_id')
      && @save_group_ids) {
    require BSE::TB::SiteUserGroups;
    my %groups = map { $_->{id} => $_ }
      BSE::TB::SiteUserGroups->admin_and_query_groups($self->{cfg});
    my %set = map { $_ => 1 } $cgi->param('group_id');
    my %current = map { $_ => 1 } $article->group_ids;

    for my $group_id (@save_group_ids) {
      $groups{$group_id} or next;
      if ($current{$group_id} && !$set{$group_id}) {
	$article->remove_group_id($group_id);
      }
      elsif (!$current{$group_id} && $set{$group_id}) {
	$article->add_group_id($group_id);
      }
    }
  }

  my $old_link = $article->{link};
  # this need to go last
  $article->update_dynamic($self->{cfg});
  if (!$self->{cfg}->entry('protect link', $article->{id})) {
    my $article_uri = $self->make_link($article);
    $article->setLink($article_uri);
  }

  $article->save();

  if ($save_tags) {
    my $error;
    $article->set_tags([ grep /\S/, @tags ], \$error);
  }

use Data::Dumper;
print STDERR Dumper($meta);
  if ($meta) {
    BSE::ArticleMetaMeta->save($article, $meta);
  }

  # fix the kids too
  my @extra_regen;
  @extra_regen = $self->update_child_dynamic($article, $articles, $req);
  
  if ($article->is_dynamic || $old_dynamic) {
    if (!$old_dynamic and $old_link) {
      unlink $article->link_to_filename($self->{cfg}, $old_link);
    }
    elsif (!$article->is_dynamic) {
      unlink $article->cached_filename($self->{cfg});
    }
  }

  my ($after_id) = $cgi->param("_after");
  if (defined $after_id) {
    BSE::TB::Articles->reorder_child($article->{parentid}, $article->{id}, $after_id);
    # reload, the displayOrder probably changed
    $article = $articles->getByPkey($article->{id});
  }

  if ($Constants::AUTO_GENERATE) {
    generate_article($articles, $article);
    for my $regen_id (@extra_regen) {
      my $regen = $articles->getByPkey($regen_id);
      BSE::Regen::generate_low($articles, $regen, $self->{cfg});
    }
  }

  $self->save_more($req, $article, \%data);

  if ($req->is_ajax) {
    return $req->json_content
      (
       {
	success => 1,
	article => $self->_article_data($req, $article),
       },
      );
  }

  return $self->refresh($article, $cgi, undef, 'Article saved');
}

sub can_reparent_to {
  my ($self, $article, $newparent, $parent_editor, $articles, $rmsg) = @_;

  my @child_types = $parent_editor->child_types;
  if (!grep $_ eq ref $self, @child_types) {
    my ($child_type) = (ref $self) =~ /(\w+)$/;
    my ($parent_type) = (ref $parent_editor) =~ /(\w+)$/;
    
    $$rmsg = "A $child_type cannot be a child of a $parent_type";
    return;
  }
  
  # the article cannot become a child of itself or one of it's 
  # children
  if ($article->{id} == $newparent->id
      || $self->is_descendant($article->id, $newparent->id, $articles)) {
    $$rmsg = "Cannot become a child of itself or of a descendant";
    return;
  }

  my $shopid = $self->{cfg}->entryErr('articles', 'shop');
  if ($self->shop_article) { # if this article belongs in the shop
    unless ($newparent->id == $shopid
	    || $self->is_descendant($shopid, $newparent->{id}, $articles)) {
      $$rmsg = "This article belongs in the shop";
      return;
    }
  }
  else {
    if ($newparent->id == $shopid
	|| $self->is_descendant($shopid, $newparent->id, $articles)) {
      $$rmsg = "This article doesn't belong in the shop";
      return;
    }
  }

  return 1;
}

sub shop_article { 0 }

sub update_child_dynamic {
  my ($self, $article, $articles, $req) = @_;

  my $cfg = $req->cfg;
  my @stack = $article->children;
  my @regen;
  while (@stack) {
    my $workart = pop @stack;
    my $old_dynamic = $workart->is_dynamic; # before update
    my $old_link = $workart->{link};
    my $editor;
    ($editor, $workart) = $self->article_class($workart, $articles, $cfg);

    $workart->update_dynamic($cfg);
    if ($old_dynamic != $workart->is_dynamic) {
      # update the link
      if ($article->{link} && !$cfg->entry('protect link', $workart->{id})) {
	my $uri = $editor->make_link($workart);
	$workart->setLink($uri);

	!$old_dynamic && $old_link
	  and unlink $workart->link_to_filename($cfg, $old_link);
	$workart->is_dynamic
	  or unlink $workart->cached_filename($cfg);
      }

      # save dynamic cache change and link if that changed
      $workart->save;
    }
    push @stack, $workart->children;
    push @regen, $workart->{id};
  }

  @regen;
}

sub sql_date {
  my $str = shift;
  my ($year, $month, $day);

  # look for a date
  if (($day, $month, $year) = ($str =~ m!(\d+)/(\d+)/(\d+)!)) {
    $year += 2000 if $year < 100;

    return sprintf("%04d-%02d-%02d", $year, $month, $day);
  }
  return undef;
}

# Added by adrian
# Converts 24hr time to 12hr AM/PM time
sub ampm_time {
  my $str = shift;
  my ($hour, $minute, $second, $ampm);

  # look for a time
  if (($hour, $minute, $second) = ($str =~ m!(\d+):(\d+):(\d+)!)) {
    if ($hour > 12) {
      $hour -= 12;
      $ampm = 'PM';
    }
    else {
      $hour = 12 if $hour == 0;
      $ampm = 'AM';
    }
    return sprintf("%02d:%02d:%02d $ampm", $hour, $minute, $second);
  }
  return undef;
}
# end adrian

sub reparent {
  my ($self, $article, $newparentid, $articles, $rmsg) = @_;

  my $newlevel;
  if ($newparentid == -1) {
    $newlevel = 1;
  }
  else {
    my $parent = $articles->getByPkey($newparentid);
    unless ($parent) {
      $$rmsg = "Cannot get new parent article";
      return;
    }
    $newlevel = $parent->{level} + 1;
  }
  # the caller will save this one
  $article->{parentid} = $newparentid;
  $article->{level} = $newlevel;
  $article->{displayOrder} = time;

  my @change = ( [ $article->{id}, $newlevel ] );
  while (@change) {
    my $this = shift @change;
    my ($art, $level) = @$this;

    my @kids = $articles->getBy(parentid=>$art);
    push @change, map { [ $_->{id}, $level+1 ] } @kids;

    for my $kid (@kids) {
      $kid->{level} = $level+1;
      $kid->save;
    }
  }

  return 1;
}

# tests if $desc is a descendant of $art
# where both are article ids
sub is_descendant {
  my ($self, $art, $desc, $articles) = @_;
  
  my @check = ($art);
  while (@check) {
    my $parent = shift @check;
    $parent == $desc and return 1;
    my @kids = $articles->getBy(parentid=>$parent);
    push @check, map $_->{id}, @kids;
  }

  return 0;
}

sub save_thumbnail {
  my ($self, $cgi, $original, $newdata) = @_;

  unless ($original) {
    @$newdata{qw/thumbImage thumbWidth thumbHeight/} = ('', 0, 0);
  }
  my $imagedir = cfg_image_dir($self->{cfg});
  if ($cgi->param('remove_thumb') && $original && $original->{thumbImage}) {
    unlink("$imagedir/$original->{thumbImage}");
    @$newdata{qw/thumbImage thumbWidth thumbHeight/} = ('', 0, 0);
  }
  my $image_name = $cgi->param('thumbnail');
  my $image = $cgi->upload('thumbnail');
  if ($image_name && -s $image) {
    # where to put it...
    my $name = '';
    $image_name =~ /([\w.-]+)$/ and $name = $1;
    my $filename = time . "_" . $name;

    use Fcntl;
    my $counter = "";
    $filename = time . '_' . $counter . '_' . $name
      until sysopen( OUTPUT, "$imagedir/$filename", 
                     O_WRONLY| O_CREAT| O_EXCL)
        || ++$counter > 100;

    fileno(OUTPUT) or die "Could not open image file: $!";
    binmode OUTPUT;
    my $buffer;

    #no strict 'refs';

    # read the image in from the browser and output it to our 
    # output filehandle
    print STDERR "\$image ",ref $image,"\n";
    seek $image, 0, 0;
    print OUTPUT $buffer while sysread $image, $buffer, 1024;

    close OUTPUT
      or die "Could not close image output file: $!";

    require BSE::ImageSize;

    if ($original && $original->{thumbImage}) {
      #unlink("$imagedir/$original->{thumbImage}");
    }
    @$newdata{qw/thumbWidth thumbHeight/} =
      BSE::ImageSize::imgsize("$imagedir/$filename");
    $newdata->{thumbImage} = $filename;
  }
}

sub child_types {
  my ($self, $article) = @_;

  my $shopid = $self->{cfg}->entryErr('articles', 'shop');
  if ($article && $article->{id} && $article->{id} == $shopid) {
    return ( 'BSE::Edit::Catalog' );
  }
  return ( 'BSE::Edit::Article' );
}

=item add_stepkid

Add a step child to an article.

Parameters:

=over

=item *

id - parent article id (required)

=item *

stepkid - child article id (required)

=item *

_after - id of the allkid of id to position the stepkid after
(optional)

=back

Returns a FIELD error for an invalid stepkid.

Returns an ACCESS error for insufficient access.

Return an ADD error for a general add failure.

On success returns:

  {
   success: 1,
   relationship: { childId: I<childid>, parentId: I<parentid> }
  }

=back

=cut

sub add_stepkid {
  my ($self, $req, $article, $articles) = @_;

  $req->check_csrf("admin_add_stepkid")
    or return $self->csrf_error($req, $article, "admin_add_stepkid", "Add Stepkid");

  $req->user_can(edit_stepkid_add => $article)
    or return $self->_service_error($req, $article, $articles,
			       "You don't have access to add step children to this article", {}, "ACCESS");

  my $cgi = $req->cgi;
  require BSE::Admin::StepParents;

  my %errors;
  my $childId = $cgi->param('stepkid');
  defined $childId
    or $errors{stepkid} = "No stepkid supplied to add_stepkid";
  unless ($errors{stepkid}) {
    $childId =~ /^\d+$/
      or $errors{stepkid} = "Invalid stepkid supplied to add_stepkid";
  }
  my $child;
  unless ($errors{stepkid}) {
    $child = $articles->getByPkey($childId)
      or $errors{stepkid} = "Article $childId not found";
  }
  keys %errors
    and return $self->_service_error
      ($req, $article, $articles, $errors{stepkid}, \%errors, "FIELD");

  $req->user_can(edit_stepparent_add => $child)
    or return $self->_service_error($req, $article, $articles, "You don't have access to add a stepparent to that article", {}, "ACCESS");

  my $new_entry;
  eval {
    
    my $release = $cgi->param('release');
    dh_parse_date($release) or $release = undef;
    my $expire = $cgi->param('expire');
    dh_parse_date($expire) or $expire = undef;
  
    $new_entry = 
      BSE::Admin::StepParents->add($article, $child, $release, $expire);
  };
  if ($@) {
    return $self->_service_error($req, $article, $articles, $@, {}, "ADD");
  }

  my $after_id = $cgi->param("_after");
  if (defined $after_id) {
    BSE::TB::Articles->reorder_child($article->id, $child->id, $after_id);
  }

  generate_article($articles, $article) if $Constants::AUTO_GENERATE;

  if ($req->is_ajax) {
    return $req->json_content
      (
       success => 1,
       relationship => $new_entry->data_only,
      );
  }
  else {
    $self->refresh($article, $cgi, 'step', 'Stepchild added');
  }
}

=item del_stepkid

Remove a stepkid relationship.

Parameters:

=over

=item *

id - parent article id (required)

=item *

stepkid - child article id (required)

=back

Returns a FIELD error for an invalid stepkid.

Returns an ACCESS error for insufficient access.

Return a DELETE error for a general delete failure.

=cut

sub del_stepkid {
  my ($self, $req, $article, $articles) = @_;

  $req->check_csrf("admin_remove_stepkid")
    or return $self->csrf_error($req, $article, "admin_del_stepkid", "Delete Stepkid");
  $req->user_can(edit_stepkid_delete => $article)
    or return $self->_service_error($req, $article, $articles,
			       "You don't have access to delete stepchildren from this article", {}, "ACCESS");

  my $cgi = $req->cgi;

  my %errors;
  my $childId = $cgi->param('stepkid');
  defined $childId
    or $errors{stepkid} = "No stepkid supplied to add_stepkid";
  unless ($errors{stepkid}) {
    $childId =~ /^\d+$/
      or $errors{stepkid} = "Invalid stepkid supplied to add_stepkid";
  }
  my $child;
  unless ($errors{stepkid}) {
    $child = $articles->getByPkey($childId)
      or $errors{stepkid} = "Article $childId not found";
  }
  keys %errors
    and return $self->_service_error
      ($req, $article, $articles, $errors{stepkid}, \%errors, "FIELD");

  $req->user_can(edit_stepparent_delete => $child)
    or return _service_error($req, $article, $article, "You cannot remove stepparents from that article", {}, "ACCESS");
    

  require BSE::Admin::StepParents;
  eval {
    BSE::Admin::StepParents->del($article, $child);
  };
  
  if ($@) {
    return $self->_service_error($req, $article, $articles, $@, {}, "DELETE");
  }
  generate_article($articles, $article) if $Constants::AUTO_GENERATE;

  if ($req->is_ajax) {
    return $req->json_content(success => 1);
  }
  else {
    return $self->refresh($article, $cgi, 'step', 'Stepchild deleted');
  }
}

sub save_stepkids {
  my ($self, $req, $article, $articles) = @_;

  $req->check_csrf("admin_save_stepkids")
    or return $self->csrf_error($req, $article, "admin_save_stepkids", "Save Stepkids");

  $req->user_can(edit_stepkid_save => $article)
    or return $self->edit_form($req, $article, $articles,
			       "No access to save stepkid data for this article");

  my $cgi = $req->cgi;
  require 'BSE/Admin/StepParents.pm';
  my @stepcats = BSE::TB::OtherParents->getBy(parentId=>$article->{id});
  my %stepcats = map { $_->{parentId}, $_ } @stepcats;
  my %datedefs = ( release => '2000-01-01', expire=>'2999-12-31' );
  for my $stepcat (@stepcats) {
    $req->user_can(edit_stepparent_save => $stepcat->{childId})
      or next;
    for my $name (qw/release expire/) {
      my $date = $cgi->param($name.'_'.$stepcat->{childId});
      if (defined $date) {
	if ($date eq '') {
	  $date = $datedefs{$name};
	}
	elsif (dh_parse_date($date)) {
	  use BSE::Util::SQL qw/date_to_sql/;
	  $date = date_to_sql($date);
	}
	else {
	  return $self->refresh($article, $cgi, '', "Invalid date '$date'");
	}
	$stepcat->{$name} = $date;
      }
    }
    eval {
      $stepcat->save();
    };
    $@ and return $self->refresh($article, $cgi, '', $@);
  }
  generate_article($articles, $article) if $Constants::AUTO_GENERATE;

  return $self->refresh($article, $cgi, 'step', 'Stepchild information saved');
}

=item a_restepkid

Moves a stepkid from one parent to another, and sets the order within
that new stepparent.

Parameters:

=over

=item *

id - id of the step kid to move (required)

=item *

parentid - id of the parent in the stepkid relationship (required)

=item *

newparentid - the new parent for the stepkid relationship (optional)

=item *

_after - id of the allkid under newparentid (or parentid if
newparentid isn't supplied) to place the stepkid after (0 to place at
the start)

=back

Errors:

=over

=item *

NOPARENTID - parentid parameter not supplied

=item *

BADPARENTID - non-numeric parentid supplied

=item *

NOTFOUND - no stepkid relationship from parentid was found

=item *

BADNEWPARENT - newparentid is non-numeric

=item *

UNKNOWNNEWPARENT - no article id newparentid found

=item *

NEWPARENTDUP - there's already a stepkid relationship between
newparentid and id.

=back

=cut

sub req_restepkid {
  my ($self, $req, $article, $articles) = @_;

  # first, identify the stepkid link
  my $cgi = $req->cgi;
  require BSE::TB::OtherParents;
  my $parentid = $cgi->param("parentid");
  defined $parentid
    or return $self->_service_error($req, $article, $articles, "Missing parentid", {}, "NOPARENTID");
  $parentid =~ /^\d+$/
    or return $self->_service_error($req, $article, $articles, "Invalid parentid", {}, "BADPARENTID");

  my ($step) = BSE::TB::OtherParents->getBy(parentId => $parentid, childId => $article->id)
    or return $self->_service_error($req, $article, $articles, "Unknown relationship", {}, "NOTFOUND");

  my $newparentid = $cgi->param("newparentid");
  if ($newparentid) {
    $newparentid =~ /^\d+$/
      or return $self->_service_error($req, $article, $articles, "Bad new parent id", {}, "BADNEWPARENT");
    my $new_parent = BSE::TB::Articles->getByPkey($newparentid)
      or return $self->_service_error($req, $article, $articles, "Unknown new parent id", {}, "UNKNOWNNEWPARENT");
    my $existing = 
      BSE::TB::OtherParents->getBy(parentId=>$newparentid, childId=>$article->id)
	and return $self->_service_error($req, $article, $articles, "New parent is duplicate", {}, "NEWPARENTDUP");

    $step->{parentId} = $newparentid;
    $step->save;
  }

  my $after_id = $cgi->param("_after");
  if (defined $after_id) {
    BSE::TB::Articles->reorder_child($step->{parentId}, $article->id, $after_id);
  }

  if ($req->is_ajax) {
    return $req->json_content
      (
       success => 1,
       relationshop => $step->data_only,
      );
  }
  else {
    return $self->refresh($article, $cgi, 'step', "Stepchild moved");
  }
}

sub add_stepparent {
  my ($self, $req, $article, $articles) = @_;

  $req->check_csrf("admin_add_stepparent")
    or return $self->csrf_error($req, $article, "admin_add_stepparent", "Add Stepparent");

  $req->user_can(edit_stepparent_add => $article)
    or return $self->edit_form($req, $article, $articles,
			       "You don't have access to add stepparents to this article");

  my $cgi = $req->cgi;
  require 'BSE/Admin/StepParents.pm';
  eval {
    my $step_parent_id = $cgi->param('stepparent');
    defined($step_parent_id)
      or die "No stepparent supplied to add_stepparent";
    int($step_parent_id) eq $step_parent_id
      or die "Invalid stepcat supplied to add_stepcat";
    my $step_parent = $articles->getByPkey($step_parent_id)
      or die "Parent $step_parent_id not found\n";

    $req->user_can(edit_stepkid_add => $step_parent)
      or die "You don't have access to add a stepkid to that article\n";

    my $release = $cgi->param('release');
    defined $release
      or $release = "01/01/2000";
    $release eq '' or dh_parse_date($release)
      or die "Invalid release date";
    my $expire = $cgi->param('expire');
    defined $expire
      or $expire = '31/12/2999';
    $expire eq '' or dh_parse_date($expire)
      or die "Invalid expire data";
  
    my $newentry = 
      BSE::Admin::StepParents->add($step_parent, $article, $release, $expire);
  };
  $@ and return $self->refresh($article, $cgi, 'step', $@);

  generate_article($articles, $article) if $Constants::AUTO_GENERATE;

  return $self->refresh($article, $cgi, 'stepparents', 'Stepparent added');
}

sub del_stepparent {
  my ($self, $req, $article, $articles) = @_;

  $req->check_csrf("admin_remove_stepparent")
    or return $self->csrf_error($req, $article, "admin_del_stepparent", "Delete Stepparent");

  $req->user_can(edit_stepparent_delete => $article)
    or return $self->edit_form($req, $article, $articles,
			       "You cannot remove stepparents from that article");

  my $cgi = $req->cgi;
  require 'BSE/Admin/StepParents.pm';
  my $step_parent_id = $cgi->param('stepparent');
  defined($step_parent_id)
    or return $self->refresh($article, $cgi, 'stepparents', 
			     "No stepparent supplied to add_stepcat");
  int($step_parent_id) eq $step_parent_id
    or return $self->refresh($article, $cgi, 'stepparents', 
			     "Invalid stepparent supplied to add_stepparent");
  my $step_parent = $articles->getByPkey($step_parent_id)
    or return $self->refresh($article, $cgi, 'stepparent', 
			     "Stepparent $step_parent_id not found");

  $req->user_can(edit_stepkid_delete => $step_parent)
    or die "You don't have access to remove the stepkid from that article\n";

  eval {
    BSE::Admin::StepParents->del($step_parent, $article);
  };
  $@ and return $self->refresh($article, $cgi, 'stepparents', $@);

  generate_article($articles, $article) if $Constants::AUTO_GENERATE;

  return $self->refresh($article, $cgi, 'stepparents', 'Stepparent deleted');
}

sub save_stepparents {
  my ($self, $req, $article, $articles) = @_;

  $req->check_csrf("admin_save_stepparents")
    or return $self->csrf_error($req, $article, "admin_save_stepparents", "Save Stepparents");
  $req->user_can(edit_stepparent_save => $article)
    or return $self->edit_form($req, $article, $articles,
			       "No access to save stepparent data for this artice");

  my $cgi = $req->cgi;

  require 'BSE/Admin/StepParents.pm';
  my @stepparents = BSE::TB::OtherParents->getBy(childId=>$article->{id});
  my %stepparents = map { $_->{parentId}, $_ } @stepparents;
  my %datedefs = ( release => '2000-01-01', expire=>'2999-12-31' );
  for my $stepparent (@stepparents) {
    $req->user_can(edit_stepkid_save => $stepparent->{parentId})
      or next;
    for my $name (qw/release expire/) {
      my $date = $cgi->param($name.'_'.$stepparent->{parentId});
      if (defined $date) {
	if ($date eq '') {
	  $date = $datedefs{$name};
	}
	elsif (dh_parse_date($date)) {
	  use BSE::Util::SQL qw/date_to_sql/;
	  $date = date_to_sql($date);
	}
	else {
	  return $self->refresh($article, $cgi, "Invalid date '$date'");
	}
	$stepparent->{$name} = $date;
      }
    }
    eval {
      $stepparent->save();
    };
    $@ and return $self->refresh($article, $cgi, '', $@);
  }

  generate_article($articles, $article) if $Constants::AUTO_GENERATE;

  return $self->refresh($article, $cgi, 'stepparents', 
			'Stepparent information saved');
}

sub refresh_url {
  my ($self, $article, $cgi, $name, $message, $extras) = @_;

  my $url = $cgi->param('r');
  if ($url) {
    if ($url !~ /[?&](m|message)=/ && $message) {
      # add in messages if none in the provided refresh
      my @msgs = ref $message ? @$message : $message;
      my $sep = $url =~ /\?/ ? "&" : "?";
      for my $msg (@msgs) {
	$url .= $sep . "m=" . CGI::escape($msg);
      }
    }
  }
  else {
    my $urlbase = admin_base_url($self->{cfg});
    $url = "$urlbase$ENV{SCRIPT_NAME}?id=$article->{id}";
    if ($message) {
      my @msgs = ref $message ? @$message : $message;
      for my $msg (@msgs) {
	$url .= "&m=" . CGI::escape($msg);
      }
    }
    if ($cgi->param('_t')) {
      $url .= "&_t=".CGI::escape($cgi->param('_t'));
    }
    $url .= $extras if defined $extras;
    my $cgiextras = $cgi->param('e');
    $url .= "#$name" if $name;
  }

  return $url;
}

sub refresh {
  my ($self, $article, $cgi, $name, $message, $extras) = @_;

  my $url = $self->refresh_url($article, $cgi, $name, $message, $extras);

  return BSE::Template->get_refresh($url, $self->{cfg});
}

sub show_images {
  my ($self, $req, $article, $articles, $msg, $errors) = @_;

  my %acts;
  %acts = $self->low_edit_tags(\%acts, $req, $article, $articles, $msg, $errors);
  my $template = 'admin/article_img';

  return $req->dyn_response($template, \%acts);
}

sub save_image_changes {
  my ($self, $req, $article, $articles) = @_;

  $req->check_csrf("admin_save_images")
    or return $self->csrf_error($req, $article, "admin_save_images", "Save Images");

  $req->user_can(edit_images_save => $article)
    or return $self->edit_form($req, $article, $articles,
				 "You don't have access to save image information for this article");

  my $image_dir = cfg_image_dir($req->cfg);

  my $cgi = $req->cgi;
  my $image_pos = $cgi->param('imagePos');
  if ($image_pos 
      && $image_pos =~ /^(?:tl|tr|bl|br|xx)$/
      && $image_pos ne $article->{imagePos}) {
    $article->{imagePos} = $image_pos;
    $article->save;
  }
  my @images = $self->get_images($article);
  
  @images or
    return $self->refresh($article, $cgi, undef, 'No images to save information for');

  my %changes;
  my %errors;
  my %names;
  my %old_images;
  my @new_images;
  for my $image (@images) {
    my $id = $image->{id};

    my $alt = $cgi->param("alt$id");
    if ($alt ne $image->{alt}) {
      $changes{$id}{alt} = $alt;
    }

    my $url = $cgi->param("url$id");
    if (defined $url && $url ne $image->{url}) {
      $changes{$id}{url} = $url;
    }

    my $name = $cgi->param("name$id");
    if (defined $name && $name ne $image->{name}) {
      if ($name eq '') {
	$changes{$id}{name} = '';
      }
      elsif ($name =~ /^[a-z_]\w*$/i) {
	my $msg;
	if ($self->validate_image_name($name, \$msg)) {
	  # check for duplicates after the loop
	  push @{$names{lc $name}}, $image->{id}
	    if length $name;
	  $changes{$id}{name} = $name;
	}
	else {
	  $errors{"name$id"} = $msg;
	}
      }
      else {
	$errors{"name$id"} = 'Image name must be empty or alphanumeric and unique to the article';
      }
    }
    else {
      push @{$names{lc $image->{name}}}, $image->{id}
	if length $image->{name};
    }

    my $filename = $cgi->param("image$id");
    if (defined $filename && length $filename) {
      my $in_fh = $cgi->upload("image$id");
      if ($in_fh) {
	my $basename;
	my $image_error;
	my ($width, $height, $type) = $self->_validate_image
	  ($filename, $in_fh, \$basename, \$image_error);

	unless ($type) {
	  $errors{"image$id"} = $image_error;
	}

	unless ($errors{"image$id"}) {
	  # work out where to put it
	  require DevHelp::FileUpload;
	  my $msg;
	  my ($image_name, $out_fh) = DevHelp::FileUpload->make_img_filename
	    ($image_dir, $basename, \$msg);
	  if ($image_name) {
	    local $/ = \8192;
	    my $data;
	    while ($data = <$in_fh>) {
	      print $out_fh $data;
	    }
	    close $out_fh;
	    
	    my $full_filename = "$image_dir/$image_name";
	    if ($width) {
	      $old_images{$id} = 
		{ 
		 image => $image->{image}, 
		 storage => $image->{storage}
		};
	      push @new_images, $image_name;
	      
	      $changes{$id}{image} = $image_name;
	      $changes{$id}{storage} = 'local';
	      $changes{$id}{src} = cfg_image_uri() . "/" . $image_name;
	      $changes{$id}{width} = $width;
	      $changes{$id}{height} = $height;
	      $changes{$id}{ftype} = $self->_image_ftype($type);
	    }
	  }
	  else {
	    $errors{"image$id"} = $msg;
	  }
	}
      }
      else {
	# problem uploading
	$errors{"image$id"} = "No image file received";
      }
    }
  }
  # look for duplicate names
  for my $name (keys %names) {
    if (@{$names{$name}} > 1) {
      for my $id (@{$names{$name}}) {
	$errors{"name$id"} = 'Image name must be unique to the article';
      }
    }
  }
  if (keys %errors) {
    # remove files that won't be stored because validation failed
    unlink map "$image_dir/$_", @new_images;

    return $self->edit_form($req, $article, $articles, undef,
			    \%errors);
  }

  my $mgr = $self->_image_manager($req->cfg);
  $req->flash('Image information saved');
  my $changes_found = 0;
  my $auto_store = $cgi->param('auto_storage');
  for my $image (@images) {
    my $id = $image->{id};

    if ($changes{$id}) {
      my $changes = $changes{$id};
      ++$changes_found;
      
      for my $field (keys %$changes) {
	$image->{$field} = $changes->{$field};
      }
      $image->save;
    }

    my $old_storage = $image->{storage};
    my $new_storage = $auto_store ? '' : $cgi->param("storage$id");
    defined $new_storage or $new_storage = $image->{storage};
    $new_storage = $mgr->select_store($image->{image}, $new_storage, $image);
    if ($new_storage ne $old_storage) {
      eval {
	$image->{src} = $mgr->store($image->{image}, $new_storage, $image);
	$image->{storage} = $new_storage;
	$image->save;
      };
      
      if ($old_storage ne 'local') {
	$mgr->unstore($image->{image}, $old_storage);
      }
    }
  }

  # delete any image files that were replaced
  for my $old_image (values %old_images) {
    my ($image, $storage) = @$old_image{qw/image storage/};
    if ($storage ne 'local') {
      $mgr->unstore($image->{image}, $storage);
    }
    unlink "$image_dir/$image";
  }
  
  if ($changes_found) {
    generate_article($articles, $article) if $Constants::AUTO_GENERATE;
  }
    
  return $self->refresh($article, $cgi);
}

=item _service_error

This function is called on various errors.

If a _service parameter was supplied, returns text like:

=over

Result: failure

Field-Error: I<field-name1> - I<message1>

Field-Error: I<field-name2> - I<message2>

=back

If the request is detected as an ajax request or a _ parameter is
supplied, return JSON like:

  { error: I<message> }

Otherwise display the normal edit page with the error.

=cut

sub _service_error {
  my ($self, $req, $article, $articles, $msg, $error, $code, $method) = @_;

  unless ($article) {
    my $mymsg;
    $article = $self->_dummy_article($req, $articles, \$mymsg);
    $article ||=
      {
       map $_ => '', BSE::TB::Article->columns
      };
  }

  if ($req->cgi->param('_service')) {
    my $body = '';
    $body .= "Result: failure\n";
    if (ref $error) {
      for my $field (keys %$error) {
	my $text = $error->{$field};
	$text =~ tr/\n/ /;
	$body .= "Field-Error: $field - $text\n";
      }
      my $text = join ('/', values %$error);
      $text =~ tr/\n/ /;
      $body .= "Error: $text\n";
    }
    elsif ($msg) {
      $body .= "Error: $msg\n";
    }
    else {
      $body .= "Error: $error\n";
    }
    return
      {
       type => 'text/plain',
       content => $body,
      };
  }
  elsif ((() = $req->cgi->param('_')) ||
	 (exists $ENV{HTTP_X_REQUESTED_WITH}
	  && $ENV{HTTP_X_REQUESTED_WITH} =~ /XMLHttpRequest/)) {
    $error ||= {};
    my $result = 
      {
       errors => $error,
       success => 0,
      };
    $msg and $result->{message} = $msg;
    $code and $result->{error_code} = $code;
    my $json_result = $req->json_content($result);

    if (!exists $ENV{HTTP_X_REQUESTED_WITH}
	|| $ENV{HTTP_X_REQUESTED_WITH} !~ /XMLHttpRequest/) {
      $json_result->{type} = "text/plain";
    }

    return $json_result;
  }
  else {
    $method ||= "edit_form";
    return $self->$method($req, $article, $articles, $msg, $error);
  }
}

sub _service_success {
  my ($self, $results) = @_;

  my $body = "Result: success\n";
  for my $field (keys %$results) {
    $body .= "$field: $results->{$field}\n";
  }
  return
    {
     type => 'text/plain',
     content => $body,
    };
}

# FIXME: eliminate this method and call get_ftype directly
sub _image_ftype {
  my ($self, $type) = @_;

  require BSE::TB::Images;
  return BSE::TB::Images->get_ftype($type);
}

my %valid_exts =
  (
   tiff => "tiff,tif",
   jpg => "jpeg,jpg",
   pnm => "pbm,pgm,ppm",
  );

sub _validate_image {
  my ($self, $filename, $fh, $rbasename, $error) = @_;

  if ($fh) {
    if (-z $fh) {
      $$error = 'Image file is empty';
      return;
    }
  }
  else {
    $$error = 'Please enter an image filename';
    return;
  }
  my $imagename = $filename;
  $imagename .= ''; # force it into a string
  my $basename = '';
  $imagename =~ tr/ //d;
  $imagename =~ /([\w.-]+)$/ and $basename = $1;

  # for OSs with special text line endings
  require BSE::ImageSize;

  my ($width,$height, $type) = BSE::ImageSize::imgsize($fh);

  unless (defined $width) {
    $$error = "Unknown image file type";
    return;
  }

  my $lctype = lc $type;
  my @valid_exts = split /,/, 
    BSE::Cfg->single->entry("valid image extensions", $lctype,
		$valid_exts{$lctype} || $lctype);

  my ($ext) = $basename =~ /\.(\w+)\z/;
  if (!$ext || !grep $_ eq lc $ext, @valid_exts) {
    $basename .= ".$valid_exts[0]";
  }
  $$rbasename = $basename;

  return ($width, $height, $type);
}

my $last_display_order = 0;

sub do_add_image {
  my ($self, $cfg, $article, $image, %opts) = @_;

  my $errors = $opts{errors}
    or die "No errors parameter";

  my $imageref = $opts{name};
  if (defined $imageref && $imageref ne '') {
    if ($imageref =~ /^[a-z_]\w+$/i) {
      # make sure it's unique
      my @images = $self->get_images($article);
      for my $img (@images) {
	if (defined $img->{name} && lc $img->{name} eq lc $imageref) {
	  $errors->{name} = 'Image name must be unique to the article';
	  last;
	}
      }
    }
    else {
      $errors->{name} = 'Image name must be empty or alphanumeric beginning with an alpha character';